Add snapshot ebuild.

(Portage version: 2.1.11.62/cvs/Linux x86_64, unsigned Manifest commit)

3 files changed, 80 insertions, 9 deletions

diff --git a/net-wireless/rtl-sdr/ChangeLog b/net-wireless/rtl-sdr/ChangeLog
index a4047a0de2c0..3454d268252c 100644
--- a/net-wireless/rtl-sdr/ChangeLog
+++ b/net-wireless/rtl-sdr/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-wireless/rtl-sdr
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/rtl-sdr/ChangeLog,v 1.3 2012/08/11 09:09:08 chithanh Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/rtl-sdr/ChangeLog,v 1.4 2013/06/01 12:56:33 chithanh Exp $
+
+*rtl-sdr-0_pre20130414 (01 Jun 2013)
+
+  01 Jun 2013; Chí-Thanh Christopher Nguyễn <chithanh@gentoo.org>
+  +rtl-sdr-0_pre20130414.ebuild, rtl-sdr-9999.ebuild:
+  Add snapshot ebuild.
 
   11 Aug 2012; Chí-Thanh Christopher Nguyễn <chithanh@gentoo.org>
   rtl-sdr-9999.ebuild:
diff --git a/net-wireless/rtl-sdr/rtl-sdr-0_pre20130414.ebuild b/net-wireless/rtl-sdr/rtl-sdr-0_pre20130414.ebuild
new file mode 100644
index 000000000000..1035fe48c63f
--- /dev/null
+++ b/net-wireless/rtl-sdr/rtl-sdr-0_pre20130414.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/rtl-sdr/rtl-sdr-0_pre20130414.ebuild,v 1.1 2013/06/01 12:56:33 chithanh Exp $
+
+EAPI=5
+inherit autotools
+
+DESCRIPTION="turns your Realtek RTL2832 based DVB dongle into a SDR receiver"
+HOMEPAGE="http://sdr.osmocom.org/trac/wiki/rtl-sdr"
+
+if [[ ${PV} == 9999* ]]; then
+	inherit git-2
+	SRC_URI=""
+	EGIT_REPO_URI="git://git.osmocom.org/${PN}.git"
+	KEYWORDS=""
+else
+	SRC_URI="mirror://gentoo/${P}.tar.xz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE=""
+
+RDEPEND="virtual/libusb:1"
+DEPEND="${RDEPEND}"
+
+DOCS=( ${PN}.rules )
+
+src_unpack() {
+	if [[ ${PV} == 9999* ]]; then
+		git-2_src_unpack
+	else
+		unpack ${A}
+		mv ${PN}-*/ ${P} || die
+	fi
+}
+
+src_prepare() {
+	eautoreconf
+}
+
+pkg_postinst() {
+	local rulesfiles=( "${EPREFIX}"/etc/udev/rules.d/*${PN}.rules )
+	if [[ ! -f ${rulesfiles} ]]; then
+		elog "In order to allow users outside the usb group to capture samples, install"
+		elog "${PN}.rules from the documentation directory to ${EPREFIX}/etc/udev/rules.d/"
+	fi
+}
diff --git a/net-wireless/rtl-sdr/rtl-sdr-9999.ebuild b/net-wireless/rtl-sdr/rtl-sdr-9999.ebuild
index 9c5c9f3d0c13..acabb9bc5e68 100644
--- a/net-wireless/rtl-sdr/rtl-sdr-9999.ebuild
+++ b/net-wireless/rtl-sdr/rtl-sdr-9999.ebuild
@@ -1,18 +1,25 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/rtl-sdr/rtl-sdr-9999.ebuild,v 1.2 2012/08/11 09:09:08 chithanh Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/rtl-sdr/rtl-sdr-9999.ebuild,v 1.3 2013/06/01 12:56:33 chithanh Exp $
 
-EAPI=4
-inherit autotools base git-2
+EAPI=5
+inherit autotools
 
 DESCRIPTION="turns your Realtek RTL2832 based DVB dongle into a SDR receiver"
 HOMEPAGE="http://sdr.osmocom.org/trac/wiki/rtl-sdr"
-SRC_URI=""
-EGIT_REPO_URI="git://git.osmocom.org/${PN}.git"
+
+if [[ ${PV} == 9999* ]]; then
+	inherit git-2
+	SRC_URI=""
+	EGIT_REPO_URI="git://git.osmocom.org/${PN}.git"
+	KEYWORDS=""
+else
+	SRC_URI="mirror://gentoo/${P}.tar.xz"
+	KEYWORDS="~amd64 ~x86"
+fi
 
 LICENSE="GPL-2"
 SLOT="0"
-KEYWORDS=""
 IUSE=""
 
 RDEPEND="virtual/libusb:1"
@@ -20,6 +27,15 @@ DEPEND="${RDEPEND}"
 
 DOCS=( ${PN}.rules )
 
+src_unpack() {
+	if [[ ${PV} == 9999* ]]; then
+		git-2_src_unpack
+	else
+		default
+		mv ${PN}-*/ ${P} || die
+	fi
+}
+
 src_prepare() {
 	eautoreconf
 }