[games-util/steam*] new launcher-1.0.0.36; steam-client updates

6 files changed, 281 insertions, 18 deletions

diff --git a/games-util/steam-client-meta/metadata.xml b/games-util/steam-client-meta/metadata.xml
index a5a4470..ef55a25 100644
--- a/games-util/steam-client-meta/metadata.xml
+++ b/games-util/steam-client-meta/metadata.xml
@@ -13,7 +13,7 @@
 		<bugs-to>https://github.com/anyc/steam-overlay</bugs-to>
 	</upstream>
 	<use>
-		<flag name='windows-games'>Pull in app-emulation/wine to play windows-only games</flag>
 		<flag name='flash'>Pull in www-plugins/adobe-flash for the internal browser</flag>
+		<flag name='trayicon'>Enable system tray icon with libappindicator</flag>
 	</use>
 </pkgmetadata>
diff --git a/games-util/steam-client-meta/steam-client-meta-0-r20130312.ebuild b/games-util/steam-client-meta/steam-client-meta-0-r20130314.ebuild
index 2d7a2c8..be0af4a 100644
--- a/games-util/steam-client-meta/steam-client-meta-0-r20130312.ebuild
+++ b/games-util/steam-client-meta/steam-client-meta-0-r20130314.ebuild
@@ -14,7 +14,7 @@ LICENSE="metapackage"
 
 SLOT="0"
 KEYWORDS="-* ~amd64 ~x86"
-IUSE="flash video_cards_intel windows-games"
+IUSE="flash trayicon video_cards_intel windows-games"
 
 RDEPEND="
 		virtual/opengl
@@ -22,6 +22,7 @@ RDEPEND="
 		media-fonts/font-mutt-misc
 		|| ( media-fonts/font-bitstream-100dpi media-fonts/font-adobe-100dpi )
 
