1 files changed, 63 insertions, 0 deletions
diff --git a/media-sound/sound-juicer/sound-juicer-2.28.1.ebuild b/media-sound/sound-juicer/sound-juicer-2.28.1.ebuild
new file mode 100644
index 000000000000..d64b77d66bcb
--- /dev/null
+++ b/media-sound/sound-juicer/sound-juicer-2.28.1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/sound-juicer/sound-juicer-2.28.1.ebuild,v 1.1 2009/12/13 21:57:57 eva Exp $
+
+EAPI="2"
+
+inherit gnome2
+
+DESCRIPTION="CD ripper for GNOME 2"
+HOMEPAGE="http://www.burtonini.com/blog/computers/sound-juicer/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="test"
+
+# FIXME: possibly automagic dual slot dep on musicbrainz, bug #275798
+COMMON_DEPEND=">=dev-libs/glib-2.18
+	>=x11-libs/gtk+-2.14
+
+	>=gnome-base/libglade-2
+	>=gnome-base/gconf-2
+	media-libs/libcanberra[gtk]
+	dev-libs/dbus-glib
+
+	>=media-libs/musicbrainz-3.0.2:3
+	>=dev-libs/libcdio-0.70
+	>=gnome-extra/gnome-media-2.11.91
+	>=app-cdr/brasero-0.9.1
+
+	>=media-libs/gstreamer-0.10.15:0.10
+	>=media-libs/gst-plugins-base-0.10:0.10"
+
+RDEPEND="${COMMON_DEPEND}
+	>=media-plugins/gst-plugins-gconf-0.10:0.10
+	>=media-plugins/gst-plugins-gio-0.10:0.10
+	|| (
+		>=media-plugins/gst-plugins-cdparanoia-0.10:0.10
+		>=media-plugins/gst-plugins-cdio-0.10:0.10 )
+	>=media-plugins/gst-plugins-meta-0.10-r2:0.10"
+
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/pkgconfig-0.9
+	>=dev-util/intltool-0.40
+	>=app-text/scrollkeeper-0.3.5
+	app-text/gnome-doc-utils
+	test? ( ~app-text/docbook-xml-dtd-4.3 )"
+
+DOCS="AUTHORS ChangeLog NEWS README TODO"
+
+pkg_setup() {
+	G2CONF="${G2CONF} --disable-scrollkeeper"
+
+	# needed to get around some sandboxing checks
+	export GST_INSPECT=/bin/true
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	echo
+	ewarn "If ${PN} does not rip to some music format, please check your"
+	ewarn "USE flags on media-plugins/gst-plugins-meta"
+}