net-analyzer/nb/nb-0.8.17.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/nb/nb-0.8.17.ebuild,v 1.1 2014/08/15 08:55:03 jer Exp $

EAPI=5
inherit autotools eutils

DESCRIPTION="Nodebrain is a tool to monitor and do event correlation"
HOMEPAGE="http://nodebrain.sourceforge.net/"
SRC_URI="mirror://sourceforge/nodebrain/nodebrain-${PV}.tar.gz"

LICENSE="GPL-2 LGPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="static-libs"

CDEPEND="dev-libs/libedit"
DEPEND="
	${CDEPEND}
	dev-lang/perl
	virtual/pkgconfig
	sys-apps/texinfo
"
RDEPEND="
	${CDEPEND}
	!sys-boot/netboot
	!www-apps/nanoblogger
"

S="${WORKDIR}/nodebrain-${PV}"

src_prepare() {
	# fdl.texi is not included in the sources
	sed -i \
		-e '/@include fdl.texi/d' \
		doc/nbTutorial/nbTutorial.texi || die

	epatch "${FILESDIR}"/${PN}-0.8.14-include.patch

	eautoreconf
}

src_configure() {
	econf \
		$(use_enable static-libs static) \
		--include=/usr/include
}

src_compile() {
	# Fails at parallel make
	emake -j1
}

src_install() {
	default
	use static-libs || prune_libtool_files
	dodoc AUTHORS NEWS README THANKS sample/*
	dohtml html/*
}