app-arch/lrzip-next: Remove ~x86 keyword; investigated musl issues

Package no longer supports 32-bit arches (sizeof(long) == 4), so
will mask on all 32-bit arches.

Package is also currently incompatible w/ musl's pthreads code;
need to talk to upstream to see if can be fixed.  Will mask on
musl for now.

Also added more missing deps, removed dev-perl/Pod-Parser as a bdep,
and added ebuild logic to fill in the package's version w/o needing
to drag dev-vcs/git in as a bdep.

Bug: https://bugs.gentoo.org/925547
Closes: https://bugs.gentoo.org/925548
Signed-off-by: Joshua Kinard <kumba@gentoo.org>

2 files changed, 67 insertions, 50 deletions

diff --git a/app-arch/lrzip-next/lrzip-next-0.12.6-r1.ebuild b/app-arch/lrzip-next/lrzip-next-0.12.6-r1.ebuild
new file mode 100644
index 000000000000..e218f7e3e4fe
--- /dev/null
+++ b/app-arch/lrzip-next/lrzip-next-0.12.6-r1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+
+inherit autotools
+
+DESCRIPTION="Fork of Con Kolivas' lrzip program for compressing large files"
+HOMEPAGE="https://github.com/pete4abw/lrzip-next"
+SRC_URI="https://github.com/pete4abw/lrzip-next/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="asm static-libs year2038"
+
+RDEPEND="app-arch/bzip2
+	app-arch/bzip3
+	app-arch/lz4
+	app-arch/zstd
+	dev-libs/libgcrypt
+	dev-libs/libgpg-error
+	dev-libs/lzo
+	sys-libs/zlib"
+DEPEND="${RDEPEND}"
+BDEPEND="amd64? ( dev-lang/nasm )"
+
+src_prepare() {
+	default
+
+	# configure.ac uses a small helper script, ./util/gitdesc.sh, to
+	# see if it's a tarball or git repo copy.  If tarball, it extracts
+	# the version information from a local VERSION file and puts it into
+	# configure.ac at the top for major/minor/micro.  To avoid the need
+	# for a BDEPEND on dev-vcs/git, we can do this directly.
+	local major=$(awk '/Major: / {printf "%s",$2; exit}' VERSION)
+	local minor=$(awk '/Minor: / {printf "%s",$2; exit}' VERSION)
+	local micro=$(awk '/Micro: / {printf "%s",$2; exit}' VERSION)
+	sed -i -e "s:\[m4_esyscmd_s(\[./util/gitdesc.sh major\])\]:${major}:" configure.ac
+	sed -i -e "s:\[m4_esyscmd_s(\[./util/gitdesc.sh minor\])\]:${minor}:" configure.ac
+	sed -i -e "s:\[m4_esyscmd_s(\[./util/gitdesc.sh micro\])\]:${micro}:" configure.ac
+
+	eautoreconf
+}
+
+src_configure() {
+	local myconf=(
+		$(use_enable static-libs static) \
+		$(use_enable amd64 asm)
+	)
+
+	# This configure switch disappears on a musl system for some
+	# reason.  However, this package is currently broken on musl,
+	# but we'll leave this in place while we see if upstream has
+	# any advice.
+	if ! use elibc_musl; then
+		myconf+=( $(use_enable year2038) )
+	fi
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name '*.la' -delete || die
+}
diff --git a/app-arch/lrzip-next/lrzip-next-0.12.6.ebuild b/app-arch/lrzip-next/lrzip-next-0.12.6.ebuild
deleted file mode 100644
index 0d3258e4caa8..000000000000
--- a/app-arch/lrzip-next/lrzip-next-0.12.6.ebuild
+++ /dev/null
@@ -1,50 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit autotools
-
-DESCRIPTION="Fork of Con Kolivas' lrzip program for compressing large files"
-HOMEPAGE="https://github.com/pete4abw/lrzip-next"
-SRC_URI="https://github.com/pete4abw/lrzip-next/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="static-libs year2038"
-
-RDEPEND="app-arch/bzip2
-	app-arch/bzip3
-	app-arch/lz4
-	app-arch/zstd
-	dev-libs/lzo
-	sys-libs/zlib"
-DEPEND="${RDEPEND}"
-BDEPEND="dev-perl/Pod-Parser
-	amd64? ( dev-lang/nasm )
-	x86? ( dev-lang/nasm )"
-
-src_prepare() {
-	default
-
-	eautoreconf
-}
-
-src_configure() {
-	# ASM optimizations are only available on amd64 and x86
-	local asm=no
-	if use amd64 || use x86; then
-		asm=yes
-	fi
-
-	econf \
-		$(use_enable static-libs static) \
-		$(use_enable year2038) \
-		--enable-asm=${asm}
-}
-
-src_install() {
-	default
-	find "${ED}" -name '*.la' -delete || die
-}