+
 		windows-games? ( app-emulation/wine )
 
 		amd64? (
@@ -29,23 +30,32 @@ RDEPEND="
 			>=sys-libs/glibc-2.15[multilib]
 			>=media-libs/libsdl-2.0.0_pre6964:2[abi_x86_32]
 
-			flash? ( www-plugins/adobe-flash[32bit] )
-			video_cards_intel? (
-				>=app-emulation/emul-linux-x86-baselibs-20121202
-				>=app-emulation/emul-linux-x86-gtklibs-20121202
-				>=app-emulation/emul-linux-x86-opengl-20121202
-				>=app-emulation/emul-linux-x86-sdl-20121202
-				>=app-emulation/emul-linux-x86-soundlibs-20121202
+			>=app-emulation/emul-linux-x86-baselibs-20121202
+			>=app-emulation/emul-linux-x86-gtklibs-20121202
+			>=app-emulation/emul-linux-x86-opengl-20121202
+			>=app-emulation/emul-linux-x86-sdl-20121202
+			>=app-emulation/emul-linux-x86-soundlibs-20121202
+			|| (
 				>=app-emulation/emul-linux-x86-xlibs-20121202
+				(
+					x11-libs/libX11[abi_x86_32]
+					x11-libs/libXcomposite[abi_x86_32]
+					x11-libs/libXcursor[abi_x86_32]
+					x11-libs/libXdamage[abi_x86_32]
+					x11-libs/libXext[abi_x86_32]
+					x11-libs/libXfixes[abi_x86_32]
+					media-libs/fontconfig[abi_x86_32]
+					media-libs/freetype[abi_x86_32]
+					x11-libs/libXi[abi_x86_32]
+					x11-libs/libXinerama[abi_x86_32]
+					x11-libs/libXrandr[abi_x86_32]
+					x11-libs/libXrender[abi_x86_32]
 				)
-			!video_cards_intel? (
-				>=app-emulation/emul-linux-x86-baselibs-20121028
-				>=app-emulation/emul-linux-x86-gtklibs-20121028
-				>=app-emulation/emul-linux-x86-opengl-20121028
-				>=app-emulation/emul-linux-x86-sdl-20121028
-				>=app-emulation/emul-linux-x86-soundlibs-20121028
-				>=app-emulation/emul-linux-x86-xlibs-20121028
-				)
+			)
+
+			trayicon? ( =dev-libs/libappindicator-12.10.0-r1[-gtk3,abi_x86_32] )
+
+			flash? ( www-plugins/adobe-flash[32bit] )
 			)
 		x86? (
 			dev-libs/glib:2
@@ -81,6 +91,7 @@ RDEPEND="
 			x11-libs/pango
 			>=x11-libs/pixman-0.24.4
 
+			trayicon? ( =dev-libs/libappindicator-12.10.0-r1[-gtk3] )
 			flash? ( www-plugins/adobe-flash )
 			video_cards_intel? ( >=media-libs/mesa-9 )
 			)"
diff --git a/games-util/steam-client-meta/steam-client-meta-0-r20130316.ebuild b/games-util/steam-client-meta/steam-client-meta-0-r20130316.ebuild
new file mode 100644
index 0000000..8312bae
--- /dev/null
+++ b/games-util/steam-client-meta/steam-client-meta-0-r20130316.ebuild
@@ -0,0 +1,108 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+# Please report bugs/suggestions on: https://github.com/anyc/steam-overlay
+# or come to #gentoo-gamerlay in freenode IRC
+
+DESCRIPTION="Meta package for Valve's native Steam client"
+HOMEPAGE="http://steampowered.com"
+SRC_URI=""
+LICENSE="metapackage"
+
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+IUSE="flash trayicon video_cards_intel"
+
+RDEPEND="
+		virtual/opengl
+
+		media-fonts/font-mutt-misc
+		|| ( media-fonts/font-bitstream-100dpi media-fonts/font-adobe-100dpi )
+
+		amd64? (
+			>=sys-devel/gcc-4.6.0[multilib]
+			>=sys-libs/glibc-2.15[multilib]
+			>=media-libs/libsdl-2.0.0_pre6964:2[abi_x86_32]
+
+			>=app-emulation/emul-linux-x86-baselibs-20121202
+			>=app-emulation/emul-linux-x86-gtklibs-20121202
+			>=app-emulation/emul-linux-x86-opengl-20121202
+			>=app-emulation/emul-linux-x86-sdl-20121202
+			>=app-emulation/emul-linux-x86-soundlibs-20121202
+			|| (
+				>=app-emulation/emul-linux-x86-xlibs-20121202
+				(
+					x11-libs/libX11[abi_x86_32]
+					x11-libs/libXcomposite[abi_x86_32]
+					x11-libs/libXcursor[abi_x86_32]
+					x11-libs/libXdamage[abi_x86_32]
+					x11-libs/libXext[abi_x86_32]
+					x11-libs/libXfixes[abi_x86_32]
+					media-libs/fontconfig[abi_x86_32]
+					media-libs/freetype[abi_x86_32]
+					x11-libs/libXi[abi_x86_32]
+					x11-libs/libXinerama[abi_x86_32]
+					x11-libs/libXrandr[abi_x86_32]
+					x11-libs/libXrender[abi_x86_32]
+				)
+			)
+
+			trayicon? ( >=dev-libs/libappindicator-12.10.0-r1[-gtk3,abi_x86_32] )
+
+			flash? ( www-plugins/adobe-flash[32bit] )
+			)
+		x86? (
+			dev-libs/glib:2
+			dev-libs/libgcrypt
+			dev-libs/nspr
+			dev-libs/nss
+			media-libs/alsa-lib
+			media-libs/fontconfig
+			media-libs/freetype:2
+			media-libs/libjpeg-turbo
+			media-libs/libogg
+			media-libs/libpng:1.2
+			>=media-libs/libsdl-2.0.0_pre6964
+			media-libs/libtheora
+			media-libs/libvorbis
+			media-libs/openal
+			media-sound/pulseaudio
+			net-misc/curl
+			net-print/cups
+			sys-apps/dbus
+			>=sys-devel/gcc-4.6.0
+			>=sys-libs/glibc-2.15
+			>=sys-libs/zlib-1.2.4
+			x11-libs/cairo
+			x11-libs/gdk-pixbuf
+			x11-libs/gtk+:2
+			>=x11-libs/libX11-1.5
+			x11-libs/libXext
+			x11-libs/libXfixes
+			x11-libs/libXi
+			x11-libs/libXrandr
+			x11-libs/libXrender
+			x11-libs/pango
+			>=x11-libs/pixman-0.24.4
+
+			trayicon? ( =dev-libs/libappindicator-12.10.0-r1[-gtk3] )
+			flash? ( www-plugins/adobe-flash )
+			video_cards_intel? ( >=media-libs/mesa-9 )
+			)"
+
+pkg_postinst() {
+	elog "This is only a meta package that pulls in the required"
+	elog "dependencies for the steam client."
+
+	if use flash; then
+		elog ""
+		elog "In order to use flash, link the 32bit libflashplayer.so to"
+		elog "\${STEAM_FOLDER}/ubuntu12_32/plugins/"
+	fi
+
+	ewarn "The steam client and the games are not controlled by"
+	ewarn "portage. Updates are handled by the client itself."
+}
diff --git a/games-util/steam-launcher/Manifest b/games-util/steam-launcher/Manifest
index f552055..1bf8b9c 100644
--- a/games-util/steam-launcher/Manifest
+++ b/games-util/steam-launcher/Manifest
@@ -1 +1,2 @@
 DIST steam_1.0.0.35.tar.gz 2464568 SHA256 73e4f639e396f142d69a543241583445426bf9eb5764f75808044deabff564a7 SHA512 d2ac4c03fb77ad1b4805c452b5e3275b5056ece45ce3162d324f963314a2767ab2b871e6bc125239c9e643c35705014f5d62a2297ec72e4c0ad61e815b1883e2 WHIRLPOOL 8daa83eeb9d395a966635f4a725beb05251b0832fc95587bff8bd951811735cf0ae402d8da97f31efcec4f4a71f1d4e2d687d57017186636ef0a46ab71b62a40
+DIST steam_1.0.0.36.tar.gz 2513304 SHA256 dfbb5cd7bb50515b97a1b1c627b5d709101932f7237eb89557c27f87a21c8545 SHA512 2e6ab3210dc7d881884dc4fb34f874079fb8803f8ba94e85ad0ced0b2997c83b26547de105bbe591ce591a149512d6754ed6659170d0f68a134c7abea19667e4 WHIRLPOOL 71586b1feede291fe267b851e5e7a83e7f98a27e238b2d3adceb268459dc4ea7ae129822e8e1d12b471af947740e843e97143e697bc1ff6cf78585ab65740ac6
diff --git a/games-util/steam-launcher/steam-launcher-1.0.0.35-r1.ebuild b/games-util/steam-launcher/steam-launcher-1.0.0.35-r1.ebuild
index 63fbd12..d3de8d8 100644
--- a/games-util/steam-launcher/steam-launcher-1.0.0.35-r1.ebuild
+++ b/games-util/steam-launcher/steam-launcher-1.0.0.35-r1.ebuild
@@ -37,7 +37,15 @@ RDEPEND="
 
 		amd64? (
 			>=app-emulation/emul-linux-x86-baselibs-20121028
-			>=app-emulation/emul-linux-x86-xlibs-20121028
+			|| (
+				>=app-emulation/emul-linux-x86-xlibs-20121028
+				(
+					x11-libs/libX11[abi_x86_32]
+					x11-libs/libXau[abi_x86_32]
+		                        x11-libs/libxcb[abi_x86_32]
+		                        x11-libs/libXdmcp[abi_x86_32]
+				)
+			)
 			>=sys-devel/gcc-4.6.0[multilib]
 			>=sys-libs/glibc-2.15[multilib]
 			)
diff --git a/games-util/steam-launcher/steam-launcher-1.0.0.36.ebuild b/games-util/steam-launcher/steam-launcher-1.0.0.36.ebuild
new file mode 100644
index 0000000..3fa95d9
--- /dev/null
+++ b/games-util/steam-launcher/steam-launcher-1.0.0.36.ebuild
@@ -0,0 +1,135 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+# Please report bugs/suggestions on: https://github.com/anyc/steam-overlay
+# or come to #gentoo-gamerlay in freenode IRC
+
+inherit eutils gnome2-utils fdo-mime
+
+DESCRIPTION="Supplementary files for Valve's Steam client for Linux"
+HOMEPAGE="http://steampowered.com"
+
+if [[ "${PV}" == "9999" ]] ; then
+	SRC_URI="http://repo.steampowered.com/steam/archive/precise/steam_latest.deb"
+	KEYWORDS=""
+else
+	SRC_URI="http://repo.steampowered.com/steam/archive/precise/steam_${PV}.tar.gz"
+	KEYWORDS="-* ~amd64 ~x86"
+fi
+
+LICENSE="ValveSteamLicense"
+
+RESTRICT="bindist mirror"
+SLOT="0"
+IUSE="-steamruntime"
+
+RDEPEND="
+		app-arch/xz-utils
+		app-shells/bash
+		net-misc/curl
+		|| (
+			gnome-extra/zenity
+			x11-terms/xterm
+			)
+
+		amd64? (
+			>=app-emulation/emul-linux-x86-baselibs-20121028
+			|| (
+				>=app-emulation/emul-linux-x86-xlibs-20121028
+				(
+					x11-libs/libX11[abi_x86_32]
+					x11-libs/libXau[abi_x86_32]
+		                        x11-libs/libxcb[abi_x86_32]
+		                        x11-libs/libXdmcp[abi_x86_32]
+				)
+			)
+			>=sys-devel/gcc-4.6.0[multilib]
+			>=sys-libs/glibc-2.15[multilib]
+			)
+		x86? (
+			>=sys-devel/gcc-4.6.0
+			>=sys-libs/glibc-2.15
+			>=x11-libs/libX11-1.5
+			x11-libs/libXau
+			x11-libs/libxcb
+			x11-libs/libXdmcp
+			)"
+
+S=${WORKDIR}/steam/
+
+src_prepare() {
+	if [[ "${PV}" != "9999" ]] ; then
+		if ! use steamruntime; then
+			# use system libraries
+			sed -i -r 's/#(if \[ -z "\$STEAM_RUNTIME" \]; then)/\1/' steam
+			sed -i -r "s/#	STEAM_RUNTIME=1/ export STEAM_RUNTIME=0/" steam
+			sed -i -r "s/#(fi)/\1/" steam
+		fi
+
+		# we use our ebuild functions to install the files
+		rm Makefile
+	fi
+}
+
+src_install() {
+	dobin steam
+
+	insinto /usr/lib/steam/
+	doins bootstraplinux_ubuntu12_32.tar.xz
+
+	dodoc debian/changelog steam_install_agreement.txt
+	doman steam.6
+
+	domenu steam.desktop
+
+	cd icons/
+	for s in * ; do
+		doicon -s ${s} ${s}/steam.png
+	done
+	
+	# tgz archive contains no separate pixmap, see #38
+	insinto /usr/share/pixmaps/
+	newins 48/steam.png steam_tray_mono.png
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+
+	elog "Execute /usr/bin/steam to download and install the actual"
+	elog "client into your home folder. After installation, the script"
+	elog "also starts the client from your home folder."
+	elog ""
+
+	if use steamruntime; then
+		ewarn "You enabled the steam runtime environment. Steam will use bundled"
+		ewarn "libraries instead of system libraries which is _not_ supported."
+		ewarn ""
+	else
+		elog "We disable STEAM_RUNTIME in order to ignore bundled libraries"
+		elog "and use installed system libraries instead. If you have problems,"
+		elog "try starting steam with: STEAM_RUNTIME=1 steam"
+		elog ""
+	fi
+
+	if ! has_version "gnome-extra/zenity"; then
+		ewarn "Valve does not provide a xterm fallback for all calls of zenity."
+		ewarn "Please install gnome-extra/zenity for full support."
+		ewarn ""
+	fi
+
+	ewarn "The steam client and the games are _not_ controlled by portage."
+	ewarn "Updates are handled by the client itself."
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}