1 files changed, 83 insertions, 0 deletions
diff --git a/app-arch/libarchive/libarchive-2.5.902a.ebuild b/app-arch/libarchive/libarchive-2.5.902a.ebuild
new file mode 100644
index 000000000000..223e9737cb4d
--- /dev/null
+++ b/app-arch/libarchive/libarchive-2.5.902a.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-arch/libarchive/libarchive-2.5.902a.ebuild,v 1.1 2008/11/13 01:38:48 flameeyes Exp $
+
+EAPI=1
+
+inherit eutils libtool toolchain-funcs autotools
+
+DESCRIPTION="BSD tar command"
+HOMEPAGE="http://people.freebsd.org/~kientzle/libarchive"
+SRC_URI="http://people.freebsd.org/~kientzle/libarchive/src/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
+IUSE="static acl xattr kernel_linux +bzip2 +lzma"
+
+COMPRESS_LIBS_DEPEND="lzma? ( app-arch/lzma-utils )
+		bzip2? ( app-arch/bzip2 )
+		sys-libs/zlib"
+
+RDEPEND="!dev-libs/libarchive
+	kernel_linux? (
+		acl? ( sys-apps/acl )
+		xattr? ( sys-apps/attr )
+	)
+	!static? ( ${COMPRESS_LIBS_DEPEND} )"
+DEPEND="${RDEPEND}
+	${COMPRESS_LIBS_DEPEND}
+	kernel_linux? ( sys-fs/e2fsprogs
+		virtual/os-headers )"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	epatch "${FILESDIR}"/${P}-automagic.patch
+
+	eautoreconf
+
+	elibtoolize
+	epunt_cxx
+}
+
+src_compile() {
+	local myconf
+
+	if ! use static ; then
+		myconf="--enable-bsdtar=shared --enable-bsdcpio=shared"
+	fi
+
+	econf --bindir=/bin \
+		--enable-bsdtar --enable-bsdcpio \
+		$(use_enable acl) $(use_enable xattr) \
+		$(use_with bzip2 bz2lib) $(use_with lzma lzmadec) \
+		${myconf} \
+		--disable-dependency-tracking || die "econf failed."
+
+	emake || die "emake failed."
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed."
+
+	# Create tar symlink for FreeBSD
+	if [[ ${CHOST} == *-freebsd* ]]; then
+		dosym bsdtar /bin/tar
+		dosym bsdtar.1 /usr/share/man/man1/tar.1
+		# We may wish to switch to symlink bsdcpio to cpio too one day
+	fi
+
+	dodoc NEWS README
+
+	if use build; then
+		rm -rf "${D}"/usr
+		rm -rf "${D}"/lib/*.so*
+		return 0
+	fi
+
+	dodir /$(get_libdir)
+	mv "${D}"/usr/$(get_libdir)/*.so* "${D}"/$(get_libdir)
+	gen_usr_ldscript libarchive.so
+}