x11-libs/qscintilla: EAPI-7, qmake-utils, drop qt4-r2, SLOT="0-qt4"

Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 32 insertions, 27 deletions

diff --git a/x11-libs/qscintilla/qscintilla-2.4-r1.ebuild b/x11-libs/qscintilla/qscintilla-2.4-r2.ebuild
index 6b21dc52..af90cb3d 100644
--- a/x11-libs/qscintilla/qscintilla-2.4-r1.ebuild
+++ b/x11-libs/qscintilla/qscintilla-2.4-r2.ebuild
@@ -1,71 +1,76 @@
 # Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=2
+EAPI=7
 
 MY_P="QScintilla-gpl-${PV/_pre/-snapshot-}"
-inherit eutils multilib qt4-r2
+inherit qmake-utils
 
 DESCRIPTION="Qt port of Neil Hodgson's Scintilla C++ editor class"
 HOMEPAGE="https://riverbankcomputing.com/software/qscintilla/intro"
 SRC_URI="https://www.riverbankcomputing.co.uk/static/Downloads/QScintilla2/${MY_P}.tar.gz
 mirror://kde-sunset/${MY_P}.tar.gz"
+S="${WORKDIR}"/${MY_P}
 
 LICENSE="|| ( GPL-2 GPL-3 )"
-SLOT="0"
+SLOT="0-qt4"
 KEYWORDS="amd64 ~hppa ~ppc ~ppc64 ~sparc x86"
 IUSE="doc"
 
-RDEPEND="dev-qt/qtgui:4"
-DEPEND="${RDEPEND}"
+DEPEND="dev-qt/qtgui:4"
+RDEPEND="${DEPEND}
+	!<x11-libs/qscintilla-2.4-r2:0
+"
 
-S="${WORKDIR}"/${MY_P}
+DOCS=( ChangeLog NEWS )
 
 PATCHES=( "${FILESDIR}/${PN}-2.4-designer.patch" )
 
 src_configure() {
-	cd "${S}"/Qt4
+	cd "${S}"/Qt4 || die
 	eqmake4 qscintilla.pro
 
-	cd "${S}"/designer-Qt4
+	cd "${S}"/designer-Qt4 || die
 	eqmake4 designer.pro
 }
 
 src_compile() {
-	cd "${S}"/Qt4
-	emake all staticlib || die "emake failed"
+	cd "${S}"/Qt4 || die
+	emake all staticlib
 
-	cd "${S}"/designer-Qt4
-	emake || die "failed to build designer plugin"
+	cd "${S}"/designer-Qt4 || die
+	emake
 }
 
 src_install() {
-	cd "${S}"/Qt4
+	einstalldocs
+
+	cd "${S}"/Qt4 || die
 	# header files
 	insinto /usr/include/Qsci
-	doins Qsci/*.h || die
+	doins Qsci/*.h
 	# libraries
-	dolib.so libqscintilla2.so* || die
-	dolib.a libqscintilla2.a || die
+	dolib.so libqscintilla2.so*
+	dolib.a libqscintilla2.a
 	# translations
 	insinto /usr/share/${PN}/translations
-	doins qscintilla_*.qm || die
-	for trans in $(ls -1 qscintilla_*.qm); do
-		dosym /usr/share/${PN}/translations/${trans} \
-			/usr/share/qt4/translations/${trans} || die
+	doins qscintilla_*.qm
+	local qm
+	for qm in $(ls -1 qscintilla_*.qm); do
+		dosym ../../${PN}/translations/${qm} /usr/share/qt4/translations/${qm}
 	done
 
 	# designer plugin
-	cd "${S}"/designer-Qt4
-	emake INSTALL_ROOT="${D}" install || die "designer plugin installation failed"
+	cd "${S}"/designer-Qt4 || die
+	emake INSTALL_ROOT="${D}" install
 
 	# documentation
-	cd "${S}"
-	dodoc ChangeLog NEWS
+	cd "${S}" || die
 	if use doc; then
-		dohtml doc/html-Qt4/* || die
-		insinto /usr/share/doc/${PF}/Scintilla
-		doins doc/Scintilla/* || die
+		docinto html
+		dodoc -r doc/html-Qt4/.
+		docinto Scintilla
+		dodoc -r doc/Scintilla/.
 	fi
 }