Enable multilib support, bug #493176.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

3 files changed, 116 insertions, 1 deletions

diff --git a/media-libs/gst-plugins-bad/ChangeLog b/media-libs/gst-plugins-bad/ChangeLog
index ca39e6f323d5..df779eaea389 100644
--- a/media-libs/gst-plugins-bad/ChangeLog
+++ b/media-libs/gst-plugins-bad/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-libs/gst-plugins-bad
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/gst-plugins-bad/ChangeLog,v 1.147 2014/05/31 13:49:52 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/gst-plugins-bad/ChangeLog,v 1.148 2014/06/10 18:35:23 mgorny Exp $
+
+*gst-plugins-bad-0.10.23-r2 (10 Jun 2014)
+*gst-plugins-bad-1.2.4-r1 (10 Jun 2014)
+
+  10 Jun 2014; Michał Górny <mgorny@gentoo.org>
+  +gst-plugins-bad-0.10.23-r2.ebuild, +gst-plugins-bad-1.2.4-r1.ebuild:
+  Enable multilib support, bug #493176.
 
 *gst-plugins-bad-1.2.4 (31 May 2014)
 
diff --git a/media-libs/gst-plugins-bad/gst-plugins-bad-0.10.23-r2.ebuild b/media-libs/gst-plugins-bad/gst-plugins-bad-0.10.23-r2.ebuild
new file mode 100644
index 000000000000..e50e69048e2f
--- /dev/null
+++ b/media-libs/gst-plugins-bad/gst-plugins-bad-0.10.23-r2.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/gst-plugins-bad/gst-plugins-bad-0.10.23-r2.ebuild,v 1.1 2014/06/10 18:35:23 mgorny Exp $
+
+EAPI="5"
+
+GST_ORG_MODULE="gst-plugins-bad"
+inherit eutils flag-o-matic gstreamer
+
+DESCRIPTION="Less plugins for GStreamer"
+HOMEPAGE="http://gstreamer.freedesktop.org/"
+SRC_URI+=" http://dev.gentoo.org/~tetromino/distfiles/${PN}/${P}-h264-patches.tar.xz"
+
+LICENSE="LGPL-2"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="+orc"
+
+RDEPEND="
+	>=dev-libs/glib-2.24:2[${MULTILIB_USEDEP}]
+	>=media-libs/gst-plugins-base-0.10.36:${SLOT}[${MULTILIB_USEDEP}]
+	>=media-libs/gstreamer-0.10.36:${SLOT}[${MULTILIB_USEDEP}]
+	orc? ( >=dev-lang/orc-0.4.11[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}"
+RDEPEND="${RDEPEND}
+	!<media-plugins/gst-plugins-farsight-0.12.11:${SLOT}"
+
+src_prepare() {
+	# Patches from 0.10 branch fixing h264 baseline decoding; bug #446384
+	epatch "${WORKDIR}/${P}-h264-patches"/*.patch
+}
+
+src_configure() {
+	strip-flags
+	replace-flags "-O3" "-O2"
+	filter-flags "-fprefetch-loop-arrays" # (Bug #22249)
+
+	multilib-minimal_src_configure
+}
+
+multilib_src_configure() {
+	gstreamer_multilib_src_configure \
+		$(use_enable orc) \
+		--disable-examples \
+		--disable-debug
+}
+
+multilib_src_install_all() {
+	DOCS="AUTHORS ChangeLog NEWS README RELEASE"
+	einstalldocs
+	prune_libtool_files --modules
+}
diff --git a/media-libs/gst-plugins-bad/gst-plugins-bad-1.2.4-r1.ebuild b/media-libs/gst-plugins-bad/gst-plugins-bad-1.2.4-r1.ebuild
new file mode 100644
index 000000000000..2a13da4a05c0
--- /dev/null
+++ b/media-libs/gst-plugins-bad/gst-plugins-bad-1.2.4-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/gst-plugins-bad/gst-plugins-bad-1.2.4-r1.ebuild,v 1.1 2014/06/10 18:35:23 mgorny Exp $
+
+EAPI="5"
+
+GST_ORG_MODULE="gst-plugins-bad"
+inherit eutils flag-o-matic gstreamer
+
+DESCRIPTION="Less plugins for GStreamer"
+HOMEPAGE="http://gstreamer.freedesktop.org/"
+
+LICENSE="LGPL-2"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="egl +introspection +orc vnc"
+
+# FIXME: we need to depend on mesa to avoid automagic on egl
+# dtmf plugin moved from bad to good in 1.2
+# X11 is automagic for now, upstream #709530
+RDEPEND="
+	>=dev-libs/glib-2.32:2[${MULTILIB_USEDEP}]
+	>=media-libs/gst-plugins-base-1.2:${SLOT}[${MULTILIB_USEDEP}]
+	>=media-libs/gstreamer-1.2:${SLOT}[${MULTILIB_USEDEP}]
+	egl? ( media-libs/mesa[egl,${MULTILIB_USEDEP}] )
+	introspection? ( >=dev-libs/gobject-introspection-1.31.1 )
+	orc? ( >=dev-lang/orc-0.4.17[${MULTILIB_USEDEP}] )
+
+	!<media-libs/gst-plugins-good-1.1:${SLOT}
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.12
+"
+
+src_configure() {
+	strip-flags
+	replace-flags "-O3" "-O2"
+	filter-flags "-fprefetch-loop-arrays" # (Bug #22249)
+
+	multilib-minimal_src_configure
+}
+
+multilib_src_configure() {
+	gstreamer_multilib_src_configure \
+		$(multilib_native_use_enable introspection) \
+		$(use_enable orc) \
+		$(use_enable vnc librfb) \
+		--disable-examples \
+		--disable-debug \
+		--with-egl-window-system=$(usex egl x11 none)
+}
+
+multilib_src_install_all() {
+	DOCS="AUTHORS ChangeLog NEWS README RELEASE"
+	einstalldocs
+	prune_libtool_files --modules
+}