app-crypt/libsecret: 0.16 → 0.18

3 files changed, 89 insertions, 7 deletions

diff --git a/app-crypt/libsecret/Manifest b/app-crypt/libsecret/Manifest
new file mode 100644
index 00000000..fea0155d
--- /dev/null
+++ b/app-crypt/libsecret/Manifest
@@ -0,0 +1,11 @@
+-----BEGIN PGP SIGNED MESSAGE-----
+Hash: SHA512
+
+DIST libsecret-0.18.tar.xz 480520 SHA256 0c73aa762dbd1e38ba7b03de350e23ce818cb810b0784375e95ef61e004b02e3 SHA512 5b3b460fe45b780fd4018dbb3b5fcc2c2e775725a8c74f4cfa86c00c643ccc1b29961b7e464c7b01846c5cc16a4bb9819c74016dd6758301ae2f67ab947c35bd WHIRLPOOL 2c3cb1a6a902665b3898a211317316d988791648d1d1f7144160f12376b2110ac99e8c3d3423ceb58a8ea0a3fb50efb42fc458aaa44f3aea52d2a1fab2d959a8
+-----BEGIN PGP SIGNATURE-----
+Version: GnuPG v2.0.22 (GNU/Linux)
+
+iEYEAREKAAYFAlNNoTkACgkQ1fmVwcYIWAa75ACePyTkTcBfCDm7kezFgj+icxFc
+MJEAoMVCTq1dc8KPV+QZ1UtlD84yZGCW
+=D9rC
+-----END PGP SIGNATURE-----
diff --git a/app-crypt/libsecret/libsecret-0.18.ebuild b/app-crypt/libsecret/libsecret-0.18.ebuild
new file mode 100644
index 00000000..7c5a95ab
--- /dev/null
+++ b/app-crypt/libsecret/libsecret-0.18.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="5"
+PYTHON_COMPAT=( python2_{6,7} )
+VALA_MIN_API_VERSION=0.18
+VALA_USE_DEPEND=vapigen
+
+inherit gnome2 python-any-r1 vala virtualx
+
+DESCRIPTION="GObject library for accessing the freedesktop.org Secret Service API"
+HOMEPAGE="https://live.gnome.org/Libsecret"
+
+LICENSE="LGPL-2.1+ Apache-2.0" # Apache-2.0 license is used for tests only
+SLOT="0"
+IUSE="+crypt debug +introspection test vala"
+REQUIRED_USE="vala? ( introspection )"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd"
+
+COMMON_DEPEND="
+	>=dev-libs/glib-2.38:2
+	crypt? ( >=dev-libs/libgcrypt-1.2.2:0= )
+	introspection? ( >=dev-libs/gobject-introspection-1.29 )
+"
+RDEPEND="${COMMON_DEPEND}
+	>=gnome-base/gnome-keyring-3
+"
+# Add ksecrets to RDEPEND when it's added to portage
+DEPEND="${COMMON_DEPEND}
+	dev-libs/libxslt
+	dev-util/gdbus-codegen
+	>=dev-util/gtk-doc-am-1.9
+	>=dev-util/intltool-0.35.0
+	sys-devel/gettext
+	virtual/pkgconfig
+	test? (
+		dev-python/mock
+		introspection? (
+			${PYTHON_DEPS}
+			>=dev-libs/gjs-1.32
+			dev-python/pygobject:3 )
+	)
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	# FIXME: disable failing test
+	sed -e '/test_get_sync);/d' \
+		-e '/test_get_async);/d' \
+		-i "${S}"/libsecret/test-service.c || die
+
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	DOCS="AUTHORS ChangeLog NEWS README"
+	gnome2_src_configure \
+		--enable-manpages \
+		--disable-strict \
+		--disable-coverage \
+		--disable-static \
+		$(use_enable crypt gcrypt) \
+		$(use_enable introspection) \
+		$(use_enable vala)
+}
+
+src_test() {
+	Xemake check
+}
diff --git a/app-crypt/libsecret/libsecret-9999.ebuild b/app-crypt/libsecret/libsecret-9999.ebuild
index 0f7631e5..c36e3a27 100644
--- a/app-crypt/libsecret/libsecret-9999.ebuild
+++ b/app-crypt/libsecret/libsecret-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2013 Gentoo Foundation
+# Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Header: $
 
@@ -7,7 +7,7 @@ PYTHON_COMPAT=( python2_{6,7} )
 VALA_MIN_API_VERSION=0.18
 VALA_USE_DEPEND=vapigen
 
-inherit eutils gnome2 python-any-r1 vala virtualx
+inherit gnome2 python-any-r1 vala virtualx
 if [[ ${PV} = 9999 ]]; then
 	inherit gnome2-live
 fi
@@ -23,12 +23,12 @@ if [[ ${PV} = 9999 ]]; then
 	IUSE="${IUSE} doc"
 	KEYWORDS=""
 else
-	KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd"
+	KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd"
 fi
 
 COMMON_DEPEND="
-	>=dev-libs/glib-2.32.0:2
-	crypt? ( >=dev-libs/libgcrypt-1.2.2:= )
+	>=dev-libs/glib-2.38:2
+	crypt? ( >=dev-libs/libgcrypt-1.2.2:0= )
 	introspection? ( >=dev-libs/gobject-introspection-1.29 )
 "
 RDEPEND="${COMMON_DEPEND}
@@ -38,7 +38,7 @@ RDEPEND="${COMMON_DEPEND}
 DEPEND="${COMMON_DEPEND}
 	dev-libs/libxslt
 	dev-util/gdbus-codegen
-	dev-util/gtk-doc-am
+	>=dev-util/gtk-doc-am-1.9
 	>=dev-util/intltool-0.35.0
 	sys-devel/gettext
 	virtual/pkgconfig
@@ -63,7 +63,7 @@ src_prepare() {
 	# FIXME: disable failing test
 	sed -e '/test_get_sync);/d' \
 		-e '/test_get_async);/d' \
-		-i libsecret/tests/test-service.c || die
+		-i "${S}"/libsecret/test-service.c || die
 
 	if use vala || [[ ${PV} = 9999 ]]; then
 		vala_src_prepare