version bump

(Portage version: 2.2.0_alpha163/cvs/Linux x86_64, signed Manifest commit with key 160F534A)

3 files changed, 113 insertions, 2 deletions

diff --git a/media-sound/sox/ChangeLog b/media-sound/sox/ChangeLog
index 6caa88e57d6b..8f987eb835e6 100644
--- a/media-sound/sox/ChangeLog
+++ b/media-sound/sox/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/sox
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/sox/ChangeLog,v 1.143 2012/11/25 21:12:32 lu_zero Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/sox/ChangeLog,v 1.144 2013/02/23 13:12:09 aballier Exp $
+
+*sox-14.4.1 (23 Feb 2013)
+
+  23 Feb 2013; Alexis Ballier <aballier@gentoo.org> +sox-14.4.1.ebuild,
+  +files/sox-14.4.1-uclibc.patch:
+  version bump
 
   25 Nov 2012; Luca Barbato <lu_zero@gentoo.org> sox-14.4.0.ebuild,
   +files/sox-14.4.0-libav-9.patch:
diff --git a/media-sound/sox/files/sox-14.4.1-uclibc.patch b/media-sound/sox/files/sox-14.4.1-uclibc.patch
new file mode 100644
index 000000000000..84a37d346147
--- /dev/null
+++ b/media-sound/sox/files/sox-14.4.1-uclibc.patch
@@ -0,0 +1,21 @@
+Index: sox-14.4.1/src/formats.c
+===================================================================
+--- sox-14.4.1.orig/src/formats.c
++++ sox-14.4.1/src/formats.c
+@@ -409,7 +409,7 @@ static void UNUSED rewind_pipe(FILE * fp
+ #if defined _FSTDIO || defined _NEWLIB_VERSION || defined __APPLE__
+   fp->_p -= PIPE_AUTO_DETECT_SIZE;
+   fp->_r += PIPE_AUTO_DETECT_SIZE;
+-#elif defined __GLIBC__
++#elif defined __GLIBC__ && ! defined __UCLIBC__
+   fp->_IO_read_ptr = fp->_IO_read_base;
+ #elif defined _MSC_VER || defined _WIN32 || defined _WIN64 || defined _ISO_STDIO_ISO_H
+   fp->_ptr = fp->_base;
+@@ -417,7 +417,6 @@ static void UNUSED rewind_pipe(FILE * fp
+   /* To fix this #error, either simply remove the #error line and live without
+    * file-type detection with pipes, or add support for your compiler in the
+    * lines above.  Test with cat monkey.wav | ./sox --info - */
+-  #error FIX NEEDED HERE
+   #define NO_REWIND_PIPE
+   (void)fp;
+ #endif
diff --git a/media-sound/sox/sox-14.4.1.ebuild b/media-sound/sox/sox-14.4.1.ebuild
new file mode 100644
index 000000000000..8ecc8496704f
--- /dev/null
+++ b/media-sound/sox/sox-14.4.1.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/sox/sox-14.4.1.ebuild,v 1.1 2013/02/23 13:12:09 aballier Exp $
+
+EAPI=4
+inherit eutils flag-o-matic autotools
+
+DESCRIPTION="The swiss army knife of sound processing programs"
+HOMEPAGE="http://sox.sourceforge.net"
+SRC_URI="mirror://sourceforge/sox/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-solaris"
+IUSE="alsa amr ao debug encode ffmpeg flac id3tag ladspa mad ogg openmp oss png pulseaudio sndfile static-libs twolame wavpack"
+
+# libtool required for libltdl
+RDEPEND=">=sys-devel/libtool-2.2.6b
+	>=media-sound/gsm-1.0.12-r1
+	alsa? ( media-libs/alsa-lib )
+	amr? ( media-libs/opencore-amr )
+	ao? ( media-libs/libao )
+	encode? ( >=media-sound/lame-3.98.4 )
+	ffmpeg? ( >=virtual/ffmpeg-0.9 )
+	flac? ( >=media-libs/flac-1.1.3 )
+	id3tag? ( media-libs/libid3tag )
+	ladspa? ( media-libs/ladspa-sdk )
+	mad? ( media-libs/libmad )
+	ogg? ( media-libs/libvorbis	media-libs/libogg )
+	png? ( media-libs/libpng sys-libs/zlib )
+	pulseaudio? ( media-sound/pulseaudio )
+	sndfile? ( >=media-libs/libsndfile-1.0.11 )
+	twolame? ( media-sound/twolame )
+	wavpack? ( media-sound/wavpack )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+DOCS=( AUTHORS ChangeLog NEWS README )
+
+src_prepare() {
+	sed -i -e 's:CFLAGS="-g":CFLAGS="$CFLAGS -g":' configure || die #386027
+
+	epatch \
+		"${FILESDIR}"/${PN}-14.4.1-uclibc.patch \
+		"${FILESDIR}"/${PN}-14.4.0-ffmpeg.patch \
+		"${FILESDIR}"/${PN}-14.4.0-avcodec54.patch \
+		"${FILESDIR}"/${PN}-14.4.0-libav-9.patch
+	eautoreconf
+}
+
+src_configure() {
+	# Fixes wav segfaults. See Bug #35745.
+	append-flags -fsigned-char
+
+	econf \
+		$(use_with alsa) \
+		$(use_with amr amrnb) \
+		$(use_with amr amrwb) \
+		$(use_with ao) \
+		$(use_enable debug) \
+		$(use_with encode lame) \
+		$(use_with ffmpeg) \
+		$(use_with flac) \
+		$(use_with id3tag) \
+		$(use_with ladspa) \
+		$(use_with mad) \
+		$(use_enable openmp gomp) \
+		$(use_with ogg oggvorbis) \
+		$(use_with oss) \
+		$(use_with png) \
+		$(use_with pulseaudio) \
+		$(use_with sndfile) \
+		$(use_enable static-libs static) \
+		$(use_with twolame) \
+		$(use_with wavpack) \
+		--with-distro="Gentoo"
+}
+
+src_install() {
+	default
+	# libltdl is used for loading plugins, keeping libtool files with empty
+	# dependency_libs what otherwise would be -exec rm -f {} +
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
+}