blob: 1f3205be2e5bf7ed41926bd1a238cb03df9aed34 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ECM_HANDBOOK="forceoptional"
ECM_TEST="true"
KFMIN=5.115.0
QTMIN=5.15.12
inherit ecm kde.org optfeature
DESCRIPTION="Desktop Planetarium"
HOMEPAGE="https://apps.kde.org/kstars/"
if [[ ${KDE_BUILD_TYPE} = release ]]; then
SRC_URI="mirror://kde/stable/${PN}/${P}.tar.xz"
KEYWORDS="~amd64 ~x86"
fi
LICENSE="GPL-2+ GPL-3+"
SLOT="5"
IUSE="+password raw wcs"
# IUSE wcs needed by TestPolarAlign
REQUIRED_USE="${PYTHON_REQUIRED_USE} test? ( wcs )"
COMMON_DEPEND="
>=dev-qt/qtdatavis3d-${QTMIN}:5
>=dev-qt/qtdbus-${QTMIN}:5
>=dev-qt/qtdeclarative-${QTMIN}:5
>=dev-qt/qtgui-${QTMIN}:5
>=dev-qt/qtnetwork-${QTMIN}:5
>=dev-qt/qtprintsupport-${QTMIN}:5
>=dev-qt/qtsql-${QTMIN}:5
>=dev-qt/qtsvg-${QTMIN}:5
>=dev-qt/qtwebsockets-${QTMIN}:5
>=dev-qt/qtwidgets-${QTMIN}:5
>=kde-frameworks/kconfig-${KFMIN}:5
>=kde-frameworks/kconfigwidgets-${KFMIN}:5
>=kde-frameworks/kcoreaddons-${KFMIN}:5
>=kde-frameworks/kcrash-${KFMIN}:5
>=kde-frameworks/ki18n-${KFMIN}:5
>=kde-frameworks/kio-${KFMIN}:5
>=kde-frameworks/knewstuff-${KFMIN}:5
>=kde-frameworks/knotifications-${KFMIN}:5
>=kde-frameworks/knotifyconfig-${KFMIN}:5
>=kde-frameworks/kplotting-${KFMIN}:5
>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
>=kde-frameworks/kxmlgui-${KFMIN}:5
sci-libs/cfitsio:=
sci-libs/gsl:=
>=sci-libs/indilib-2.0.2
sci-libs/libnova:=
>=sci-libs/stellarsolver-2.2
sys-libs/zlib
password? ( dev-libs/qtkeychain:=[qt5(+)] )
raw? ( media-libs/libraw:= )
wcs? ( sci-astronomy/wcslib:= )
"
# TODO: Add back when re-enabled by upstream
# opengl? (
# >=dev-qt/qtopengl-${QTMIN}:5
# virtual/opengl
# )
DEPEND="${COMMON_DEPEND}
dev-cpp/eigen:3
>=dev-qt/qtconcurrent-${QTMIN}:5
test? ( sci-astronomy/erfa )
"
RDEPEND="${COMMON_DEPEND}
>=dev-qt/qtgraphicaleffects-${QTMIN}:5
>=dev-qt/qtpositioning-${QTMIN}:5
>=dev-qt/qtquickcontrols-${QTMIN}:5
>=dev-qt/qtquickcontrols2-${QTMIN}:5
"
CMAKE_SKIP_TESTS=(
# bug 842768, test declared unstable by upstream
TestKSPaths
# bugs 923871, 939788
TestPlaceholderPath # ki18n (KLocalizedString) failure
# all fail with offscreen plugin
TestEkos{Capture,FilterWheel,Focus,Mount,Scheduler{,Ops},Simulator}
)
src_configure() {
local mycmakeargs=(
-DCMAKE_DISABLE_FIND_PACKAGE_LibXISF=ON # not packaged
-DBUILD_DOC=$(usex handbook)
$(cmake_use_find_package password Qt5Keychain)
$(cmake_use_find_package raw LibRaw)
$(cmake_use_find_package wcs WCSLIB)
)
ecm_src_configure
}
src_test() {
LC_NUMERIC="C" LC_TIME="C" TZ=UTC ecm_src_test
}
pkg_postinst() {
if [[ -z "${REPLACING_VERSIONS}" ]]; then
optfeature "Display 'current' pictures of planets" x11-misc/xplanet
fi
ecm_pkg_postinst
}
|
GitWeb