Add missing x11-libs/libXext dep (bug #514066).

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

3 files changed, 76 insertions, 2 deletions

diff --git a/x11-wm/herbstluftwm/ChangeLog b/x11-wm/herbstluftwm/ChangeLog
index 513df6243f2f..834b24fd6b9a 100644
--- a/x11-wm/herbstluftwm/ChangeLog
+++ b/x11-wm/herbstluftwm/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for x11-wm/herbstluftwm
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/herbstluftwm/ChangeLog,v 1.16 2014/04/04 07:57:21 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/herbstluftwm/ChangeLog,v 1.17 2014/06/21 06:26:05 radhermit Exp $
+
+*herbstluftwm-0.6.2-r1 (21 Jun 2014)
+
+  21 Jun 2014; Tim Harder <radhermit@gentoo.org> +herbstluftwm-0.6.2-r1.ebuild,
+  herbstluftwm-9999.ebuild:
+  Add missing x11-libs/libXext dep (bug #514066).
 
 *herbstluftwm-0.6.2 (04 Apr 2014)
 
diff --git a/x11-wm/herbstluftwm/herbstluftwm-0.6.2-r1.ebuild b/x11-wm/herbstluftwm/herbstluftwm-0.6.2-r1.ebuild
new file mode 100644
index 000000000000..67ffb74d3b1e
--- /dev/null
+++ b/x11-wm/herbstluftwm/herbstluftwm-0.6.2-r1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/herbstluftwm/herbstluftwm-0.6.2-r1.ebuild,v 1.1 2014/06/21 06:26:05 radhermit Exp $
+
+EAPI=5
+inherit toolchain-funcs bash-completion-r1
+
+if [[ ${PV} == 9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="git://git.cs.fau.de/hlwm"
+	EXTRA_DEPEND="app-text/asciidoc"
+else
+	SRC_URI="http://herbstluftwm.org/tarballs/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	EXTRA_DEPEND=""
+fi
+
+DESCRIPTION="A manual tiling window manager for X"
+HOMEPAGE="http://herbstluftwm.org"
+
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="examples xinerama zsh-completion"
+
+CDEPEND=">=dev-libs/glib-2.24:2
+	x11-libs/libX11
+	x11-libs/libXext
+	xinerama? ( x11-libs/libXinerama )"
+RDEPEND="${CDEPEND}
+	app-shells/bash
+	zsh-completion? ( app-shells/zsh )"
+DEPEND="${CDEPEND}
+	${EXTRA_DEPEND}
+	virtual/pkgconfig"
+
+src_compile() {
+	emake CC="$(tc-getCC)" LD="$(tc-getCC)" COLOR=0 VERBOSE= \
+		$(use xinerama || echo XINERAMAFLAGS= XINERAMALIBS= )
+}
+
+src_install() {
+	dobin herbstluftwm herbstclient
+	dodoc BUGS MIGRATION NEWS README
+
+	doman doc/{herbstluftwm,herbstclient}.1
+
+	exeinto /etc/xdg/herbstluftwm
+	doexe share/{autostart,panel.sh,restartpanels.sh}
+
+	insinto /usr/share/xsessions
+	doins share/herbstluftwm.desktop
+
+	newbashcomp share/herbstclient-completion herbstclient
+
+	if use zsh-completion ; then
+		insinto /usr/share/zsh/site-functions
+		doins share/_herbstclient
+	fi
+
+	if use examples ; then
+		exeinto /usr/share/doc/${PF}/examples
+		doexe scripts/*.sh
+		docinto examples
+		dodoc scripts/README
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
diff --git a/x11-wm/herbstluftwm/herbstluftwm-9999.ebuild b/x11-wm/herbstluftwm/herbstluftwm-9999.ebuild
index 999491401ddb..7638a2022388 100644
--- a/x11-wm/herbstluftwm/herbstluftwm-9999.ebuild
+++ b/x11-wm/herbstluftwm/herbstluftwm-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/herbstluftwm/herbstluftwm-9999.ebuild,v 1.10 2014/01/01 22:54:50 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/herbstluftwm/herbstluftwm-9999.ebuild,v 1.11 2014/06/21 06:26:05 radhermit Exp $
 
 EAPI=5
 inherit toolchain-funcs bash-completion-r1
@@ -24,6 +24,7 @@ IUSE="examples xinerama zsh-completion"
 
 CDEPEND=">=dev-libs/glib-2.24:2
 	x11-libs/libX11
+	x11-libs/libXext
 	xinerama? ( x11-libs/libXinerama )"
 RDEPEND="${CDEPEND}
 	app-shells/bash