Version bump

(Portage version: 2.2.0_alpha30/cvs/Linux x86_64)

2 files changed, 80 insertions, 1 deletions

diff --git a/www-client/midori/ChangeLog b/www-client/midori/ChangeLog
index a60d5bd9d41a..bdf11c38c8ea 100644
--- a/www-client/midori/ChangeLog
+++ b/www-client/midori/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for www-client/midori
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/midori/ChangeLog,v 1.58 2011/04/28 10:29:09 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/midori/ChangeLog,v 1.59 2011/05/02 08:01:01 angelos Exp $
+
+*midori-0.3.5 (02 May 2011)
+
+  02 May 2011; Christoph Mende <angelos@gentoo.org> +midori-0.3.5.ebuild:
+  Version bump
 
   28 Apr 2011; Pawel Hajdan jr <phajdan.jr@gentoo.org> midori-0.3.3.ebuild:
   x86 stable wrt security bug #364973
diff --git a/www-client/midori/midori-0.3.5.ebuild b/www-client/midori/midori-0.3.5.ebuild
new file mode 100644
index 000000000000..f4134e94f297
--- /dev/null
+++ b/www-client/midori/midori-0.3.5.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/midori/midori-0.3.5.ebuild,v 1.1 2011/05/02 08:01:01 angelos Exp $
+
+EAPI=3
+inherit eutils fdo-mime gnome2-utils python waf-utils
+
+DESCRIPTION="A lightweight web browser based on WebKitGTK+"
+HOMEPAGE="http://www.twotoasts.de/index.php?/pages/midori_summary.html"
+SRC_URI="mirror://xfce/src/apps/${PN}/0.3/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1 MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86 ~x86-fbsd"
+IUSE="doc gnome idn libnotify nls +unique vala"
+
+RDEPEND="dev-libs/libxml2:2
+	>=dev-db/sqlite-3.0
+	>=net-libs/libsoup-2.25.2:2.4
+	net-libs/webkit-gtk:2
+	x11-libs/gtk+:2
+	gnome? ( net-libs/libsoup-gnome:2.4 )
+	idn? ( net-dns/libidn )
+	libnotify? ( x11-libs/libnotify )
+	unique? ( dev-libs/libunique:1 )
+	vala? ( dev-lang/vala:0.10 )"
+DEPEND="${RDEPEND}
+	|| ( dev-lang/python:2.7 dev-lang/python:2.6 )
+	dev-util/intltool
+	doc? ( dev-util/gtk-doc )
+	nls? ( sys-devel/gettext )"
+
+pkg_setup() {
+	python_set_active_version 2
+	python_pkg_setup
+
+	DOCS=( AUTHORS ChangeLog HACKING INSTALL TODO TRANSLATE )
+	HTML_DOCS=( data/faq.html data/faq.css )
+}
+
+src_prepare() {
+	# Make it work with slotted vala versions
+	sed -i -e "s/conf.env, 'valac'/conf.env, 'valac-0.10', var='VALAC'/" wscript || die
+}
+
+src_configure() {
+	strip-linguas -i po
+
+	waf-utils_src_configure \
+		--disable-docs \
+		--enable-addons \
+		$(use_enable doc apidocs) \
+		$(use_enable idn libidn) \
+		$(use_enable libnotify) \
+		$(use_enable nls) \
+		$(use_enable unique) \
+		$(use_enable vala)
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+	gnome2_icon_cache_update
+}