path: root/editcomponents.cgi

#!/usr/bin/perl -T
# This Source Code Form is subject to the terms of the Mozilla Public
# License, v. 2.0. If a copy of the MPL was not distributed with this
# file, You can obtain one at http://mozilla.org/MPL/2.0/.
#
# This Source Code Form is "Incompatible With Secondary Licenses", as
# defined by the Mozilla Public License, v. 2.0.

use 5.10.1;
use strict;
use warnings;

use lib qw(. lib);

use Bugzilla;
use Bugzilla::Constants;
use Bugzilla::Util;
use Bugzilla::Error;
use Bugzilla::User;
use Bugzilla::Component;
use Bugzilla::Token;

my $cgi      = Bugzilla->cgi;
my $template = Bugzilla->template;
my $vars     = {};

# There is only one section about components in the documentation,
# so all actions point to the same page.
$vars->{'doc_section'} = 'administering/categorization.html#components';

#
# Preliminary checks:
#

my $user = Bugzilla->login(LOGIN_REQUIRED);

print $cgi->header();

$user->in_group('editcomponents')
  || scalar(@{$user->get_products_by_permission('editcomponents')})
  || ThrowUserError("auth_failure",
  {group => "editcomponents", action => "edit", object => "components"});

#
# often used variables
#
my $product_name = trim($cgi->param('product')   || '');
my $comp_name    = trim($cgi->param('component') || '');
my $action       = trim($cgi->param('action')    || '');
my $showbugcounts = (defined $cgi->param('showbugcounts'));
my $token         = $cgi->param('token');

## REDHAT EXTENSION START 462305 1067210
sub load_product_data {
  my ($product_name, $showbugcounts) = @_;

  my $dbh = Bugzilla->dbh;

  my $query = q{
        SELECT c.id,
            c.name,
            c.description,
            c.initialowner,
            c.initialqacontact,
            c.initialdocscontact,
            devel.login_name AS default_assignee,
            qa.login_name AS default_qa_contact,
            docs.login_name AS default_docs_contact,
            c.isactive,
            c.default_to_private,
            CASE WHEN sc.sub_component_count IS NULL
                THEN 'Add'
                ELSE CONCAT('Edit (', sc.sub_component_count, ')')
            END AS sub_component_string,
       } . $dbh->sql_group_concat('ccu.login_name') . q{ AS initial_cc_names
        FROM components c
            LEFT JOIN component_cc cc ON c.id = cc.component_id
            LEFT JOIN products p ON c.product_id = p.id
            LEFT JOIN profiles ccu ON cc.user_id = ccu.userid
            LEFT JOIN profiles docs ON c.initialdocscontact = docs.userid
            LEFT JOIN profiles qa ON c.initialqacontact = qa.userid
            LEFT JOIN profiles devel ON c.initialowner = devel.userid
            LEFT JOIN (SELECT component_id, COUNT(*) AS sub_component_count
                       FROM rh_sub_components
                       GROUP BY component_id
                  ) AS sc ON sc.component_id = c.id
        WHERE p.name = ?
        GROUP BY c.id,
            c.name,
            c.description,
            c.initialowner,
            c.initialqacontact,
            c.initialdocscontact,
            c.isactive,
            devel.login_name,
            qa.login_name,
            docs.login_name,
            sc.sub_component_count
    };

  trick_taint($product_name);

  my $components
    = $dbh->selectall_arrayref($query, {'Slice' => {}}, $product_name);

  if ($showbugcounts) {
    ## REDHAT EXTENSION BEGIN 584957
    $query = q{
            SELECT component_id, COUNT(DISTINCT bug_id) AS bug_count
            FROM (
                SELECT b.bug_id, b.component_id
                FROM bugs AS b
                    JOIN products AS p ON b.product_id = p.id
                WHERE p.name = ?
                UNION ALL
                SELECT b.bug_id, c.id AS component_id
                FROM bugs b
                    JOIN rh_multiple_bug_components mbc USING ( bug_id )
                    JOIN components c ON (c.id = mbc.component_id)
                    JOIN products p ON (c.product_id = p.id)
                WHERE p.name = ?
            ) AS every_derived_table_must_have_its_own_alias
            GROUP BY component_id
        };
    ## REDHAT EXTENSION END 584957
    my $count_arr = $dbh->selectcol_arrayref($query, {Columns => [1, 2]},
      $product_name, $product_name);
    my %counts = @$count_arr;

    foreach my $component (@$components) {
      $component->{bug_count}
        = defined $counts{$component->{id}} ? $counts{$component->{id}} : 0;
    }
  }


  return {name => $product_name, components => $components,};
}
## REDHAT EXTENSION END 462305 1067210

