Bump.

(Portage version: 2.2.0_alpha136/cvs/Linux x86_64)

4 files changed, 164 insertions, 3 deletions

diff --git a/www-client/google-chrome/ChangeLog b/www-client/google-chrome/ChangeLog
index e12daa3f0121..2ac56feaa8a5 100644
--- a/www-client/google-chrome/ChangeLog
+++ b/www-client/google-chrome/ChangeLog
@@ -1,6 +1,18 @@
 # ChangeLog for www-client/google-chrome
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/google-chrome/ChangeLog,v 1.203 2012/10/09 01:29:18 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/google-chrome/ChangeLog,v 1.204 2012/10/10 20:44:27 floppym Exp $
+
+*google-chrome-23.0.1271.26_beta160934 (10 Oct 2012)
+*google-chrome-22.0.1229.94_p161065 (10 Oct 2012)
+*google-chrome-24.0.1290.1_alpha160787 (10 Oct 2012)
+
+  10 Oct 2012; Mike Gilbert <floppym@gentoo.org>
+  +google-chrome-22.0.1229.94_p161065.ebuild,
+  +google-chrome-23.0.1271.26_beta160934.ebuild,
+  +google-chrome-24.0.1290.1_alpha160787.ebuild,
+  -google-chrome-22.0.1229.92_p159988.ebuild,
+  -google-chrome-23.0.1271.22_beta160452.ebuild:
+  Bump.
 
 *google-chrome-23.0.1271.22_beta160452 (09 Oct 2012)
 
diff --git a/www-client/google-chrome/google-chrome-22.0.1229.92_p159988.ebuild b/www-client/google-chrome/google-chrome-22.0.1229.94_p161065.ebuild
index 2a3c7f655227..827289d0f4c3 100644
--- a/www-client/google-chrome/google-chrome-22.0.1229.92_p159988.ebuild
+++ b/www-client/google-chrome/google-chrome-22.0.1229.94_p161065.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/google-chrome/google-chrome-22.0.1229.92_p159988.ebuild,v 1.1 2012/10/08 20:39:24 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/google-chrome/google-chrome-22.0.1229.94_p161065.ebuild,v 1.1 2012/10/10 20:44:27 floppym Exp $
 
 EAPI="4"
 
diff --git a/www-client/google-chrome/google-chrome-23.0.1271.22_beta160452.ebuild b/www-client/google-chrome/google-chrome-23.0.1271.26_beta160934.ebuild
index 7476918a806a..b77440eda63d 100644
--- a/www-client/google-chrome/google-chrome-23.0.1271.22_beta160452.ebuild
+++ b/www-client/google-chrome/google-chrome-23.0.1271.26_beta160934.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/google-chrome/google-chrome-23.0.1271.22_beta160452.ebuild,v 1.1 2012/10/09 01:29:18 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/google-chrome/google-chrome-23.0.1271.26_beta160934.ebuild,v 1.1 2012/10/10 20:44:27 floppym Exp $
 
 EAPI="4"
 
