app-editors/ne/ne-1.36.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/ne/ne-1.36.ebuild,v 1.1 2004/08/22 13:37:42 swegener Exp $

inherit eutils

DESCRIPTION="the nice editor, easy to use for the beginner and powerful for the wizard"
HOMEPAGE="http://ne.dsi.unimi.it/"
SRC_URI="http://ne.dsi.unimi.it/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~ppc"
IUSE="ncurses"

DEPEND="ncurses? ( >=sys-libs/ncurses-5.2 )"
PROVIDE="virtual/editor"

src_unpack() {
	unpack ${A}
	cd ${S}

	epatch ${FILESDIR}/${PV}-include-fix.patch
}

src_compile() {
	if use ncurses
	then
		emake -j1 -C src ne CFLAGS="${CFLAGS} -DNODEBUG -D_POSIX_C_SOURCE=199506L" LIBS="-lncurses" || die "emake failed"
	else
		emake -j1 -C src net CFLAGS="${CFLAGS} -DNODEBUG -DTERMCAP -D_POSIX_C_SOURCE=199506L" LIBS="" || die "emake failed"
	fi
}

src_install() {
	gunzip doc/ne.info*.gz || die "gunzip failed"

	dobin src/ne || die "dobin failed"
	doman doc/ne.1 || die "doman failed"
	doinfo doc/*.info* || die "doinfo failed"
	dohtml doc/*.html || die "dohtml failed"
	dodoc \
		CHANGES README \
		doc/*.txt doc/*.ps doc/*.pdf doc/*.texinfo doc/default.* \
		|| die "dodoc failed"
}