version bump, updated live ebuild

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key EB9B4AFA)

3 files changed, 178 insertions, 9 deletions

diff --git a/net-irc/znc/ChangeLog b/net-irc/znc/ChangeLog
index 5dd4c4ad7ceb..7c281cbef6d7 100644
--- a/net-irc/znc/ChangeLog
+++ b/net-irc/znc/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-irc/znc
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-irc/znc/ChangeLog,v 1.68 2013/06/04 12:31:34 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-irc/znc/ChangeLog,v 1.69 2013/11/14 11:35:35 wired Exp $
+
+*znc-1.2 (14 Nov 2013)
+
+  14 Nov 2013; Alex Alexander <wired@gentoo.org> +znc-1.2.ebuild,
+  znc-9999.ebuild:
+  version bump, updated live ebuild
 
   04 Jun 2013; Agostino Sarubbo <ago@gentoo.org> znc-1.0-r2.ebuild:
   Stable for amd64, wrt bug #471738
diff --git a/net-irc/znc/znc-1.2.ebuild b/net-irc/znc/znc-1.2.ebuild
new file mode 100644
index 000000000000..0d10a2c9bc37
--- /dev/null
+++ b/net-irc/znc/znc-1.2.ebuild
@@ -0,0 +1,164 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-irc/znc/znc-1.2.ebuild,v 1.1 2013/11/14 11:35:35 wired Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{3_2,3_3} )
+inherit base python-single-r1 user
+
+MY_PV=${PV/_/-}
+DESCRIPTION="An advanced IRC Bouncer"
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-2
+	EGIT_REPO_URI=${EGIT_REPO_URI:-"git://github.com/znc/znc.git"}
+	SRC_URI=""
+	KEYWORDS=""
+else
+	SRC_URI="http://znc.in/releases/${PN}-${MY_PV}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~x86"
+fi
+
+HOMEPAGE="http://znc.in"
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="daemon debug ipv6 perl python ssl sasl tcl"
+
+RDEPEND="
+	perl? ( >=dev-lang/perl-5.10 )
+	sasl? ( >=dev-libs/cyrus-sasl-2 )
+	ssl? ( >=dev-libs/openssl-0.9.7d )
+	tcl? ( dev-lang/tcl )
+"
+DEPEND="
+	virtual/pkgconfig
+	perl? ( dev-lang/swig )
+	python? (
+		>=dev-lang/swig-2.0.8
+		>=dev-lang/perl-5.10
+	)
+	${RDEPEND}
+"
+
+S=${WORKDIR}/${PN}-${MY_PV}
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.0-systemwideconfig.patch"
+)
+
+CONFDIR="/var/lib/znc"
+
+pkg_setup() {
+	if use python; then
+		python-single-r1_pkg_setup
+	fi
+	if use daemon; then
+		enewgroup ${PN}
+		enewuser ${PN} -1 -1 /dev/null ${PN}
+	fi
+}
+
+src_prepare() {
+	if [[ ${PV} == *9999* ]]; then
+		./autogen.sh
+	fi
+
+	base_src_prepare
+}
+
+src_configure() {
+	econf \
+		$(use_enable debug) \
+		$(use_enable ipv6) \
+		$(use_enable perl) \
+		$(use python && echo "--enable-python=python3") \
+		$(use_enable sasl cyrus) \
+		$(use_enable ssl openssl) \
+		$(use_enable tcl tcl)
+}
+
+src_install() {
+	emake install DESTDIR="${D}"
+	dodoc NOTICE README.md
+	if use daemon; then
+		newinitd "${FILESDIR}"/znc.initd znc
+		newconfd "${FILESDIR}"/znc.confd znc
+	fi
+}
+
+pkg_postinst() {
+	if use !daemon; then
+		elog
+		elog "Run 'znc --makeconf' as the user you want to run ZNC as"
+		elog "to make a configuration file"
+		elog "If you are using SSL you should also run 'znc --makepem'"
+		elog
+	else
+		elog
+		elog "An init-script was installed in /etc/init.d"
+		elog "A config file was installed in /etc/conf.d"
+		if [[ ! -d "${EROOT}${CONFDIR}" ]]; then
+			elog
+			elog "Run 'emerge --config znc' to configure ZNC"
+			elog "as a system-wide daemon."
+			elog
+			elog "If you are using SSL you should also run:"
+			elog "  znc --system-wide-config-as znc --makepem -d ${CONFDIR}"
+			elog "as root"
+			elog
+			elog "If migrating from a user-based install"
+			elog "you can use your existing config files:"
+			elog "  mkdir ${CONFDIR}"
+			elog "  mv /home/\$USER/.znc/* ${CONFDIR}"
+			elog "  rm -rf /home/\$USER/.znc"
+			elog "  chown -R znc:znc ${CONFDIR}"
+			elog
+			elog "If you already have znc set up and want take advantage of the"
+			elog "init script but skip of all the above, you can also edit"
+			elog "  /etc/conf.d/znc"
+			elog "and adjust the variables to your current znc user and config"
+			elog "location."
+			if [[ -d "${EROOT}"/etc/znc ]]; then
+				elog
+				ewarn "/etc/znc exists on your system."
+				ewarn "Due to the nature of the contents of that folder,"
+				ewarn "we have changed the default configuration to use"
+				ewarn "	/var/lib/znc"
+				ewarn "please move /etc/znc to /var/lib/znc"
+				ewarn "or adjust /etc/conf.d/znc"
+			fi
+		else
+			elog "Existing config detected in ${CONFDIR}"
+			elog "You're good to go :)"
+		fi
+		elog
+	fi
+}
+
+pkg_config() {
+	if use daemon && ! [[ -d "${EROOT}${CONFDIR}" ]]; then
+		einfo "Press ENTER to interactively create a new configuration file for znc."
+		einfo "To abort, press Control-C"
+		read
+		mkdir -p "${EROOT}${CONFDIR}" || die
+		chown -R ${PN}:${PN} "${EROOT}${CONFDIR}" ||
+			die "Setting permissions failed"
+		"${EROOT}"/usr/bin/znc --system-wide-config-as znc -c -r -d "${EROOT}${CONFDIR}" ||
+			die "Config failed"
+		echo
+		einfo "To start znc, run '/etc/init.d/znc start'"
+		einfo "or add znc to a runlevel:"
+		einfo "  rc-update add znc default"
+	else
+		if use daemon; then
+			ewarn "${CONFDIR} already exists, aborting to avoid damaging"
+			ewarn "any existing configuration. If you are sure you want"
+			ewarn "to generate a new configuration, remove the folder"
+			ewarn "and try again."
+		else
+			ewarn "To configure znc as a system-wide daemon you have to"
+			ewarn "enable the 'daemon' use flag."
+		fi
+	fi
+}
diff --git a/net-irc/znc/znc-9999.ebuild b/net-irc/znc/znc-9999.ebuild
index 59dc71333cf7..d0fd78f488ce 100644
--- a/net-irc/znc/znc-9999.ebuild
+++ b/net-irc/znc/znc-9999.ebuild
@@ -1,11 +1,11 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-irc/znc/znc-9999.ebuild,v 1.6 2013/02/02 02:48:24 wired Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-irc/znc/znc-9999.ebuild,v 1.7 2013/11/14 11:35:35 wired Exp $
 
 EAPI=5
 
