1 files changed, 60 insertions, 0 deletions
diff --git a/net-proxy/tsocks/tsocks-1.8_beta5-r6.ebuild b/net-proxy/tsocks/tsocks-1.8_beta5-r6.ebuild
new file mode 100644
index 000000000000..9c926e81beda
--- /dev/null
+++ b/net-proxy/tsocks/tsocks-1.8_beta5-r6.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-proxy/tsocks/tsocks-1.8_beta5-r6.ebuild,v 1.1 2011/11/19 16:24:03 naota Exp $
+
+EAPI="2"
+
+inherit multilib eutils autotools toolchain-funcs
+
+DESCRIPTION="Transparent SOCKS v4 proxying library"
+HOMEPAGE="http://tsocks.sourceforge.net/"
+SRC_URI="mirror://sourceforge/tsocks/${PN}-${PV/_}.tar.gz
+	tordns? ( http://dev.gentoo.org/~naota/patch/${PN}-${PV/_beta/b}-tordns1-gentoo-r2.patch.gz )"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="tordns"
+
+S="${WORKDIR}/${P%%_*}"
+
+src_prepare() {
+	epatch "${FILESDIR}/${P}-gentoo-r3.patch"
+	epatch "${FILESDIR}/${P}-bsd.patch"
+	use tordns && epatch "../${PN}-${PV/_beta/b}-tordns1-gentoo-r2.patch"
+	eautoreconf
+}
+
+src_configure() {
+	tc-export CC
+
+	# NOTE: the docs say to install it into /lib. If you put it into
+	# /usr/lib and add it to /etc/ld.so.preload on many systems /usr isn't
+	# mounted in time :-( (Ben Lutgens) <lamer@gentoo.org>
+	econf \
+		--with-conf=/etc/socks/tsocks.conf \
+		--libdir=/$(get_libdir) || die "configure failed"
+}
+
+src_compile() {
+	# Fix QA notice lack of SONAME
+	emake DYNLIB_FLAGS=-Wl,--soname,libtsocks.so.${PV/_beta*} || die "emake failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "make install failed"
+	newbin validateconf tsocks-validateconf
+	newbin saveme tsocks-saveme
+	dobin inspectsocks
+	insinto /etc/socks
+	doins tsocks.conf.*.example
+	dodoc FAQ
+	use tordns && dodoc README*
+}
+
+pkg_postinst() {
+	einfo "Make sure you create /etc/socks/tsocks.conf from one of the examples in that directory"
+	einfo "The following executables have been renamed:"
+	einfo "    /usr/bin/saveme renamed to tsocks-saveme"
+	einfo "    /usr/bin/validateconf renamed to tsocks-validateconf"
+}