dev-util/d-feet: bump to 0.3.13

Package-Manager: Portage-2.3.43, Repoman-2.3.10

2 files changed, 62 insertions, 0 deletions

diff --git a/dev-util/d-feet/Manifest b/dev-util/d-feet/Manifest
index aaefe0479aee..ac83a68e3f20 100644
--- a/dev-util/d-feet/Manifest
+++ b/dev-util/d-feet/Manifest
@@ -1 +1,2 @@
 DIST d-feet-0.3.12.tar.xz 184308 BLAKE2B 1e0bb31c768cff357db735ed924cd0d768cb0412ccb6b722569c906671fd4929f67d62cbc09d37b1176755dff228c659013c1ec27d785c4175e534a4458c3fd3 SHA512 ef7a8aa57893cc210327420e954d39d256733839e6a171b8e035f15089fdf963c708a39c3b931b8a85d9faf78a1be324576c5fa2440db8305c1bfc8a8d9e991e
+DIST d-feet-0.3.13.tar.xz 174700 BLAKE2B 66d2a8735011c64985889edf1acbb37e1547d6af52fc6499124ffae09d8cfd876051e12f231c26a1af848939b9a3e9c36d1083e8afb240575d4f580ea92fde65 SHA512 b5a4eb995e883406a13e8a4137b1ed751cfbfd0fd80fa26eb81cf6f8b69bca63f3a4ad940b1aeaed0a57d48d81c582b62f6c3880e7038136f2b40a1eef25328f
diff --git a/dev-util/d-feet/d-feet-0.3.13.ebuild b/dev-util/d-feet/d-feet-0.3.13.ebuild
new file mode 100644
index 000000000000..553e81b24062
--- /dev/null
+++ b/dev-util/d-feet/d-feet-0.3.13.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit gnome2 python-single-r1 virtualx
+
+DESCRIPTION="D-Feet is a powerful D-Bus debugger"
+HOMEPAGE="https://wiki.gnome.org/Apps/DFeet"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="test +X"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="
+	${PYTHON_DEPS}
+	>=x11-libs/gtk+-3.9.4:3[introspection]
+	>=dev-libs/gobject-introspection-0.9.6:=
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	>=dev-libs/glib-2.34:2
+	>=dev-python/pygobject-3.3.91:3[${PYTHON_USEDEP}]
+	>=sys-apps/dbus-1
+	X? ( x11-libs/libwnck:3[introspection] )
+"
+DEPEND="
+	${COMMON_DEPEND}
+	app-text/yelp-tools
+	>=dev-util/intltool-0.40.0
+"
+
+src_prepare() {
+	python_fix_shebang .
+
+	# Do not run update-desktop-database (sandbox violation)
+	sed -e '/^UPDATE_DESKTOP/s:=.*:=true:' \
+		-i data/Makefile.am data/Makefile.in || die
+
+	# disable pep8 - checking python whitespace style is not useful for us
+	sed -e 's/pep8 /# pep8 /' \
+		-i src/tests/Makefile.am src/tests/Makefile.in || die
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# disable pep8 - checking python code style is not useful downstream
+	# (especially when that style check fails!)
+	gnome2_src_configure \
+		$(use_enable test tests) \
+		PEP8=$(type -P true)
+}
+
+src_test() {
+	virtx emake check
+}