1 files changed, 68 insertions, 0 deletions
diff --git a/dev-python/pygtk/pygtk-9999.ebuild b/dev-python/pygtk/pygtk-9999.ebuild
new file mode 100644
index 0000000..b320485
--- /dev/null
+++ b/dev-python/pygtk/pygtk-9999.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+inherit autotools flag-o-matic python virtualx gnome2 gnome2-live
+
+DESCRIPTION="GTK+2 bindings for Python"
+HOMEPAGE="http://www.pygtk.org/"
+SRC_URI=""
+
+LICENSE="LGPL-2.1"
+SLOT="2"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples"
+
+RDEPEND=">=dev-libs/glib-2.8.0
+	>=x11-libs/pango-1.16.0
+	>=dev-libs/atk-1.12.0
+	>=x11-libs/gtk+-2.13.6
+	>=gnome-base/libglade-2.5.0
+	>=dev-lang/python-2.4.4-r5
+	>=dev-python/pycairo-1.0.2
+	>=dev-python/pygobject-2.15.5
+	!arm? ( dev-python/numeric )"
+
+DEPEND="${RDEPEND}
+	doc? ( dev-libs/libxslt >=app-text/docbook-xsl-stylesheets-1.70.1 )
+	>=dev-util/pkgconfig-0.9"
+
+DOCS="AUTHORS ChangeLog INSTALL MAPPING NEWS README THREADS TODO"
+PATCHES="${PN}-2.13.0-fix-codegen-location.patch"
+
+pkg_setup() {
+	use hppa && append-flags -ffunction-sections
+	G2CONF="${G2CONF}
+		--enable-thread
+		$(use_enable doc docs)"
+}
+
+src_install() {
+	gnome2_src_install
+
+	if use examples; then
+		rm examples/Makefile*
+		insinto /usr/share/doc/${PF}
+		doins -r examples
+	fi
+}
+
+src_test() {
+	cd tests
+	Xemake check-local || die "tests failed"
+}
+
+pkg_postinst() {
+	python_version
+	python_mod_optimize /usr/$(get_libdir)/python${PYVER}/site-packages/gtk-2.0
+
+	gnome2-live_pkg_postinst
+}
+
+pkg_postrm() {
+	python_version
+	python_mod_cleanup /usr/$(get_libdir)/python*/site-packages/gtk-2.0
+	rm -f "${ROOT}"/usr/$(get_libdir)/python${PYVER}/site-packages/pygtk.{py,pth}
+	alternatives_auto_makesym /usr/$(get_libdir)/python${PYVER}/site-packages/pygtk.py pygtk.py-[0-9].[0-9]
+	alternatives_auto_makesym /usr/$(get_libdir)/python${PYVER}/site-packages/pygtk.pth pygtk.pth-[0-9].[0-9]
+}