#
# product = '' -> Show nice list of products
#

unless ($product_name) {
  my $selectable_products = $user->get_selectable_products;

  # If the user has editcomponents privs for some products only,
  # we have to restrict the list of products to display.
  unless ($user->in_group('editcomponents')) {
    $selectable_products = $user->get_products_by_permission('editcomponents');
  }
  $vars->{'products'}      = $selectable_products;
  $vars->{'showbugcounts'} = $showbugcounts;

  $template->process("admin/components/select-product.html.tmpl", $vars)
    || ThrowTemplateError($template->error());
  exit;
}

my $product = $user->check_can_admin_product($product_name);

#
# action='' -> Show nice list of components
#

unless ($action) {
  $vars->{'showbugcounts'} = $showbugcounts;
  $vars->{'product'}       = load_product_data($product_name, $showbugcounts);
  $template->process("admin/components/list.html.tmpl", $vars)
    || ThrowTemplateError($template->error());
  exit;
}

#
# action='add' -> present form for parameters for new component
#
# (next action will be 'new')
#

if ($action eq 'add') {
  ## REDHAT EXTENSION START 460258
  $vars->{comp}{bvp_template_id} = Bugzilla->default_template_id;
  ## REDHAT EXTENSION END 460258

  $vars->{'token'}   = issue_session_token('add_component');
  $vars->{'product'} = $product;
  $template->process("admin/components/create.html.tmpl", $vars)
    || ThrowTemplateError($template->error());
  exit;
}

#
# action='new' -> add component entered in the 'action=add' screen
#

if ($action eq 'new') {
  check_token_data($token, 'add_component');

  # Do the user matching
  Bugzilla::User::match_field({
    'initialowner'     => {'type' => 'single'},
    'initialqacontact' => {'type' => 'single'},
    ## REDHAT EXTENSION 876015: Add initialdocscontact
    'initialdocscontact' => {'type' => 'single'},
    'initialcc'          => {'type' => 'multi'},
  });

  my $default_assignee   = trim($cgi->param('initialowner')     || '');
  my $default_qa_contact = trim($cgi->param('initialqacontact') || '');
  ## REDHAT EXTENSION 876015: Add default_docs_contact
  my $default_docs_contact = trim($cgi->param('initialdocscontact') || '');
  my $description          = trim($cgi->param('description')        || '');
  my @initial_cc           = $cgi->param('initialcc');
  my $isactive             = $cgi->param('isactive');
  ## REDHAT EXTENSION 460258: Add bvp_template_id
  my $bvp_template_id = $cgi->param('bvp_template_id');

  my $default_pool = $cgi->param('default_pool');    ## RED HAT EXTENSION 1613297
  my $agile_team   = $cgi->param('agile_team');      ## RED HAT EXTENSION 1622371

  my $component = Bugzilla::Component->create({
    name             => $comp_name,
    product          => $product,
    description      => $description,
    initialowner     => $default_assignee,
    initialqacontact => $default_qa_contact,
    ## REDHAT EXTENSION 876015: Add initialdocscontact
    initialdocscontact => $default_docs_contact,
    initial_cc         => \@initial_cc,

    # XXX We should not be creating series for products that we
    # didn't create series for.
    create_series => 1,
    ## REDHAT EXTENSION 460258: Add bvp_template_id
    bvp_template_id => $bvp_template_id,
    default_pool    => $default_pool,      ## RED HAT EXTENSION 1613297
    agile_team      => $agile_team,        ## RED HAT EXTENSION 1622371
  });

  $vars->{'message'} = 'component_created';
  $vars->{'comp'}    = $component;
  $vars->{'product'} = load_product_data($product_name, $showbugcounts);
  delete_token($token);

  $template->process("admin/components/list.html.tmpl", $vars)
    || ThrowTemplateError($template->error());
  exit;
}

#
# action='del' -> ask if user really wants to delete
#
# (next action would be 'delete')
#

