1 files changed, 58 insertions, 0 deletions
diff --git a/net-irc/irssi/irssi-0.8.15_rc1.ebuild b/net-irc/irssi/irssi-0.8.15_rc1.ebuild
new file mode 100644
index 000000000000..f6052ec39e0c
--- /dev/null
+++ b/net-irc/irssi/irssi-0.8.15_rc1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-irc/irssi/irssi-0.8.15_rc1.ebuild,v 1.1 2010/03/22 20:16:58 swegener Exp $
+
+EAPI="2"
+
+inherit perl-module
+
+MY_P="${P/_/-}"
+
+DESCRIPTION="A modular textUI IRC client with IPv6 support"
+HOMEPAGE="http://irssi.org/"
+SRC_URI="http://irssi.org/files/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="ipv6 +perl ssl socks5"
+
+RDEPEND="sys-libs/ncurses
+	>=dev-libs/glib-2.2.1
+	ssl? ( dev-libs/openssl )
+	perl? ( dev-lang/perl )
+	socks5? ( >=net-proxy/dante-1.1.18 )"
+DEPEND="${RDEPEND}
+	>=dev-util/pkgconfig-0.9.0"
+RDEPEND="${RDEPEND}
+	perl? ( !net-im/silc-client )
+	!net-irc/irssi-svn"
+
+S="${WORKDIR}"/${MY_P}
+
+src_prepare() {
+	epunt_cxx
+}
+
+src_configure() {
+	econf \
+		--with-proxy \
+		--with-ncurses \
+		--with-perl-lib=vendor \
+		$(use_with perl) \
+		$(use_with socks5 socks) \
+		$(use_enable ssl) \
+		$(use_enable ipv6) \
+		|| die "econf failed"
+}
+
+src_install() {
+	emake \
+		DESTDIR="${D}" \
+		docdir=/usr/share/doc/${PF} \
+		install || die "make install failed"
+
+	use perl && fixlocalpod
+
+	dodoc AUTHORS ChangeLog README TODO NEWS || die "dodoc failed"
+}