Version bumped, bug #299670.

(Portage version: 2.1.7.16/cvs/Linux x86_64)

1 files changed, 52 insertions, 0 deletions

diff --git a/net-dns/ldns-utils/ldns-utils-1.6.3.ebuild b/net-dns/ldns-utils/ldns-utils-1.6.3.ebuild
new file mode 100644
index 000000000000..832be9c687d1
--- /dev/null
+++ b/net-dns/ldns-utils/ldns-utils-1.6.3.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-dns/ldns-utils/ldns-utils-1.6.3.ebuild,v 1.1 2010/01/04 23:28:02 matsuu Exp $
+
+EAPI="2"
+
+MY_P="${P/-utils}"
+DESCRIPTION="Set of utilities to simplify various dns(sec) tasks."
+HOMEPAGE="http://www.nlnetlabs.nl/projects/ldns/"
+SRC_URI="http://www.nlnetlabs.nl/downloads/ldns/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples ssl"
+
+DEPEND=">=net-libs/ldns-${PV}[ssl?]
+	examples? ( net-libs/libpcap )"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+src_configure() {
+	cd "${S}"/drill
+	econf $(use_with ssl) || die
+
+	if use examples; then
+		cd "${S}"/examples
+		econf \
+			$(use_enable ssl sha2) \
+			$(use_with ssl) || die
+	fi
+}
+
+src_compile() {
+	emake -C drill || die "emake for drill failed"
+	if use examples; then
+		emake -C examples || die "emake for examples failed"
+	fi
+}
+
+src_install() {
+	cd "${S}"/drill
+	emake DESTDIR="${D}" install || die "emake install for drill failed"
+	dodoc ChangeLog.22-nov-2005 README REGRESSIONS
+
+	if use examples; then
+		cd "${S}"/examples
+		emake DESTDIR="${D}" install || die "emake install for examples failed"
+		newdoc README README.examples
+	fi
+}