1 files changed, 41 insertions, 0 deletions
diff --git a/games-action/rafkill/rafkill-1.2.3.ebuild b/games-action/rafkill/rafkill-1.2.3.ebuild
new file mode 100644
index 000000000000..54ee8bdb34dc
--- /dev/null
+++ b/games-action/rafkill/rafkill-1.2.3.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-action/rafkill/rafkill-1.2.3.ebuild,v 1.1 2007/01/31 10:32:25 nyhm Exp $
+
+inherit eutils toolchain-funcs games
+
+DESCRIPTION="space shoot-em-up game"
+HOMEPAGE="http://raptorv2.sourceforge.net/"
+SRC_URI="mirror://sourceforge/raptorv2/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~x86"
+IUSE=""
+
+RDEPEND=">=media-libs/allegro-4.0.0
+	media-libs/aldumb"
+DEPEND="${RDEPEND}
+	dev-util/scons"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	rm -f {data,music}/.sconsign
+	epatch "${FILESDIR}"/${P}-build.patch
+	sed -i "/^#define INSTALL_DIR/s:\.:${GAMES_DATADIR}:" \
+		src/defs.cpp || die "sed failed"
+}
+
+src_compile() {
+	tc-export CXX
+	scons || die "scons failed"
+}
+
+src_install() {
+	dogamesbin ${PN} || die "dogamesbin failed"
+	insinto "${GAMES_DATADIR}"/${PN}
+	doins -r data music || die "doins failed"
+	dodoc README
+	prepgamesdirs
+}