blob: 827de980a8af799c70020cd87fada76cc8bba946 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
|
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libvpx/libvpx-9999.ebuild,v 1.35 2013/06/25 17:02:49 aballier Exp $
EAPI=4
inherit multilib toolchain-funcs flag-o-matic multilib-minimal
if [[ ${PV} == *9999* ]]; then
inherit git-2
EGIT_REPO_URI="http://git.chromium.org/webm/${PN}.git"
KEYWORDS=""
elif [[ ${PV} == *pre* ]]; then
SRC_URI="mirror://gentoo/${P}.tar.bz2"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
else
SRC_URI="http://webm.googlecode.com/files/${PN}-v${PV}.tar.bz2"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
S="${WORKDIR}/${PN}-v${PV}"
fi
DESCRIPTION="WebM VP8 Codec SDK"
HOMEPAGE="http://www.webmproject.org"
LICENSE="BSD"
SLOT="0"
IUSE="altivec debug doc mmx postproc sse sse2 sse3 ssse3 sse4_1 static-libs +threads"
RDEPEND="abi_x86_32? ( !<=app-emulation/emul-linux-x86-medialibs-20130224 )"
DEPEND="abi_x86_32? ( dev-lang/yasm )
abi_x86_64? ( dev-lang/yasm )
x86-fbsd? ( dev-lang/yasm )
amd64-fbsd? ( dev-lang/yasm )
doc? (
app-doc/doxygen
dev-lang/php
)
"
REQUIRED_USE="
sse2? ( mmx )
ssse3? ( sse2 )
"
multilib_src_configure() {
replace-flags -ggdb3 -g #402825
unset CODECS #357487
# let the build system decide which AS to use (it honours $AS but
# then feeds it with yasm flags without checking...) #345161
tc-export AS
case "${CHOST}" in
i?86*) export AS=yasm;;
x86_64*) export AS=yasm;;
esac
# build verbose by default
MAKEOPTS="${MAKEOPTS} verbose=yes"
# do not build examples that will not be installed
MAKEOPTS="${MAKEOPTS} GEN_EXAMPLES="
# http://bugs.gentoo.org/show_bug.cgi?id=384585
addpredict /usr/share/snmp/mibs/.index
# Build with correct toolchain.
tc-export CC CXX AR NM
# Link with gcc by default, the build system should override this if needed.
export LD="${CC}"
local myconf
if [ "${ABI}" = "${DEFAULT_ABI}" ] ; then
myconf+=" $(use_enable doc install-docs) $(use_enable doc docs)"
else
# not needed for multilib and will be overwritten anyway.
myconf+=" --disable-examples --disable-install-docs --disable-docs"
fi
"${S}/configure" \
--prefix="${EPREFIX}"/usr \
--libdir="${EPREFIX}"/usr/$(get_libdir) \
--enable-pic \
--enable-vp8 \
--enable-shared \
--extra-cflags="${CFLAGS}" \
$(use_enable altivec) \
$(use_enable debug debug-libs) \
$(use_enable debug) \
$(use_enable mmx) \
$(use_enable postproc) \
$(use_enable sse) \
$(use_enable sse2) \
$(use_enable sse3) \
$(use_enable sse4_1) \
$(use_enable ssse3) \
$(use_enable static-libs static) \
$(use_enable threads multithread) \
${myconf} \
|| die
}
|
GitWeb