-PYTHON_DEPEND="python? 3"
-inherit base python user
+PYTHON_COMPAT=( python{3_2,3_3} )
+inherit base python-single-r1 user
 
 MY_PV=${PV/_/-}
 DESCRIPTION="An advanced IRC Bouncer"
@@ -35,7 +35,7 @@ DEPEND="
 	virtual/pkgconfig
 	perl? ( dev-lang/swig )
 	python? (
-		>=dev-lang/swig-2.0.2
+		>=dev-lang/swig-2.0.8
 		>=dev-lang/perl-5.10
 	)
 	${RDEPEND}
@@ -51,8 +51,7 @@ CONFDIR="/var/lib/znc"
 
 pkg_setup() {
 	if use python; then
-		python_set_active_version 3
-		python_pkg_setup
+		python-single-r1_pkg_setup
 	fi
 	if use daemon; then
 		enewgroup ${PN}
@@ -73,7 +72,7 @@ src_configure() {
 		$(use_enable debug) \
 		$(use_enable ipv6) \
 		$(use_enable perl) \
-		$(use python && echo "--enable-python=python-$(python_get_version)") \
+		$(use python && echo "--enable-python=python3") \
 		$(use_enable sasl cyrus) \
 		$(use_enable ssl openssl) \
 		$(use_enable tcl tcl)
@@ -81,7 +80,7 @@ src_configure() {
 
 src_install() {
 	emake install DESTDIR="${D}"
-	dodoc AUTHORS README.md
+	dodoc NOTICE README.md
 	if use daemon; then
 		newinitd "${FILESDIR}"/znc.initd znc
 		newconfd "${FILESDIR}"/znc.confd znc