1 files changed, 45 insertions, 0 deletions
diff --git a/games-puzzle/monsterz/monsterz-0.7.1-r3.ebuild b/games-puzzle/monsterz/monsterz-0.7.1-r3.ebuild
new file mode 100644
index 000000000000..c3199fadc81e
--- /dev/null
+++ b/games-puzzle/monsterz/monsterz-0.7.1-r3.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-puzzle/monsterz/monsterz-0.7.1-r3.ebuild,v 1.1 2013/08/26 23:35:12 hasufell Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python2_6 python2_7 )
+inherit eutils games python-r1
+
+DESCRIPTION="a little puzzle game, similar to the famous Bejeweled or Zookeeper"
+HOMEPAGE="http://sam.zoy.org/projects/monsterz/"
+SRC_URI="http://sam.zoy.org/projects/monsterz/${P}.tar.gz"
+
+LICENSE="WTFPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~sparc ~x86"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	dev-python/pygame[${PYTHON_USEDEP}]
+	media-libs/sdl-image[png]
+	media-libs/sdl-mixer[mod]"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${P}-gentoo.patch \
+		"${FILESDIR}"/${P}-64bit.patch \
+		"${FILESDIR}"/${P}-blit.patch
+	sed -i \
+		-e "s:GENTOO_DATADIR:${GAMES_DATADIR}/${PN}:" \
+		monsterz.py || die "sed failed"
+	rm Makefile || die
+}
+
+src_install() {
+	insinto "${GAMES_DATADIR}"/${PN}
+	doins -r graphics sound
+	newgamesbin monsterz.py ${PN}
+	newicon graphics/icon.png ${PN}.png
+	make_desktop_entry ${PN} Monsterz
+	dodoc README AUTHORS TODO
+	python_replicate_script "${ED%/}${GAMES_BINDIR}"/monsterz
+	prepgamesdirs
+}