Version bump.

(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key A792A613)

2 files changed, 73 insertions, 1 deletions

diff --git a/media-sound/ncmpcpp/ChangeLog b/media-sound/ncmpcpp/ChangeLog
index d7400d92311b..80171c863996 100644
--- a/media-sound/ncmpcpp/ChangeLog
+++ b/media-sound/ncmpcpp/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/ncmpcpp
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/ncmpcpp/ChangeLog,v 1.92 2014/12/08 19:01:22 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/ncmpcpp/ChangeLog,v 1.93 2014/12/15 14:07:19 jer Exp $
+
+*ncmpcpp-0.6.2 (15 Dec 2014)
+
+  15 Dec 2014; Jeroen Roovers <jer@gentoo.org> +ncmpcpp-0.6.2.ebuild:
+  Version bump.
 
   08 Dec 2014; Jeroen Roovers <jer@gentoo.org> ncmpcpp-0.6.1-r1.ebuild:
   Stable for HPPA (bug #531892).
diff --git a/media-sound/ncmpcpp/ncmpcpp-0.6.2.ebuild b/media-sound/ncmpcpp/ncmpcpp-0.6.2.ebuild
new file mode 100644
index 000000000000..d9ed27334de0
--- /dev/null
+++ b/media-sound/ncmpcpp/ncmpcpp-0.6.2.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/ncmpcpp/ncmpcpp-0.6.2.ebuild,v 1.1 2014/12/15 14:07:19 jer Exp $
+
+EAPI=5
+inherit bash-completion-r1 eutils
+
+DESCRIPTION="featureful ncurses based MPD client inspired by ncmpc"
+HOMEPAGE="http://ncmpcpp.rybczak.net/"
+SRC_URI="http://ncmpcpp.rybczak.net/stable/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~sparc ~x86"
+IUSE="clock curl outputs taglib unicode visualizer"
+
+RDEPEND="
+	>=media-libs/libmpdclient-2.1
+	curl? ( net-misc/curl )
+	dev-libs/boost[nls]
+	sys-libs/ncurses[unicode?]
+	sys-libs/readline
+	taglib? ( media-libs/taglib )
+	visualizer? ( sci-libs/fftw:3.0 )
+"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	sed -i -e '/^docdir/d' {,doc/}Makefile{.am,.in} || die
+	sed -i -e 's|COPYING||g' Makefile{.am,.in} || die
+}
+
+src_configure() {
+	econf \
+		$(use_enable clock) \
+		$(use_enable outputs) \
+		$(use_enable unicode) \
+		$(use_enable visualizer) \
+		$(use_with curl) \
+		$(use_with taglib) \
+		$(use_with visualizer fftw) \
+		--docdir=/usr/share/doc/${PF}
+}
+
+src_install() {
+	default
+
+	dodoc doc/{bindings,config}
+
+	newbashcomp doc/${PN}-completion.bash ${PN}
+}
+
+pkg_postinst() {
+	echo
+	elog "Example configuration files have been installed at"
+	elog "${ROOT}usr/share/doc/${PF}"
+	elog "${P} uses ~/.ncmpcpp/config and ~/.ncmpcpp/bindings"
+	elog "as user configuration files."
+	echo
+	if use visualizer; then
+	elog "If you want to use the visualizer, you need mpd with fifo enabled."
+	echo
+	fi
+}