net-analyzer/wireshark: clean up old

Now that 4.4.4 passes tests even on big endian arches we can drop 4.4.3.

Signed-off-by: Holger Hoffstätte <holger@applied-asynchrony.com>
Closes: https://github.com/gentoo/gentoo/pull/40679
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 0 insertions, 351 deletions

diff --git a/net-analyzer/wireshark/Manifest b/net-analyzer/wireshark/Manifest
index b5a542327ac0..288ed05f83ab 100644
--- a/net-analyzer/wireshark/Manifest
+++ b/net-analyzer/wireshark/Manifest
@@ -1,6 +1,4 @@
 DIST wireshark-4.4.2-signatures.txt 2706 BLAKE2B 3349a3e88782e1326b6c2e1b56d5eefbaeb2dbd6cf33b055e3a49692023b02e77a7e6d26ade7a9018cda783aa29edade997aaa03222fadb06c5bfa106a492459 SHA512 c809085b69c909702b3390b93891a19b8a8c0812d448ac9399eb59991618737b3bfeb737bd569267dcffc46290d59b34664f967e88c1a38b1678faaecd76d445
 DIST wireshark-4.4.2.tar.xz 46763620 BLAKE2B ea5c48f06c2aeb5b51f6ba62fd57214e9dd79917f978867d3ae31ffec74eb82ba7c8a2e2dcba415e53d051e531f9f9907aac88c6f29b6746222cf812bb43c85b SHA512 df80c98a2d00ba46a853acfe3aec9dfc0d4484f490a276b8b8390b6d108634b7e0fa38e8f02f8d93afe5c2394c463a0d89611027032898d7d0390d2111b70ca6
-DIST wireshark-4.4.3-signatures.txt 2706 BLAKE2B 175e3f54e8e88426554ccdf0cf9b09c51a3d6f6cb128d1b1172e2478f1255f35773575d15c65f7c7aa835086e11c32c7bc0802374b44eebd14ac7f7f25f12c24 SHA512 5dfbc85bb41b009022cd67148c44051971e2c3f0bf865c4755a41596b25f9018bae125cda3477c5e7d19f9a0c1c60de424ddbad60abd4b19da697349849c8b9b
-DIST wireshark-4.4.3.tar.xz 46769200 BLAKE2B b6a7348a4da0f6160e325e3345b508ae9e0ca900a2c0d308cb70d3da216ff90818e0439be3ef5f89dc87166e566d8b7d77f6fff114b5b303a5ad9b72e5665be4 SHA512 d100b562fbd452f52945502ecd918b26a15084b9c942754af43ffb221d49229f5a93eafd18b9bacc0cfcd60a38935d51a6ac809a2060d65faf1157ec9dae16e7
 DIST wireshark-4.4.4-signatures.txt 2706 BLAKE2B c1bd0f36657ceddffbf6a3a1a0b896a177946c5cca7893016a8bf6bfbdb03a45b101db4d1b6cd4b9ec114875d10447fa4ee8f2283758f8d0860dd012de883fa9 SHA512 f543b5fc95bbead2bad9981e75083c364014e1cceb81c9b96057fdd30d9d4547fccb9db23879180b9e15e769d99e89d26e78937662a7e66acdba27d4f42eefaa
 DIST wireshark-4.4.4.tar.xz 46845832 BLAKE2B 86c0d2bdb341f291180a021ecdef5d07c4a05e4296207925ca2443017a78a8cffdb98ac6890c2968c7bd1e42c9a43cab9770599d715729a4e63b486c73ae2ba9 SHA512 f2787d49de55cea4b6f09217e5520c7517f2a906ee7b91447ca0e6e1ab50c58d71963577a5eb899fd1e9b87103f34c9f7ea081ac6d6586e3a4974d74946a0199
