1 files changed, 85 insertions, 0 deletions
diff --git a/sys-apps/pciutils/pciutils-3.2.0.ebuild b/sys-apps/pciutils/pciutils-3.2.0.ebuild
new file mode 100644
index 00000000..8e9ed66e
--- /dev/null
+++ b/sys-apps/pciutils/pciutils-3.2.0.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/pciutils/pciutils-3.2.0.ebuild,v 1.14 2014/01/18 04:55:35 vapier Exp $
+
+EAPI="5"
+
+inherit eutils multilib toolchain-funcs
+
+DESCRIPTION="Various utilities dealing with the PCI bus"
+HOMEPAGE="http://mj.ucw.cz/sw/pciutils/ http://git.kernel.org/?p=utils/pciutils/pciutils.git"
+SRC_URI="ftp://atrey.karlin.mff.cuni.cz/pub/linux/pci/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 arm ~mips ppc x86"
+IUSE="+kmod static-libs zlib"
+
+# Have the sub-libs in RDEPEND with [static-libs] since, logically,
+# our libssl.a depends on libz.a/etc... at runtime.
+LIB_DEPEND="zlib? ( sys-libs/zlib[static-libs(+)] )"
+DEPEND="kmod? ( sys-apps/kmod )
+	static-libs? ( ${LIB_DEPEND} )
+	!static-libs? ( ${LIB_DEPEND//\[static-libs(+)]} )"
+RDEPEND="${DEPEND}
+	sys-apps/hwids"
+DEPEND="${DEPEND}
+	kmod? ( virtual/pkgconfig )"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-3.1.9-static-pc.patch
+	epatch "${FILESDIR}"/${PN}-3.2.0-io.patch
+
+	if use static-libs ; then
+		cp -pPR "${S}" "${S}.static" || die
+	fi
+}
+
+pemake() {
+	emake \
+		HOST="${CHOST}" \
+		CROSS_COMPILE="${CHOST}-" \
+		CC="$(tc-getCC)" \
+		DNS="yes" \
+		IDSDIR='$(SHAREDIR)/misc' \
+		MANDIR='$(SHAREDIR)/man' \
+		PREFIX="${EPREFIX}/usr" \
+		SHARED="yes" \
+		STRIP="" \
+		ZLIB=$(usex zlib) \
+		PCI_COMPRESSED_IDS=0 \
+		PCI_IDS=pci.ids \
+		LIBDIR="\${PREFIX}/$(get_libdir)" \
+		LIBKMOD="$(usex kmod)" \
+		"$@"
+}
+
+src_compile() {
+	pemake OPT="${CFLAGS}" all
+	if use static-libs ; then
+		pemake \
+			-C "${S}.static" \
+			OPT="${CFLAGS}" \
+			SHARED="no" \
+			lib/libpci.a
+	fi
+}
+
+src_install() {
+	pemake DESTDIR="${D}" install install-lib
+	use static-libs && dolib.a "${S}.static/lib/libpci.a"
+	dodoc ChangeLog README TODO
+
+	rm "${ED}"/usr/sbin/update-pciids "${ED}"/usr/share/misc/pci.ids \
+		"${ED}"/usr/share/man/man8/update-pciids.8*
+
+	newinitd "${FILESDIR}"/init.d-pciparm pciparm
+	newconfd "${FILESDIR}"/conf.d-pciparm pciparm
+}
+
+pkg_postinst() {
+	if [[ ${REPLACING_VERSIONS} ]] && [[ ${REPLACING_VERSIONS} < 3.2.0 ]]; then
+		elog "The 'network-cron' USE flag is gone; if you want a more up-to-date"
+		elog "pci.ids file, you should use sys-apps/hwids-99999999 (live ebuild)."
+	fi
+}