blob: 3c1bfaf211c7cf48600be08370eaee6ea1ea6207 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-wireless/gnome-bluetooth/gnome-bluetooth-3.10.0.ebuild,v 1.5 2014/03/09 12:04:08 pacho Exp $
EAPI="5"
GCONF_DEBUG="yes"
inherit eutils gnome2 udev user
DESCRIPTION="Bluetooth graphical utilities integrated with GNOME"
HOMEPAGE="https://wiki.gnome.org/GnomeBluetooth"
LICENSE="GPL-2+ LGPL-2.1+ FDL-1.1+"
SLOT="2/12" # subslot = libgnome-bluetooth soname version
IUSE="+introspection"
KEYWORDS="amd64 ~arm ~ppc ~ppc64 x86"
COMMON_DEPEND="
>=dev-libs/glib-2.37.3:2
>=x11-libs/gtk+-2.91.3:3[introspection?]
virtual/udev
introspection? ( >=dev-libs/gobject-introspection-0.9.5 )
"
RDEPEND="${COMMON_DEPEND}
>=net-wireless/bluez-5
app-mobilephone/obexd
x11-themes/gnome-icon-theme-symbolic
"
DEPEND="${COMMON_DEPEND}
!net-wireless/bluez-gnome
app-text/docbook-xml-dtd:4.1.2
dev-libs/libxml2:2
dev-util/gdbus-codegen
>=dev-util/gtk-doc-am-1.9
>=dev-util/intltool-0.40.0
virtual/pkgconfig
x11-libs/libX11
x11-libs/libXi
x11-proto/xproto
"
# eautoreconf needs:
# gnome-base/gnome-common
pkg_setup() {
enewgroup plugdev
}
src_prepare() {
# Regenerate gdbus-codegen files to allow using any glib version; bug #436236
rm -v lib/bluetooth-client-glue.{c,h} || die
gnome2_src_prepare
}
src_configure() {
gnome2_src_configure \
$(use_enable introspection) \
--enable-documentation \
--disable-desktop-update \
--disable-icon-update \
--disable-static \
ITSTOOL=$(type -P true)
}
src_install() {
gnome2_src_install
udev_dorules "${FILESDIR}"/61-${PN}.rules
}
pkg_postinst() {
gnome2_pkg_postinst
if ! has_version sys-auth/consolekit[acl] && ! has_version sys-apps/systemd[acl] ; then
elog "Don't forget to add yourself to the plugdev group "
elog "if you want to be able to control bluetooth transmitter."
fi
}
|
GitWeb
