1 files changed, 46 insertions, 0 deletions
diff --git a/xfce-base/libxfce4ui/libxfce4ui-4.8.0-r1.ebuild b/xfce-base/libxfce4ui/libxfce4ui-4.8.0-r1.ebuild
new file mode 100644
index 000000000000..cddc802364ee
--- /dev/null
+++ b/xfce-base/libxfce4ui/libxfce4ui-4.8.0-r1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/libxfce4ui/libxfce4ui-4.8.0-r1.ebuild,v 1.1 2011/12/11 07:15:59 ssuominen Exp $
+
+EAPI=4
+inherit xfconf
+
+DESCRIPTION="Xfce's unified widgets library"
+HOMEPAGE="http://www.xfce.org/projects/libraries/"
+SRC_URI="mirror://xfce/src/xfce/${PN}/4.8/${P}.tar.bz2"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="debug glade startup-notification vanilla"
+
+RDEPEND="x11-libs/libX11
+	x11-libs/libICE
+	x11-libs/libSM
+	>=dev-libs/glib-2.16:2
+	>=x11-libs/gtk+-2.14:2
+	>=xfce-base/libxfce4util-4.8
+	>=xfce-base/xfconf-4.8
+	glade? ( dev-util/glade:3 )
+	startup-notification? ( x11-libs/startup-notification )"
+DEPEND="${RDEPEND}
+	!<xfce-base/libxfcegui4-4.8
+	dev-util/pkgconfig
+	dev-util/intltool
+	sys-devel/gettext
+	dev-lang/perl"
+
+pkg_setup() {
+	use vanilla || PATCHES=( "${FILESDIR}"/${P}-keyboard-shortcuts.patch ) #392001
+
+	XFCONF=(
+		$(use_enable startup-notification)
+		$(use_enable glade gladeui)
+		$(xfconf_use_debug)
+		--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html
+		)
+
+	[[ ${CHOST} == *-darwin* ]] && XFCONF+=( --disable-visibility ) #366857
+
+	DOCS=( AUTHORS ChangeLog NEWS README THANKS TODO )
+}