Version bump.

(Portage version: 2.2.0_alpha166/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

4 files changed, 127 insertions, 5 deletions

diff --git a/www-client/midori/ChangeLog b/www-client/midori/ChangeLog
index 707c4b01d35e..0dedfada89bf 100644
--- a/www-client/midori/ChangeLog
+++ b/www-client/midori/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for www-client/midori
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/midori/ChangeLog,v 1.105 2013/02/06 18:18:15 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/midori/ChangeLog,v 1.106 2013/03/12 10:19:16 ssuominen Exp $
+
+*midori-0.4.9 (12 Mar 2013)
+
+  12 Mar 2013; Samuli Suominen <ssuominen@gentoo.org> +midori-0.4.9.ebuild,
+  midori-9999.ebuild, metadata.xml:
+  Version bump.
 
   06 Feb 2013; Samuli Suominen <ssuominen@gentoo.org> midori-0.4.8.ebuild:
   Comment out the desktop file validation patch temporarily because the code is
diff --git a/www-client/midori/metadata.xml b/www-client/midori/metadata.xml
index 756f517676a1..6fe4735b70cb 100644
--- a/www-client/midori/metadata.xml
+++ b/www-client/midori/metadata.xml
@@ -6,5 +6,6 @@
     <flag name='deprecated'>Enable GTK+-2 instead of GTK+-3 because of external plugins like adobe-flash</flag>
     <flag name='unique'>Enable single instance support using <pkg>dev-libs/libunique</pkg></flag>
     <flag name='zeitgeist'>Add support for Zeitgeist event tracking system</flag>
+	<flag name='webkit2'>Enable WebKit2 API that splits web content rendering and application UI into separate processes</flag>
   </use>
 </pkgmetadata>
diff --git a/www-client/midori/midori-0.4.9.ebuild b/www-client/midori/midori-0.4.9.ebuild
new file mode 100644
index 000000000000..b905fc882d8d
--- /dev/null
+++ b/www-client/midori/midori-0.4.9.ebuild
@@ -0,0 +1,111 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/midori/midori-0.4.9.ebuild,v 1.1 2013/03/12 10:19:16 ssuominen Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+unset _live_inherits
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="git://git.xfce.org/apps/${PN}"
+	_live_inherits=git-2
+else
+	KEYWORDS="~amd64 ~arm ~ppc ~x86 ~x86-fbsd"
+	SRC_URI="mirror://xfce/src/apps/${PN}/${PV%.*}/${P}.tar.bz2"
+fi
+
+inherit eutils fdo-mime gnome2-utils python-any-r1 waf-utils ${_live_inherits}
+
+VALA_VERSION=0.18
+
+DESCRIPTION="A lightweight web browser based on WebKitGTK+"
+HOMEPAGE="http://twotoasts.de/index.php/midori/"
+
+LICENSE="LGPL-2.1 MIT"
+SLOT="0"
+IUSE="+deprecated doc gnome libnotify nls +unique webkit2 zeitgeist"
+
+RDEPEND=">=dev-db/sqlite-3.6.19:3
+	>=dev-libs/glib-2.22
+	dev-libs/libxml2
+	>=net-libs/libsoup-2.34:2.4
+	x11-libs/libXScrnSaver
+	deprecated? (
+		net-libs/webkit-gtk:2
+		x11-libs/gtk+:2
+		unique? ( dev-libs/libunique:1 )
+		)
+	!deprecated? (
+		>=app-crypt/gcr-3
+		>=net-libs/webkit-gtk-1.10.2:3
+		x11-libs/gtk+:3
+		unique? ( dev-libs/libunique:3 )
+		)
+	gnome? ( >=net-libs/libsoup-gnome-2.34:2.4 )
+	libnotify? ( >=x11-libs/libnotify-0.7 )
+	zeitgeist? ( >=dev-libs/libzeitgeist-0.3.14 )"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	dev-lang/vala:${VALA_VERSION}
+	dev-util/intltool
+	gnome-base/librsvg
+	doc? ( dev-util/gtk-doc )
+	nls? ( sys-devel/gettext )"
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+
+	DOCS=( AUTHORS ChangeLog HACKING INSTALL TODO TRANSLATE )
+	HTML_DOCS=( data/faq.html data/faq.css )
+}
+
+src_unpack() {
+	if [[ ${PV} == *9999* ]]; then
+		git-2_src_unpack
+	else
+		default
+	fi
+}
+
+src_prepare() {
+	# Force disabled because we don't have this custom renamed in Portage
+	sed -i -e 's:gcr-3-gtk2:&dIsAbLe:' wscript || die
+}
+
+src_configure() {
+	strip-linguas -i po
+
+	local myconf
+	use deprecated || myconf="$(use_enable webkit2)"
+
+	VALAC="$(type -P valac-${VALA_VERSION})" \
+	waf-utils_src_configure \
+		--disable-docs \
+		$(use_enable doc apidocs) \
+		$(use_enable unique) \
+		$(use_enable libnotify) \
+		--disable-granite \
+		--enable-addons \
+		$(use_enable nls) \
+		$(use_enable !deprecated gtk3) \
+		$(use_enable zeitgeist) \
+		${myconf}
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+	gnome2_icon_cache_update
+}
diff --git a/www-client/midori/midori-9999.ebuild b/www-client/midori/midori-9999.ebuild
index 64999c49bd79..9b5fcad5c038 100644
--- a/www-client/midori/midori-9999.ebuild
+++ b/www-client/midori/midori-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/midori/midori-9999.ebuild,v 1.45 2013/02/06 12:56:37 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/midori/midori-9999.ebuild,v 1.46 2013/03/12 10:19:16 ssuominen Exp $
 
 EAPI=5
 
@@ -25,7 +25,7 @@ HOMEPAGE="http://twotoasts.de/index.php/midori/"
 
 LICENSE="LGPL-2.1 MIT"
 SLOT="0"
-IUSE="+deprecated doc gnome libnotify nls +unique zeitgeist"
+IUSE="+deprecated doc gnome libnotify nls +unique webkit2 zeitgeist"
 
 RDEPEND=">=dev-db/sqlite-3.6.19:3
 	>=dev-libs/glib-2.22
@@ -39,7 +39,7 @@ RDEPEND=">=dev-db/sqlite-3.6.19:3
 		)
 	!deprecated? (
 		>=app-crypt/gcr-3
-		net-libs/webkit-gtk:3
+		>=net-libs/webkit-gtk-1.10.2:3
 		x11-libs/gtk+:3
 		unique? ( dev-libs/libunique:3 )
 		)
@@ -77,6 +77,9 @@ src_prepare() {
 src_configure() {
 	strip-linguas -i po
 
+	local myconf
+	use deprecated || myconf="$(use_enable webkit2)"
+
 	VALAC="$(type -P valac-${VALA_VERSION})" \
 	waf-utils_src_configure \
 		--disable-docs \
@@ -87,7 +90,8 @@ src_configure() {
 		--enable-addons \
 		$(use_enable nls) \
 		$(use_enable !deprecated gtk3) \
-		$(use_enable zeitgeist)
+		$(use_enable zeitgeist) \
+		${myconf}
 }
 
 pkg_preinst() {