1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
|
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
GNOME2_LA_PUNT="yes"
PYTHON_COMPAT=( python{2_7,3_3,3_4,3_5,3_6} )
VALA_USE_DEPEND="vapigen"
inherit gnome2 multilib-minimal python-any-r1 vala
if [[ ${PV} = 9999 ]]; then
inherit gnome2-live
fi
DESCRIPTION="An HTTP library implementation in C"
HOMEPAGE="https://wiki.gnome.org/Projects/libsoup"
LICENSE="LGPL-2+"
SLOT="2.4"
IUSE="debug gssapi +introspection samba ssl test vala"
REQUIRED_USE="vala? ( introspection )"
if [[ ${PV} = 9999 ]]; then
KEYWORDS=""
IUSE="${IUSE} doc"
else
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
fi
RDEPEND="
>=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}]
>=dev-libs/libxml2-2.9.1-r4:2[${MULTILIB_USEDEP}]
>=dev-db/sqlite-3.8.2:3[${MULTILIB_USEDEP}]
>=net-libs/glib-networking-2.38.2[ssl?,${MULTILIB_USEDEP}]
gssapi? ( virtual/krb5[${MULTILIB_USEDEP}] )
introspection? ( >=dev-libs/gobject-introspection-0.9.5:= )
samba? ( net-fs/samba )
"
DEPEND="${RDEPEND}
${PYTHON_DEPS}
>=dev-util/intltool-0.35
>=dev-util/gtk-doc-am-1.20
sys-devel/gettext
>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
test? ( >=dev-libs/glib-2.40:2[${MULTILIB_USEDEP}] )
vala? ( $(vala_depend) )
"
if [[ ${PV} = 9999 ]]; then
DEPEND="${DEPEND}
doc? ( >=dev-util/gtk-doc-1.10 )"
fi
# test? ( www-servers/apache[ssl,apache2_modules_auth_digest,apache2_modules_alias,apache2_modules_auth_basic,
# apache2_modules_authn_file,apache2_modules_authz_host,apache2_modules_authz_user,apache2_modules_dir,
# apache2_modules_mime,apache2_modules_proxy,apache2_modules_proxy_http,apache2_modules_proxy_connect]
# dev-lang/php[apache2,xmlrpc]
# net-misc/curl
# net-libs/glib-networking[ssl])"
RDEPEND="${RDEPEND}
abi_x86_32? (
!<=app-emulation/emul-linux-x86-baselibs-20140508-r8
!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
)
"
src_prepare() {
if [[ ${PV} = 9999 ]]; then
# prevent SOUP_MAINTAINER_FLAGS from getting set
mv .git .git-bck || die
fi
if ! use test; then
# don't waste time building tests (bug #226271)
sed 's/^\(SUBDIRS =.*\)tests\(.*\)$/\1\2/' -i Makefile.am Makefile.in \
|| die "sed failed"
fi
# FIXME: workaround upstream not respecting --without-apache-httpd
sed -e '/check: start-httpd/d' \
-i tests/Makefile.am tests/Makefile.in || die
vala_src_prepare
gnome2_src_prepare
}
src_configure() {
# FIXME: we need addpredict to workaround bug #324779 until
# root cause (bug #249496) is solved
addpredict /usr/share/snmp/mibs/.index
multilib-minimal_src_configure
}
multilib_src_configure() {
# Disable apache tests until they are usable on Gentoo, bug #326957
ECONF_SOURCE=${S} \
gnome2_src_configure \
--disable-static \
--disable-tls-check \
--without-gnome \
--without-apache-httpd \
$(usex debug --enable-debug=yes ' ') \
$(multilib_native_use_with gssapi) \
$(multilib_native_use_enable introspection) \
$(multilib_native_use_enable vala) \
$(use_with samba ntlm-auth '${EPREFIX}'/usr/bin/ntlm_auth)
if multilib_is_native_abi; then
# fix gtk-doc
ln -s "${S}"/docs/reference/html docs/reference/html || die
fi
}
multilib_src_install() {
gnome2_src_install
}
|
GitWeb