blob: 5c04cd4fac01d534ad2b9ba8fd20265841f6d31a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
|
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/rygel/rygel-0.18.3.ebuild,v 1.2 2013/09/08 17:19:38 eva Exp $
EAPI="5"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"
inherit gnome2 virtualx
DESCRIPTION="Rygel is an open source UPnP/DLNA MediaServer"
HOMEPAGE="http://live.gnome.org/Rygel"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="X nls +sqlite tracker test transcode"
# The deps for tracker? and transcode? are just the earliest available
# version at the time of writing this ebuild
RDEPEND="
>=dev-libs/glib-2.32:2
>=dev-libs/libgee-0.8:0.8
>=dev-libs/libxml2-2.7:2
>=media-libs/gupnp-dlna-0.9.4:2.0
media-libs/gstreamer:1.0
media-libs/gst-plugins-base:1.0
media-plugins/gst-plugins-soup:1.0
>=net-libs/gssdp-0.13
>=net-libs/gupnp-0.19
>=net-libs/gupnp-av-0.11.4
>=net-libs/libsoup-2.34:2.4
>=sys-apps/util-linux-2.20
x11-misc/shared-mime-info
sqlite? (
>=dev-db/sqlite-3.5:3
dev-libs/libunistring
)
tracker? ( >=app-misc/tracker-0.14:= )
transcode? (
media-libs/gst-plugins-bad:1.0
media-plugins/gst-plugins-twolame:1.0
media-plugins/gst-plugins-libav:1.0
)
X? ( >=x11-libs/gtk+-2.90.3:3 )
"
DEPEND="${RDEPEND}
dev-util/gtk-doc-am
>=dev-util/intltool-0.40
sys-devel/gettext
virtual/pkgconfig
"
# Maintainer only
# >=dev-lang/vala-0.18
# dev-libs/libxslt
src_prepare() {
# runs gst-plugins-scanner on run with triggers sandbox violation
# trying to open dri
sed -e 's/rygel-media-engine-test$(EXEEXT)//' \
-e 's/rygel-playbin-renderer-test$(EXEEXT)//' \
-i tests/Makefile.in || die
gnome2_src_prepare
}
src_configure() {
# We defined xsltproc because man pages are provided by upstream
# and we do not want to regenerate them automagically.
gnome2_src_configure \
XSLTPROC=$(type -P false) \
--disable-valadoc \
--enable-gst-launch-plugin \
--enable-mediathek-plugin \
--with-media-engine=gstreamer \
$(use_enable nls) \
$(use_enable sqlite media-export-plugin) \
$(use_enable test tests) \
$(use_enable tracker tracker-plugin) \
$(use_with X ui)
}
src_install() {
gnome2_src_install
# Autostart file is not placed correctly, bug #402745
insinto /etc/xdg/autostart
doins "${D}"/usr/share/applications/rygel.desktop
rm "${D}"/usr/share/applications/rygel.desktop
}
|
GitWeb