blob: 2c5c0faafa31a52bb4b159fa52e689a939420b5a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ECM_TEST="forceoptional"
KF5MIN=5.113.0
KFMIN=5.249.0
QT5MIN=5.15.9
QTMIN=6.6.0
VIRTUALDBUS_TEST="true"
inherit ecm gear.kde.org multibuild
DESCRIPTION="Administer web accounts for the sites and services across the Plasma desktop"
HOMEPAGE="https://community.kde.org/KTp"
LICENSE="LGPL-2.1"
SLOT="6"
KEYWORDS=""
IUSE="qt5"
# bug #549444
RESTRICT="test"
COMMON_DEPEND="
>=dev-qt/qtbase-${QTMIN}:6[gui,widgets]
>=dev-qt/qtdeclarative-${QTMIN}:6
>=kde-frameworks/kconfig-${KFMIN}:6
>=kde-frameworks/kcoreaddons-${KFMIN}:6
>=kde-frameworks/kdbusaddons-${KFMIN}:6
>=kde-frameworks/kdeclarative-${KFMIN}:6
>=kde-frameworks/ki18n-${KFMIN}:6
>=kde-frameworks/kio-${KFMIN}:6
>=kde-frameworks/kpackage-${KFMIN}:6
>=kde-frameworks/kwallet-${KFMIN}:6
>=net-libs/accounts-qt-1.16_p20220803[qt5?,qt6]
>=net-libs/signond-8.61-r100[qt5?,qt6]
qt5? (
>=dev-qt/qtdeclarative-${QT5MIN}:5
>=dev-qt/qtgui-${QT5MIN}:5
>=dev-qt/qtwidgets-${QT5MIN}:5
>=kde-frameworks/kconfig-${KF5MIN}:5
>=kde-frameworks/kcoreaddons-${KF5MIN}:5
>=kde-frameworks/kdbusaddons-${KF5MIN}:5
>=kde-frameworks/kdeclarative-${KF5MIN}:5
>=kde-frameworks/ki18n-${KF5MIN}:5
>=kde-frameworks/kio-${KF5MIN}:5
>=kde-frameworks/kwallet-${KF5MIN}:5
)
"
DEPEND="${COMMON_DEPEND}
dev-libs/qcoro
>=kde-frameworks/kcmutils-${KFMIN}:6
kde-plasma/kde-cli-tools:*
qt5? (
dev-libs/qcoro5
>=kde-frameworks/kcmutils-${KF5MIN}:5
)
"
# KAccountsMacros.cmake needs intltool
RDEPEND="${COMMON_DEPEND}
dev-util/intltool
"
BDEPEND="
>=kde-frameworks/kpackage-${KFMIN}:6
sys-devel/gettext
qt5? ( >=kde-frameworks/kpackage-${KF5MIN}:5 )
"
pkg_setup() {
MULTIBUILD_VARIANTS=( $(usev qt5) default )
}
src_configure() {
my_src_configure() {
if [[ ${MULTIBUILD_VARIANT} == qt5 ]]; then
local mycmakeargs=( -DKF6_COMPAT_BUILD=ON )
fi
ecm_src_configure
}
multibuild_foreach_variant my_src_configure
}
src_compile() {
multibuild_foreach_variant cmake_src_compile
}
src_test() {
multibuild_foreach_variant ecm_src_test
}
src_install() {
multibuild_foreach_variant ecm_src_install
}
|
GitWeb