Version bump.

(Portage version: 2.2.0_alpha101/cvs/Linux x86_64)

2 files changed, 116 insertions, 1 deletions

diff --git a/net-misc/apt-cacher-ng/ChangeLog b/net-misc/apt-cacher-ng/ChangeLog
index 8100f77e9972..94054965a7e7 100644
--- a/net-misc/apt-cacher-ng/ChangeLog
+++ b/net-misc/apt-cacher-ng/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/apt-cacher-ng
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/apt-cacher-ng/ChangeLog,v 1.11 2012/03/06 18:24:43 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/apt-cacher-ng/ChangeLog,v 1.12 2012/04/25 17:44:31 jer Exp $
+
+*apt-cacher-ng-0.7.3 (25 Apr 2012)
+
+  25 Apr 2012; Jeroen Roovers <jer@gentoo.org> +apt-cacher-ng-0.7.3.ebuild:
+  Version bump.
 
 *apt-cacher-ng-0.7.2 (06 Mar 2012)
 
diff --git a/net-misc/apt-cacher-ng/apt-cacher-ng-0.7.3.ebuild b/net-misc/apt-cacher-ng/apt-cacher-ng-0.7.3.ebuild
new file mode 100644
index 000000000000..5692151e1eb7
--- /dev/null
+++ b/net-misc/apt-cacher-ng/apt-cacher-ng-0.7.3.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/apt-cacher-ng/apt-cacher-ng-0.7.3.ebuild,v 1.1 2012/04/25 17:44:32 jer Exp $
+
+EAPI="4"
+
+inherit eutils cmake-utils
+
+DESCRIPTION="Yet another implementation of an HTTP proxy for Debian/Ubuntu software packages written in C++"
+HOMEPAGE="http://www.unix-ag.uni-kl.de/~bloch/acng/"
+LICENSE="as-is"
+SLOT="0"
+SRC_URI="mirror://debian/pool/main/a/${PN}/${PN}_${PV}.orig.tar.xz"
+
+KEYWORDS="~amd64 ~x86"
+IUSE="doc fuse lzma tcpd"
+
+COMMON_DEPEND="
+	app-arch/bzip2
+	sys-libs/zlib
+"
+DEPEND="
+	${COMMON_DEPEND}
+	app-arch/xz-utils
+	dev-util/cmake
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	lzma? ( app-arch/xz-utils )
+	fuse? ( sys-fs/fuse )
+	tcpd? ( sys-apps/tcp-wrappers )
+	dev-lang/perl
+"
+
+pkg_setup() {
+	# add new user & group for daemon
+	enewgroup ${PN}
+	enewuser ${PN} -1 -1 -1 ${PN}
+}
+
+src_configure(){
+	mycmakeargs="-DCMAKE_INSTALL_PREFIX=/usr"
+	if use fuse; then
+		mycmakeargs="-DHAVE_FUSE_26=yes ${mycmakeargs}"
+	else
+		mycmakeargs="-DHAVE_FUSE_26=no ${mycmakeargs}"
+	fi
+	if use lzma; then
+		mycmakeargs="-DHAVE_LZMA=yes ${mycmakeargs}"
+	else
+		mycmakeargs="-DHAVE_LZMA=no ${mycmakeargs}"
+	fi
+	if use tcpd; then
+		mycmakeargs="-DHAVE_LIBWRAP=yes ${mycmakeargs}"
+	else
+		mycmakeargs="-DHAVE_LIBWRAP=no ${mycmakeargs}"
+	fi
+
+	cmake-utils_src_configure
+}
+
+src_install() {
+	pushd ${CMAKE_BUILD_DIR}
+	dosbin ${PN}
+	if use fuse; then
+		dobin acngfs
+	fi
+	popd
+
+	newinitd "${FILESDIR}"/initd ${PN}
+	newconfd "${FILESDIR}"/confd ${PN}
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/logrotate ${PN}
+
+	doman doc/man/${PN}*
+	if use fuse; then
+		doman doc/man/acngfs*
+	fi
+
+	# Documentation
+	dodoc README TODO VERSION INSTALL ChangeLog
+	if use doc; then
+		dodoc doc/*.pdf
+		dohtml doc/html/*
+		docinto examples/conf
+		dodoc conf/*
+	fi
+
+	# perl daily cron script
+	dosbin expire-caller.pl
+	exeinto /etc/cron.daily
+	newexe "${FILESDIR}"/cron.daily ${PN}
+
+	# default configuration
+	insinto /etc/${PN}
+	newins conf/acng.conf ${PN}.conf
+	doins $( echo conf/* | sed 's|conf/acng.conf||g' )
+
+	dodir /var/cache/${PN}
+	dodir /var/log/${PN}
+	# Some directories must exists
+	keepdir /var/log/${PN}
+	keepdir /var/run/${PN}
+	fowners -R ${PN}:${PN} \
+		/etc/${PN} \
+		/var/log/${PN} \
+		/var/cache/${PN} \
+		/var/run/${PN}
+}