Version bump for Gnome 3.12.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key C6085806)

2 files changed, 76 insertions, 1 deletions

diff --git a/media-sound/sound-juicer/ChangeLog b/media-sound/sound-juicer/ChangeLog
index 5a457c07e667..7e4397bf3dc0 100644
--- a/media-sound/sound-juicer/ChangeLog
+++ b/media-sound/sound-juicer/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/sound-juicer
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/sound-juicer/ChangeLog,v 1.233 2014/04/27 08:05:36 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/sound-juicer/ChangeLog,v 1.234 2014/04/27 17:36:12 eva Exp $
+
+*sound-juicer-3.11.90 (27 Apr 2014)
+
+  27 Apr 2014; Gilles Dartiguelongue <eva@gentoo.org>
+  +sound-juicer-3.11.90.ebuild:
+  Version bump for Gnome 3.12.
 
   27 Apr 2014; Pacho Ramos <pacho@gentoo.org>
   -sound-juicer-3.5.1_pre20121231.ebuild:
diff --git a/media-sound/sound-juicer/sound-juicer-3.11.90.ebuild b/media-sound/sound-juicer/sound-juicer-3.11.90.ebuild
new file mode 100644
index 000000000000..6c966a7fc128
--- /dev/null
+++ b/media-sound/sound-juicer/sound-juicer-3.11.90.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/sound-juicer/sound-juicer-3.11.90.ebuild,v 1.1 2014/04/27 17:36:12 eva Exp $
+
+EAPI="5"
+GCONF_DEBUG="yes"
+
+inherit gnome2
+
+DESCRIPTION="CD ripper for GNOME"
+HOMEPAGE="http://www.burtonini.com/blog/computers/sound-juicer/"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="flac test vorbis"
+
+COMMON_DEPEND="
+	app-text/iso-codes
+	>=dev-libs/glib-2.32:2
+	>=x11-libs/gtk+-3.2:3
+	media-libs/libcanberra[gtk3]
+	>=app-cdr/brasero-2.90
+	sys-apps/dbus
+
+	media-libs/libdiscid
+	>=media-libs/musicbrainz-5.0.1:5
+
+	media-libs/gstreamer:1.0
+	media-libs/gst-plugins-base:1.0[vorbis?]
+	flac? ( media-plugins/gst-plugins-flac:1.0 )
+"
+RDEPEND="${COMMON_DEPEND}
+	gnome-base/gvfs[cdda,udev]
+	|| (
+		media-plugins/gst-plugins-cdparanoia:1.0
+		media-plugins/gst-plugins-cdio:1.0 )
+	media-plugins/gst-plugins-meta:1.0
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.50
+	>=app-text/scrollkeeper-0.3.5
+	virtual/pkgconfig
+	test? ( ~app-text/docbook-xml-dtd-4.3 )
+"
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# FIXME: gst macros does not take GST_INSPECT override anymore but we need a
+	# way to disable inspection due to gst-clutter always creating a GL context
+	# which is forbidden in sandbox since it needs write access to
+	# /dev/card*/dri
+	sed -e "s|\(gstinspect=\).*|\1$(type -P true)|" \
+		-i configure || die
+}
+
+src_configure() {
+	gnome2_src_configure ITSTOOLS="$(type -P true)"
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	if [ -z ${REPLACING_VERSIONS} ]; then
+		ewarn "The list of audio encoding profiles in ${P} is non-customizable."
+		ewarn "A possible workaround is to rip to flac using ${PN}, and convert to"
+		ewarn "your desired format using a separate tool."
+	fi
+}