Version bump

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 0x5D21B852895192F9)

2 files changed, 77 insertions, 1 deletions

diff --git a/x11-wm/i3/ChangeLog b/x11-wm/i3/ChangeLog
index 579d9214a96b..6ef2018933f7 100644
--- a/x11-wm/i3/ChangeLog
+++ b/x11-wm/i3/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for x11-wm/i3
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/i3/ChangeLog,v 1.40 2013/10/10 09:38:25 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/i3/ChangeLog,v 1.41 2013/12/22 21:16:16 xarthisius Exp $
+
+*i3-4.7 (22 Dec 2013)
+
+  22 Dec 2013; Kacper Kowalik <xarthisius@gentoo.org> +i3-4.7.ebuild:
+  Version bump
 
   10 Oct 2013; Kacper Kowalik <xarthisius@gentoo.org> metadata.xml:
   Drop desktop-wm from metadata.xml
diff --git a/x11-wm/i3/i3-4.7.ebuild b/x11-wm/i3/i3-4.7.ebuild
new file mode 100644
index 000000000000..2dcb02147cb0
--- /dev/null
+++ b/x11-wm/i3/i3-4.7.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/i3/i3-4.7.ebuild,v 1.1 2013/12/22 21:16:16 xarthisius Exp $
+
+EAPI=5
+
+inherit eutils toolchain-funcs
+
+DESCRIPTION="An improved dynamic tiling window manager"
+HOMEPAGE="http://i3wm.org/"
+SRC_URI="http://i3wm.org/downloads/${P}.tar.bz2"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+pango"
+
+CDEPEND="dev-libs/libev
+	dev-libs/libpcre
+	dev-libs/yajl
+	x11-libs/libxcb
+	x11-libs/libX11
+	x11-libs/startup-notification
+	x11-libs/xcb-util
+	x11-libs/xcb-util-cursor
+	x11-libs/xcb-util-keysyms
+	x11-libs/xcb-util-wm
+	pango? (
+		>=x11-libs/pango-1.30.0[X]
+		>=x11-libs/cairo-1.12.2[X,xcb]
+	)"
+DEPEND="${CDEPEND}
+	virtual/pkgconfig"
+RDEPEND="${CDEPEND}
+	x11-apps/xmessage"
+
+DOCS=( RELEASE-NOTES-${PV} )
+
+src_prepare() {
+	if ! use pango; then
+		sed -i common.mk -e '/PANGO/d' || die
+	fi
+
+	cat <<- EOF > "${T}"/i3wm
+		#!/bin/sh
+		exec /usr/bin/i3
+	EOF
+
+	epatch_user #471716
+}
+
+src_compile() {
+	emake V=1 CC="$(tc-getCC)" AR="$(tc-getAR)"
+}
+
+src_install() {
+	default
+	dohtml -r docs/*
+	doman man/*.1
+	exeinto /etc/X11/Sessions
+	doexe "${T}"/i3wm
+}
+
+pkg_postinst() {
+	einfo "There are several packages that you may find useful with ${PN} and"
+	einfo "their usage is suggested by the upstream maintainers, namely:"
+	einfo "  x11-misc/dmenu"
+	einfo "  x11-misc/i3status"
+	einfo "  x11-misc/i3lock"
+	einfo "Please refer to their description for additional info."
+}