diff --git a/net-analyzer/wireshark/wireshark-4.4.3.ebuild b/net-analyzer/wireshark/wireshark-4.4.3.ebuild
deleted file mode 100644
index 475ae8d5d1a7..000000000000
--- a/net-analyzer/wireshark/wireshark-4.4.3.ebuild
+++ /dev/null
@@ -1,349 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-LUA_COMPAT=( lua5-{3..4} )
-PYTHON_COMPAT=( python3_{10..13} )
-
-inherit fcaps flag-o-matic lua-single python-any-r1 qmake-utils xdg cmake
-
-DESCRIPTION="Network protocol analyzer (sniffer)"
-HOMEPAGE="https://www.wireshark.org/"
-
-if [[ ${PV} == *9999* ]] ; then
-	EGIT_REPO_URI="https://gitlab.com/wireshark/wireshark"
-	inherit git-r3
-else
-	VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/wireshark.asc
-	inherit verify-sig
-
-	SRC_URI="https://www.wireshark.org/download/src/all-versions/${P/_/}.tar.xz"
-	SRC_URI+=" verify-sig? ( https://www.wireshark.org/download/SIGNATURES-${PV}.txt -> ${P}-signatures.txt )"
-	S="${WORKDIR}/${P/_/}"
-
-	if [[ ${PV} != *_rc* ]] ; then
-		KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
-	fi
-fi
-
-LICENSE="GPL-2"
-SLOT="0/${PV}"
-IUSE="androiddump bcg729 brotli +capinfos +captype ciscodump +dftest doc dpauxmon"
-IUSE+=" +dumpcap +editcap +gui http2 http3 ilbc kerberos libxml2 lua lz4 maxminddb"
-IUSE+=" +mergecap +minizip +netlink opus +plugins +pcap +randpkt"
-IUSE+=" +randpktdump +reordercap sbc selinux +sharkd smi snappy spandsp sshdump ssl"
-IUSE+=" sdjournal test +text2pcap +tshark +udpdump wifi zlib +zstd"
-
-REQUIRED_USE="
-	lua? ( ${LUA_REQUIRED_USE} )
-"
-
-RESTRICT="!test? ( test )"
-
-# bug #753062 for speexdsp
-RDEPEND="
-	acct-group/pcap
-	>=dev-libs/glib-2.50.0:2
-	dev-libs/libpcre2
-	>=net-dns/c-ares-1.13.0:=
-	>=dev-libs/libgcrypt-1.8.0:=
-	media-libs/speexdsp
-	bcg729? ( media-libs/bcg729 )
-	brotli? ( app-arch/brotli:= )
-	ciscodump? ( >=net-libs/libssh-0.6:= )
-	filecaps? ( sys-libs/libcap )
-	http2? ( >=net-libs/nghttp2-1.11.0:= )
-	http3? ( net-libs/nghttp3 )
-	ilbc? ( media-libs/libilbc:= )
-	kerberos? ( virtual/krb5 )
-	libxml2? ( dev-libs/libxml2 )
-	lua? ( ${LUA_DEPS} )
-	lz4? ( app-arch/lz4:= )
-	maxminddb? ( dev-libs/libmaxminddb:= )
-	minizip? ( sys-libs/minizip-ng )
-	netlink? ( dev-libs/libnl:3 )
-	opus? ( media-libs/opus )
-	pcap? ( net-libs/libpcap )
-	gui? (
-		dev-qt/qtbase:6[concurrent,dbus,gui,widgets]
-		dev-qt/qt5compat:6
-		dev-qt/qtdeclarative:6
-		dev-qt/qtmultimedia:6
-		x11-misc/xdg-utils
-	)
-	sbc? ( media-libs/sbc )
-	sdjournal? ( sys-apps/systemd:= )
-	smi? ( net-libs/libsmi )
-	snappy? ( app-arch/snappy:= )
-	spandsp? ( media-libs/spandsp:= )
-	sshdump? ( >=net-libs/libssh-0.6:= )
-	ssl? ( >=net-libs/gnutls-3.5.8:= )
-	wifi? ( >=net-libs/libssh-0.6:= )
-	zlib? ( sys-libs/zlib-ng )
-	zstd? ( app-arch/zstd:= )
-"
-DEPEND="
-	${RDEPEND}
-"
-# TODO: 4.0.0_rc1 release notes say:
-# "Perl is no longer required to build Wireshark, but may be required to build some source code files and run code analysis checks."
-BDEPEND="
-	${PYTHON_DEPS}
-	dev-lang/perl
-	app-alternatives/lex
-	sys-devel/gettext
-	virtual/pkgconfig
-	doc? (
-		app-text/doxygen
-		dev-ruby/asciidoctor
-		dev-libs/libxslt
-	)
-	gui? (
-		dev-qt/qttools:6[linguist]
-	)
-	test? (
-		$(python_gen_any_dep '
-			dev-python/pytest[${PYTHON_USEDEP}]
-			dev-python/pytest-xdist[${PYTHON_USEDEP}]
-		')
-	)
-"
-RDEPEND="
-	${RDEPEND}
-	gui? ( virtual/freedesktop-icon-theme )
-	selinux? ( sec-policy/selinux-wireshark )
-"
-
-if [[ ${PV} != *9999* ]] ; then
-	BDEPEND+=" verify-sig? ( sec-keys/openpgp-keys-wireshark )"
-fi
-
-python_check_deps() {
-	use test || return 0
-
-	python_has_version -b "dev-python/pytest[${PYTHON_USEDEP}]" &&
-		 python_has_version -b "dev-python/pytest-xdist[${PYTHON_USEDEP}]"
-}
-
-pkg_setup() {
-	use lua && lua-single_pkg_setup
-
-	python-any-r1_pkg_setup
-}
-
-src_unpack() {
-	if [[ ${PV} == *9999* ]] ; then
-		git-r3_src_unpack
-	else
-		if use verify-sig ; then
-			cd "${DISTDIR}" || die
-			verify-sig_verify_signed_checksums \
-				${P}-signatures.txt \
-				openssl-dgst \
-				${P}.tar.xz
-			cd "${WORKDIR}" || die
-		fi
-
-		default
-	fi
-}
-
-src_configure() {
-	local mycmakeargs
-
-	python_setup
-
-	# Workaround bug #213705. If krb5-config --libs has -lcrypto then pass
-	# --with-ssl to ./configure. (Mimics code from acinclude.m4).
-	if use kerberos ; then
-		case $(krb5-config --libs) in
-			*-lcrypto*)
-				ewarn "Kerberos was built with ssl support: linkage with openssl is enabled."
-				ewarn "Note there are annoying license incompatibilities between the OpenSSL"
-				ewarn "license and the GPL, so do your check before distributing such package."
-				mycmakeargs+=( -DENABLE_GNUTLS=$(usex ssl) )
-				;;
-		esac
-	fi
-
-	if use gui ; then
-		append-cxxflags -fPIC -DPIC
-	fi
-
-	# crashes at runtime
-	# https://bugs.gentoo.org/754021
-	filter-lto
-
-	mycmakeargs+=(
-		-DPython3_EXECUTABLE="${PYTHON}"
-		-DCMAKE_DISABLE_FIND_PACKAGE_{Asciidoctor,DOXYGEN}=$(usex !doc)
-
-		# Force bundled lemon (bug 933119)
-		-DLEMON_EXECUTABLE=
-
-		-DRPMBUILD_EXECUTABLE=
-		-DGIT_EXECUTABLE=
-		-DENABLE_CCACHE=OFF
-
-		$(use androiddump && use pcap && echo -DEXTCAP_ANDROIDDUMP_LIBPCAP=yes)
-		$(usex gui LRELEASE=$(qt6_get_bindir)/lrelease '')
-		$(usex gui MOC=$(qt6_get_bindir)/moc '')
-		$(usex gui RCC=$(qt6_get_bindir)/rcc '')
-		$(usex gui UIC=$(qt6_get_bindir)/uic '')
-
-		-DBUILD_androiddump=$(usex androiddump)
-		-DBUILD_capinfos=$(usex capinfos)
-		-DBUILD_captype=$(usex captype)
-		-DBUILD_ciscodump=$(usex ciscodump)
-		-DBUILD_dftest=$(usex dftest)
-		-DBUILD_dpauxmon=$(usex dpauxmon)
-		-DBUILD_dumpcap=$(usex dumpcap)
-		-DBUILD_editcap=$(usex editcap)
-		-DBUILD_mergecap=$(usex mergecap)
-		-DBUILD_mmdbresolve=$(usex maxminddb)
-		-DBUILD_randpkt=$(usex randpkt)
-		-DBUILD_randpktdump=$(usex randpktdump)
-		-DBUILD_reordercap=$(usex reordercap)
-		-DBUILD_sdjournal=$(usex sdjournal)
-		-DBUILD_sharkd=$(usex sharkd)
-		-DBUILD_sshdump=$(usex sshdump)
-		-DBUILD_text2pcap=$(usex text2pcap)
-		-DBUILD_tfshark=OFF
-		-DBUILD_tshark=$(usex tshark)
-		-DBUILD_udpdump=$(usex udpdump)
-
-		-DBUILD_wireshark=$(usex gui)
-		-DUSE_qt6=$(usex gui)
-
-		-DENABLE_WERROR=OFF
-		-DENABLE_BCG729=$(usex bcg729)
-		-DENABLE_BROTLI=$(usex brotli)
-		-DENABLE_CAP=$(usex filecaps caps)
-		-DENABLE_GNUTLS=$(usex ssl)
-		-DENABLE_ILBC=$(usex ilbc)
-		-DENABLE_KERBEROS=$(usex kerberos)
-		-DENABLE_LIBXML2=$(usex libxml2)
-		# only appends -flto
-		-DENABLE_LTO=OFF
-		-DENABLE_LUA=$(usex lua)
-		-DLUA_FIND_VERSIONS="${ELUA#lua}"
-		-DENABLE_LZ4=$(usex lz4)
-		-DENABLE_MINIZIP=$(usex minizip)
-		-DENABLE_NETLINK=$(usex netlink)
-		-DENABLE_NGHTTP2=$(usex http2)
-		-DENABLE_NGHTTP3=$(usex http3)
-		-DENABLE_OPUS=$(usex opus)
-		-DENABLE_PCAP=$(usex pcap)
-		-DENABLE_PLUGINS=$(usex plugins)
-		-DENABLE_PLUGIN_IFDEMO=OFF
-		-DENABLE_SBC=$(usex sbc)
-		-DENABLE_SMI=$(usex smi)
-		-DENABLE_SNAPPY=$(usex snappy)
-		-DENABLE_SPANDSP=$(usex spandsp)
-		-DBUILD_wifidump=$(usex wifi)
-		-DENABLE_ZLIB=OFF
-		-DENABLE_ZLIBNG=$(usex zlib)
-		-DENABLE_ZSTD=$(usex zstd)
-	)
-
-	cmake_src_configure
-}
-
-src_test() {
-	cmake_build test-programs
-
-	EPYTEST_DESELECT=(
-		# https://gitlab.com/wireshark/wireshark/-/issues/20330
-		suite_sharkd.py::TestSharkd::test_sharkd_req_follow_http2
-	)
-
-	# https://www.wireshark.org/docs/wsdg_html_chunked/ChTestsRunPytest.html
-	epytest \
-		--disable-capture \
-		--skip-missing-programs=all \
-		--program-path "${BUILD_DIR}"/run
-}
-
-src_install() {
-	# bug #928577
-	# https://gitlab.com/wireshark/wireshark/-/commit/fe7bfdf6caac9204ab5f34eeba7b0f4a0314d3cd
-	cmake_src_install install-headers
-
-	if ! use doc; then
-		# prepare Relase Notes redirector (bug #939195)
-		local relnotes="doc/release-notes.html"
-
-		# by default create a link for our specific version
-		local relversion="wireshark-${PV}.html"
-
-		# for 9999 we link to the release notes index page
-		if [[ ${PV} == *9999* ]] ; then
-			relversion=""
-		fi
-
-		# patch version into redirector & install it
-		sed -e "s/#VERSION#/${relversion}/g" < "${FILESDIR}/release-notes.html" > ${relnotes} || die
-		dodoc ${relnotes}
-	fi
-
-	# FAQ is not required as is installed from help/faq.txt
-	dodoc AUTHORS ChangeLog README* doc/randpkt.txt doc/README*
-
-	# install headers
-	insinto /usr/include/wireshark
-	doins "${BUILD_DIR}"/config.h
-
-	# If trying to remove this, try build e.g. libvirt first!
-	# At last check, Fedora is still doing this too.
-	local dir dirs=(
-		epan
-		epan/crypt
-		epan/dfilter
-		epan/dissectors
-		epan/ftypes
-		wiretap
-		wsutil
-		wsutil/wmem
-	)
-
-	for dir in "${dirs[@]}" ; do
-		insinto /usr/include/wireshark/${dir}
-		doins ${dir}/*.h
-	done
-
-	if use gui ; then
-		local s
-
-		for s in 16 32 48 64 128 256 512 1024 ; do
-			insinto /usr/share/icons/hicolor/${s}x${s}/apps
-			newins resources/icons/wsicon${s}.png wireshark.png
-		done
-
-		for s in 16 24 32 48 64 128 256 ; do
-			insinto /usr/share/icons/hicolor/${s}x${s}/mimetypes
-			newins resources/icons//WiresharkDoc-${s}.png application-vnd.tcpdump.pcap.png
-		done
-	fi
-
-	if [[ -d "${ED}"/usr/share/appdata ]] ; then
-		rm -r "${ED}"/usr/share/appdata || die
-	fi
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-
-	# Add group for users allowed to sniff.
-	chgrp pcap "${EROOT}"/usr/bin/dumpcap
-
-	if use dumpcap && use pcap ; then
-		fcaps -o 0 -g pcap -m 4710 -M 0710 \
-			cap_dac_read_search,cap_net_raw,cap_net_admin \
-			"${EROOT}"/usr/bin/dumpcap
-	fi
-
-	ewarn "NOTE: To capture traffic with wireshark as normal user you have to"
-	ewarn "add yourself to the pcap group. This security measure ensures"
-	ewarn "that only trusted users are allowed to sniff your traffic."
-}