Enable multilib support, needed for dev-libs/libnsfb.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

2 files changed, 80 insertions, 1 deletions

diff --git a/net-libs/libvncserver/ChangeLog b/net-libs/libvncserver/ChangeLog
index d20346abd983..fbc296507152 100644
--- a/net-libs/libvncserver/ChangeLog
+++ b/net-libs/libvncserver/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-libs/libvncserver
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/libvncserver/ChangeLog,v 1.75 2014/03/01 22:38:07 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libvncserver/ChangeLog,v 1.76 2014/06/17 17:11:38 mgorny Exp $
+
+*libvncserver-0.9.9-r2 (17 Jun 2014)
+
+  17 Jun 2014; Michał Górny <mgorny@gentoo.org> +libvncserver-0.9.9-r2.ebuild:
+  Enable multilib support, needed for dev-libs/libnsfb.
 
   01 Mar 2014; Michał Górny <mgorny@gentoo.org> libvncserver-0.9.8.2-r2.ebuild,
   libvncserver-0.9.9-r1.ebuild, libvncserver-0.9.9.ebuild:
diff --git a/net-libs/libvncserver/libvncserver-0.9.9-r2.ebuild b/net-libs/libvncserver/libvncserver-0.9.9-r2.ebuild
new file mode 100644
index 000000000000..0d8e80993a4f
--- /dev/null
+++ b/net-libs/libvncserver/libvncserver-0.9.9-r2.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libvncserver/libvncserver-0.9.9-r2.ebuild,v 1.1 2014/06/17 17:11:38 mgorny Exp $
+
+EAPI="5"
+
+inherit eutils libtool multilib-minimal
+
+DESCRIPTION="library for creating vnc servers"
+HOMEPAGE="http://libvncserver.sourceforge.net/"
+SRC_URI="http://libvncserver.sourceforge.net/LibVNCServer-${PV/_}.tar.gz
+	mirror://sourceforge/${PN}/LibVNCServer-${PV/_}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux"
+IUSE="+24bpp gcrypt gnutls ipv6 +jpeg +png ssl static-libs test threads +zlib"
+
+REQUIRED_USE="png? ( zlib )"
+
+DEPEND="
+	gcrypt? ( dev-libs/libgcrypt:0[${MULTILIB_USEDEP}] )
+	gnutls? (
+		net-libs/gnutls[${MULTILIB_USEDEP}]
+		dev-libs/libgcrypt:0[${MULTILIB_USEDEP}]
+	)
+	!gnutls? (
+		ssl? ( dev-libs/openssl[${MULTILIB_USEDEP}] )
+	)
+	jpeg? ( virtual/jpeg[${MULTILIB_USEDEP}] )
+	png? ( media-libs/libpng:0[${MULTILIB_USEDEP}] )
+	zlib? ( sys-libs/zlib[${MULTILIB_USEDEP}] )
+"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}"/LibVNCServer-${PV/_}
+
+DOCS=( AUTHORS ChangeLog NEWS README TODO )
+
+src_prepare() {
+	sed -i -r \
+		-e '/^CFLAGS =/d' \
+		-e "/^SUBDIRS/s:\<($(use test || echo 'test|')client_examples|examples)\>::g" \
+		Makefile.in || die
+
+	elibtoolize
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE=${S} \
+	econf \
+		--disable-silent-rules \
+		--without-x11vnc \
+		$(use_enable static-libs static) \
+		$(use_with 24bpp) \
+		$(use_with gnutls) \
+		$(usex gnutls --with-gcrypt $(use_with gcrypt)) \
+		$(usex gnutls --without-ssl $(use_with ssl)) \
+		$(use_with ipv6) \
+		$(use_with jpeg) \
+		$(use_with png) \
+		$(use_with threads pthread) \
+		$(use_with zlib)
+}
+
+multilib_src_compile() {
+	default
+	multilib_is_native_abi && emake -C examples noinst_PROGRAMS=storepasswd
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files
+}