blob: e8f4e6097866b4ba9537cd7016612556abc5bdf7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $
EAPI=3
inherit common-lisp-3 elisp eutils
DESCRIPTION="SLIME, the Superior Lisp Interaction Mode (Extended)"
HOMEPAGE="http://common-lisp.net/project/slime/"
SRC_URI="http://common-lisp.net/~sionescu/files/${P}.tar.bz2"
LICENSE="GPL-2 xref.lisp"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="doc"
RDEPEND="virtual/commonlisp
dev-lisp/asdf"
DEPEND="sys-apps/texinfo
doc? ( virtual/texi2dvi )"
CLPACKAGE=swank
CLSYSTEMS=swank
SITEFILE=70${PN}-gentoo.el
src_prepare() {
epatch "${FILESDIR}"/${PV}/fix-inspect-presentations.patch
epatch "${FILESDIR}"/${PV}/fix-slime-indentation.patch
epatch "${FILESDIR}"/${PV}/gentoo-module-load.patch
epatch "${FILESDIR}"/${PV}/gentoo-dont-call-init.patch
# Eliminate Debian-specific rule
sed -i '/^section :=/d' doc/Makefile || die "sed doc/Makefile failed"
# extract date of last update from ChangeLog, bug 233270
SLIME_CHANGELOG_DATE=$(awk '/^[-0-9]+ / { print $1; exit; }' ChangeLog)
[ -n "${SLIME_CHANGELOG_DATE}" ] || die "cannot determine ChangeLog date"
# SLIME uses the changelog date to make sure that the emacs side and the CL side
# are in sync. We hardcode it instead of letting slime determine it at runtime
# because ChangeLog doesn't get installed to $EMACSDIR
epatch "${FILESDIR}"/${PV}/gentoo-changelog-date.patch
sed -i "/(defvar \*swank-wire-protocol-version\*/s:nil:\"${SLIME_CHANGELOG_DATE}\":" swank.lisp \
|| die "sed swank.lisp failed"
sed -i "s:@SLIME-CHANGELOG-DATE@:${SLIME_CHANGELOG_DATE}:" slime.el \
|| die "sed slime.el failed"
}
src_compile() {
emake -j1 -C doc slime.info || die "Cannot build info docs"
if use doc; then
VARTEXFONTS="${T}"/fonts \
emake -j1 -C doc slime.pdf || die "emake doc failed"
fi
}
src_install() {
## install core
elisp-install ${PN} *.el "${FILESDIR}"/swank-loader.lisp \
|| die "Cannot install SLIME core"
sed "s:/usr/:${EPREFIX}&:g" "${FILESDIR}"/${PV}/${SITEFILE} \
>"${T}"/${SITEFILE} || die "sed failed"
elisp-site-file-install "${T}"/${SITEFILE} || die
cp "${FILESDIR}"/${PV}/swank.asd "${S}"
# remove upstream swank-loader, since it won't be used
rm "${S}"/swank-loader.lisp
common-lisp-install-sources *.lisp
common-lisp-install-asdf swank.asd
## install contribs
elisp-install ${PN}/contrib/ contrib/*.{el,scm,goo} \
|| die "Cannot install contribs"
common-lisp-install-sources contrib/*.lisp
## install docs
dodoc README* ChangeLog HACKING NEWS PROBLEMS
newdoc contrib/README README.contrib
newdoc contrib/ChangeLog ChangeLog.contrib
doinfo doc/slime.info
use doc && dodoc doc/slime.pdf
}
|
GitWeb