diff --git a/www-client/google-chrome/google-chrome-24.0.1290.1_alpha160787.ebuild b/www-client/google-chrome/google-chrome-24.0.1290.1_alpha160787.ebuild
new file mode 100644
index 000000000000..f06df028d375
--- /dev/null
+++ b/www-client/google-chrome/google-chrome-24.0.1290.1_alpha160787.ebuild
@@ -0,0 +1,149 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/google-chrome/google-chrome-24.0.1290.1_alpha160787.ebuild,v 1.1 2012/10/10 20:44:27 floppym Exp $
+
+EAPI="4"
+
+CHROMIUM_LANGS="am ar bg bn ca cs da de el en_GB es es_LA et fa fi fil fr gu he
+	hi hr hu id it ja kn ko lt lv ml mr ms nb nl pl pt_BR pt_PT ro ru sk sl sr
+	sv sw ta te th tr uk vi zh_CN zh_TW"
+
+inherit chromium eutils multilib pax-utils unpacker
+
+DESCRIPTION="The web browser from Google"
+HOMEPAGE="http://www.google.com/chrome"
+
+case ${PV} in
+	*_alpha*)
+		SLOT="unstable"
+		MY_PV=${PV/_alpha/-r}
+		;;
+	*_beta*)
+		SLOT="beta"
+		MY_PV=${PV/_beta/-r}
+		;;
+	*_p*)
+		SLOT="stable"
+		MY_PV=${PV/_p/-r}
+		;;
+	*)
+		die "Invalid value for \${PV}: ${PV}"
+		;;
+esac
+
+MY_PN="${PN}-${SLOT}"
+MY_P="${MY_PN}_${MY_PV}"
+
+SRC_BASE="http://dl.google.com/linux/chrome/deb/pool/main/g/${MY_PN}/${MY_P}_"
+SRC_URI="amd64? ( ${SRC_BASE}amd64.deb ) x86? ( ${SRC_BASE}i386.deb )"
+
+LICENSE="google-chrome"
+KEYWORDS="-* ~amd64 ~x86"
+IUSE="+plugins"
+RESTRICT="mirror strip"
+
+RDEPEND="
+	app-arch/bzip2
+	app-misc/ca-certificates
+	dev-libs/atk
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/libgcrypt
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gconf:2
+	media-libs/alsa-lib
+	media-libs/fontconfig
+	media-libs/freetype
+	net-print/cups
+	sys-apps/dbus
+	|| ( >=sys-devel/gcc-4.4.0[-nocxx] >=sys-devel/gcc-4.4.0[cxx] )
+	sys-fs/udev
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:2
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libXScrnSaver
+	x11-libs/pango
+	x11-misc/xdg-utils
+"
+
+# Add blockers for the other slots.
+for x in 0 beta stable unstable; do
+	if [[ ${SLOT} != ${x} ]]; then
+		RDEPEND+=" !${CATEGORY}/${PN}:${x}"
+	fi
+done
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+
+pkg_nofetch() {
+	eerror "Please do not report bugs for google-chrome fetch failures."
+	eerror "The problem will be resolved with the next version bump."
+	eerror "Sync your portage tree and try again."
+}
+
+pkg_setup() {
+	CHROME_HOME="opt/google/chrome/"
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_install() {
+	pax-mark m ${CHROME_HOME}chrome || die
+	rm -rf usr/share/menu || die
+	mv usr/share/doc/${PN} usr/share/doc/${PF} || die
+
+	pushd "${CHROME_HOME}locales" > /dev/null || die
+	chromium_remove_language_paks
+	popd
+
+	mv opt usr "${D}" || die
+
+	fperms u+s "/${CHROME_HOME}chrome-sandbox" || die
+
+	if use plugins ; then
+		local plugins="--extra-plugin-dir=/usr/$(get_libdir)/nsbrowser/plugins"
+		sed -e "/^exec/ i set -- \"${plugins}\" \"\$@\"" \
+			-i "${D}${CHROME_HOME}google-chrome" || die
+	fi
+
+	domenu "${D}${CHROME_HOME}google-chrome.desktop" || die
+	local size
+	for size in 16 22 24 32 48 64 128 256 ; do
+		insinto /usr/share/icons/hicolor/${size}x${size}/apps
+		newins "${D}${CHROME_HOME}product_logo_${size}.png" google-chrome.png
+	done
+
+	# Compatibility symlink for newer udev, bug 423415.
+	dosym "/usr/$(get_libdir)/libudev.so" "${CHROME_HOME}libudev.so.0"
+}
+
+any_cpu_missing_flag() {
+	local value=$1
+	grep '^flags' /proc/cpuinfo | grep -qv "$value"
+}
+
+pkg_preinst() {
+	chromium_pkg_preinst
+	if any_cpu_missing_flag sse2; then
+		ewarn "The bundled PepperFlash plugin requires a CPU that supports the"
+		ewarn "SSE2 instruction set, and at least one of your CPUs does not"
+		ewarn "support this feature. Disabling PepperFlash."
+		sed -e "/^exec/ i set -- --disable-bundled-ppapi-flash \"\$@\"" \
+			-i "${D}${CHROME_HOME}google-chrome" || die
+	fi
+}
+
+pkg_postinst() {
+	chromium_pkg_postinst
+
+	einfo
+	elog "Please notice the bundled flash player (PepperFlash)."
+	elog "You can (de)activate all flash plugins via chrome://plugins"
+	einfo
+}