if ($action eq 'del') {
  $vars->{'token'} = issue_session_token('delete_component');
  $vars->{'comp'}
    = Bugzilla::Component->check({product => $product, name => $comp_name});
  $vars->{'product'} = $product;

  $template->process("admin/components/confirm-delete.html.tmpl", $vars)
    || ThrowTemplateError($template->error());
  exit;
}

#
# action='delete' -> really delete the component
#

if ($action eq 'delete') {
  check_token_data($token, 'delete_component');
  my $component
    = Bugzilla::Component->check({product => $product, name => $comp_name});

  $component->remove_from_db;

  $vars->{'message'} = 'component_deleted';
  $vars->{'comp'}    = $component;
  $vars->{'product'} = load_product_data($product_name, $showbugcounts);
  $vars->{'no_edit_component_link'} = 1;
  delete_token($token);

  $template->process("admin/components/list.html.tmpl", $vars)
    || ThrowTemplateError($template->error());
  exit;
}

#
# action='edit' -> present the edit component form
#
# (next action would be 'update')
#

if ($action eq 'edit') {
  $vars->{'token'} = issue_session_token('edit_component');
  my $component
    = Bugzilla::Component->check({product => $product, name => $comp_name});
  $vars->{'comp'} = $component;

  $vars->{'initial_cc_names'}
    = join(', ', map($_->login, @{$component->initial_cc}));

  $vars->{'product'} = $product;

  $template->process("admin/components/edit.html.tmpl", $vars)
    || ThrowTemplateError($template->error());
  exit;
}

#
# action='update' -> update the component
#

if ($action eq 'update') {
  check_token_data($token, 'edit_component');

  # Do the user matching
  Bugzilla::User::match_field({
    'initialowner'     => {'type' => 'single'},
    'initialqacontact' => {'type' => 'single'},
    ## REDHAT EXTENSION 876015: Add initialdocscontact
    'initialdocscontact' => {'type' => 'single'},
    'initialcc'          => {'type' => 'multi'},
  });

  my $comp_old_name      = trim($cgi->param('componentold')     || '');
  my $default_assignee   = trim($cgi->param('initialowner')     || '');
  my $default_qa_contact = trim($cgi->param('initialqacontact') || '');
  ## REDHAT EXTENSION 876015: Add default_docs_contact
  my $default_docs_contact = trim($cgi->param('initialdocscontact') || '');
  my $description          = trim($cgi->param('description')        || '');
  my @initial_cc           = $cgi->param('initialcc');
  my $isactive             = $cgi->param('isactive');
  ## REDHAT EXTENSION 460258: Add bvp_template_id
  my $bvp_template_id = $cgi->param('bvp_template_id');
  my $default_pool = $cgi->param('default_pool');    ## RED HAT EXTENSION 1613297
  my $agile_team   = $cgi->param('agile_team');      ## RED HAT EXTENSION 1622371

  my $component
    = Bugzilla::Component->check({product => $product, name => $comp_old_name});

  $component->set_name($comp_name);
  $component->set_description($description);
  $component->set_default_assignee($default_assignee);
  $component->set_default_qa_contact($default_qa_contact);
  ## REDHAT EXTENSION 876015: Add default_docs_contact
  $component->set_default_docs_contact($default_docs_contact);
  $component->set_cc_list(\@initial_cc);
  $component->set_is_active($isactive);
  ## REDHAT EXTENSION 460258 1326981: Add bvp_template_id
  $component->set_template_id($bvp_template_id);
  $component->set_default_pool($default_pool);    ## RED HAT EXTENSION 1613297
  $component->set_agile_team($agile_team);        ## RED HAT EXTENSION 1622371

## REDHAT EXTENSION BEGIN 1326559
  $component->set_always_cc(scalar $cgi->param('always_cc'));
## REDHAT EXTENSION END 1326559

  ## REDHAT EXTENSION BEGIN 1937776
  $component->set_default_to_private(scalar $cgi->param('default_to_private'));
  ## REDHAT EXTENSION END 1937776

  my $changes = $component->update();

  $vars->{'message'} = 'component_updated';
  $vars->{'comp'}    = $component;
  $vars->{'product'} = load_product_data($product_name, $showbugcounts);
  $vars->{'changes'} = $changes;
  delete_token($token);

  $template->process("admin/components/list.html.tmpl", $vars)
    || ThrowTemplateError($template->error());
  exit;
}

# No valid action found
ThrowUserError('unknown_action', {action => $action});