Version bump.

(Portage version: 2.2_rc67/cvs/Linux x86_64)

2 files changed, 108 insertions, 1 deletions

diff --git a/net-nntp/nzbget/ChangeLog b/net-nntp/nzbget/ChangeLog
index 3aafb54b3eb2..e61b3ac0ca9c 100644
--- a/net-nntp/nzbget/ChangeLog
+++ b/net-nntp/nzbget/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-nntp/nzbget
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-nntp/nzbget/ChangeLog,v 1.29 2010/05/09 08:37:43 swegener Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-nntp/nzbget/ChangeLog,v 1.30 2010/05/09 08:43:43 swegener Exp $
+
+*nzbget-0.7.0 (09 May 2010)
+
+  09 May 2010; Sven Wegener <swegener@gentoo.org> +nzbget-0.7.0.ebuild:
+  Version bump.
 
   09 May 2010; Sven Wegener <swegener@gentoo.org> nzbget-0.6.0.ebuild:
   Install example post-process script, bug #296311.
diff --git a/net-nntp/nzbget/nzbget-0.7.0.ebuild b/net-nntp/nzbget/nzbget-0.7.0.ebuild
new file mode 100644
index 000000000000..0ac7b6feb496
--- /dev/null
+++ b/net-nntp/nzbget/nzbget-0.7.0.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-nntp/nzbget/nzbget-0.7.0.ebuild,v 1.1 2010/05/09 08:43:43 swegener Exp $
+
+EAPI="2"
+
+inherit eutils
+
+MY_P="${P/_pre/-testing-r}"
+
+DESCRIPTION="A command-line based binary newsgrapper supporting .nzb files"
+HOMEPAGE="http://nzbget.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~x86"
+IUSE="debug ssl gnutls ncurses parcheck"
+
+DEPEND="dev-libs/libxml2
+	ssl? (
+		gnutls? ( net-libs/gnutls )
+		!gnutls? ( dev-libs/openssl )
+	)
+	ncurses? ( sys-libs/ncurses )
+	parcheck? (
+		app-arch/libpar2
+		dev-libs/libsigc++:2
+	)"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}"/${P/_pre*/-testing}
+
+src_prepare() {
+	sed \
+		-i \
+		-e 's:^PostProcess=.*:#PostProcess=/usr/share/nzbget/postprocess-example.sh:' \
+		nzbget.conf.example \
+		|| die "sed nzbget.conf.example failed"
+
+	sed \
+		-e 's:^$MAINDIR=.*:$MAINDIR=/var/lib/nzbget:' \
+		-e 's:^LockFile=.*:LockFile=/var/run/nzbget/nzbget.pid:' \
+		-e 's:^LogFile=.*:LogFile=/var/log/nzbget/nzbget.log:' \
+		"${S}"/nzbget.conf.example >"${S}"/nzbgetd.conf.example \
+		|| die "sed nzbgetd.conf.example failed"
+}
+
+src_configure() {
+	econf \
+		$(use_enable debug) \
+		$(use_enable ncurses curses) \
+		$(use_enable parcheck) \
+		$(use_enable ssl tls) \
+		--with-tlslib=$(use gnutls && echo GnuTLS || echo OpenSSL) \
+	|| die "econf failed"
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die "emake install failed"
+
+	insinto /etc
+	newins nzbget.conf.example nzbget.conf || die "newins failed"
+	newins nzbgetd.conf.example nzbgetd.conf || die "newins failed"
+
+	keepdir /var/lib/nzbget/{dst,nzb,queue,tmp}
+	keepdir /var/{log,run}/nzbget
+
+	newinitd "${FILESDIR}"/nzbget.initd nzbget
+	newconfd "${FILESDIR}"/nzbget.confd nzbget
+
+	exeinto /usr/share/nzbget
+	doexe postprocess-example.sh
+
+	insinto /usr/share/nzbget
+	doins postprocess-example.conf
+
+	dodoc AUTHORS ChangeLog README nzbget.conf.example || die "dodoc failed"
+}
+
+pkg_preinst() {
+	enewgroup nzbget
+	enewuser nzbget -1 -1 /var/lib/nzbget nzbget
+
+	fowners nzbget:nzbget /var/lib/nzbget/{dst,nzb,queue,tmp}
+	fperms 750 /var/lib/nzbget/{queue,tmp}
+	fperms 770 /var/lib/nzbget/{dst,nzb}
+
+	fowners nzbget:nzbget /var/{log,run}/nzbget
+	fperms 750 /var/{log,run}/nzbget
+
+	fowners root:nzbget /etc/nzbgetd.conf
+	fperms 640 /etc/nzbgetd.conf
+}
+
+pkg_postinst() {
+	elog
+	elog "Please add users that you want to be able to use the system-wide"
+	elog "nzbget daemon to the nzbget group. To access the daemon run nzbget"
+	elog "with the --configfile /etc/nzbgetd.conf option."
+	elog
+}