games-strategy/warzone2100/warzone2100-2.0.4.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-strategy/warzone2100/warzone2100-2.0.4.ebuild,v 1.2 2006/09/26 14:49:08 wolf31o2 Exp $

inherit debug eutils versionator games

MY_PV=$(get_version_component_range -2)
DESCRIPTION="3D real-time strategy game"
HOMEPAGE="http://wz2100.net/"
SRC_URI="http://download.gna.org/warzone/releases/${MY_PV}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
# upstream requested debug support
IUSE="debug mp3"

RDEPEND="dev-games/physfs
	mp3? ( >=media-libs/libmad-0.15 )
	media-libs/jpeg
	media-libs/libogg
	media-libs/libpng
	media-libs/libsdl
	media-libs/libvorbis
	media-libs/openal
	media-libs/sdl-net
	virtual/glu
	virtual/opengl"
DEPEND="${RDEPEND}
	app-arch/zip"

src_unpack() {
	unpack ${A}
	cd "${S}"

	sed -i \
		-e '/FilePattern/d' \
		-e "s/warzone$/${PN}/" \
		debian/${PN}.desktop || die "sed failed"
}

src_compile() {
	egamesconf \
		--disable-dependency-tracking \
		--with-ogg=/usr \
		--with-vorbis=/usr \
		--enable-ogg \
		$(use_enable mp3) \
		$(use_enable debug) \
		|| die "egamesconf failed"

	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	doicon debian/${PN}.png
	domenu debian/${PN}.desktop

	dodoc AUTHORS ChangeLog README TODO
	prepgamesdirs
}