app-cdr/backlite/backlite-1.0.3-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-cdr/backlite/backlite-1.0.3-r1.ebuild,v 1.7 2013/07/10 04:43:06 patrick Exp $

EAPI=5

inherit qt4-r2 eutils

DESCRIPTION="backlite is a pure QT4 version of k9copy"
HOMEPAGE="http://k9copy.sourceforge.net/"
SRC_URI="mirror://sourceforge/k9copy/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 x86"
IUSE="mplayer"

# According to the author of backlite/k9copy libdvdread and libdvdnav are
# bundled internal because newer versions produce bad DVD copies.
# This will be fixed later.
# DEPEND="media-libs/libdvdread"

DEPEND=">=media-libs/libmpeg2-0.5.1
	virtual/ffmpeg
	dev-qt/qtgui:4[dbus(+)]
	|| ( dev-qt/qtphonon:4 media-libs/phonon )"

RDEPEND="${DEPEND}
	media-video/dvdauthor
	mplayer? ( media-video/mplayer )"

src_prepare() {
	sed -i -e '/^MimeTypes=.*/d' \
		-e '/^Encoding=.*/d' *.desktop || die
	epatch "${FILESDIR}/${P}-ffmpeg-0.11.patch" \
		"${FILESDIR}/${P}-includepaths.patch"
}

src_configure() {
	eqmake4 backlite.pro PREFIX="${D}"/usr
}

src_install() {
	unset INSTALL_ROOT
	default
}