Enable multilib support, bug #493176.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

3 files changed, 173 insertions, 1 deletions

diff --git a/media-libs/gst-plugins-base/ChangeLog b/media-libs/gst-plugins-base/ChangeLog
index c4e187508899..594ab5a2da16 100644
--- a/media-libs/gst-plugins-base/ChangeLog
+++ b/media-libs/gst-plugins-base/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-libs/gst-plugins-base
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/gst-plugins-base/ChangeLog,v 1.245 2014/05/31 14:01:07 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/gst-plugins-base/ChangeLog,v 1.246 2014/06/10 18:33:55 mgorny Exp $
+
+*gst-plugins-base-0.10.36-r1 (10 Jun 2014)
+*gst-plugins-base-1.2.4-r1 (10 Jun 2014)
+
+  10 Jun 2014; Michał Górny <mgorny@gentoo.org>
+  +gst-plugins-base-0.10.36-r1.ebuild, +gst-plugins-base-1.2.4-r1.ebuild:
+  Enable multilib support, bug #493176.
 
 *gst-plugins-base-1.2.4 (31 May 2014)
 
diff --git a/media-libs/gst-plugins-base/gst-plugins-base-0.10.36-r1.ebuild b/media-libs/gst-plugins-base/gst-plugins-base-0.10.36-r1.ebuild
new file mode 100644
index 000000000000..80bd419f70db
--- /dev/null
+++ b/media-libs/gst-plugins-base/gst-plugins-base-0.10.36-r1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/gst-plugins-base/gst-plugins-base-0.10.36-r1.ebuild,v 1.1 2014/06/10 18:33:55 mgorny Exp $
+
+EAPI="5"
+
+GST_ORG_MODULE="gst-plugins-base"
+inherit gstreamer
+
+DESCRIPTION="Basepack of plugins for gstreamer"
+HOMEPAGE="http://gstreamer.freedesktop.org/"
+
+LICENSE="GPL-2+ LGPL-2+"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="+introspection nls +orc"
+
+RDEPEND=">=media-libs/gstreamer-${PV}:0.10[introspection?,${MULTILIB_USEDEP}]
+	dev-libs/libxml2:2[${MULTILIB_USEDEP}]
+	sys-libs/zlib[${MULTILIB_USEDEP}]
+	app-text/iso-codes
+	introspection? ( >=dev-libs/gobject-introspection-0.9.12 )
+	orc? ( >=dev-lang/orc-0.4.11[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.3
+"
+RDEPEND="${RDEPEND}
+	!<media-libs/gst-plugins-bad-0.10.10:0.10
+	abi_x86_32? (
+		!<=app-emulation/emul-linux-x86-medialibs-20140508-r5
+		!app-emulation/emul-linux-x86-medialibs[-abi_x86_32(-)]
+	)
+"
+
+src_prepare() {
+	# The AC_PATH_XTRA macro unnecessarily pulls in libSM and libICE even
+	# though they are not actually used. This needs to be fixed upstream by
+	# replacing AC_PATH_XTRA with PKG_CONFIG calls.
+	sed -i -e 's:X_PRE_LIBS -lSM -lICE:X_PRE_LIBS:' "${S}"/configure || die
+}
+
+multilib_src_configure() {
+	gstreamer_multilib_src_configure \
+		$(multilib_native_use_enable introspection) \
+		$(use_enable nls) \
+		$(use_enable orc) \
+		--disable-examples \
+		--disable-debug \
+		--disable-static
+
+	# bug #366931, flag-o-matic for the whole thing is overkill
+	if [[ ${CHOST} == *86-*-darwin* ]] ; then
+		sed -i \
+			-e '/FLAGS = /s|-O[23]|-O1|g' \
+			gst/audioconvert/Makefile \
+			gst/volume/Makefile || die
+	fi
+
+	if multilib_is_native_abi; then
+		local x
+		for x in libs plugins; do
+			ln -s "${S}"/docs/${x}/html docs/${x}/html || die
+		done
+	fi
+}
+
+multilib_src_install_all() {
+	DOCS="AUTHORS NEWS README RELEASE"
+	einstalldocs
+	prune_libtool_files --modules
+}
diff --git a/media-libs/gst-plugins-base/gst-plugins-base-1.2.4-r1.ebuild b/media-libs/gst-plugins-base/gst-plugins-base-1.2.4-r1.ebuild
new file mode 100644
index 000000000000..486cee865f35
--- /dev/null
+++ b/media-libs/gst-plugins-base/gst-plugins-base-1.2.4-r1.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/gst-plugins-base/gst-plugins-base-1.2.4-r1.ebuild,v 1.1 2014/06/10 18:33:55 mgorny Exp $
+
+EAPI="5"
+
+GST_ORG_MODULE="gst-plugins-base"
+inherit gstreamer
+
+DESCRIPTION="Basepack of plugins for gstreamer"
+HOMEPAGE="http://gstreamer.freedesktop.org/"
+
+LICENSE="GPL-2+ LGPL-2+"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="alsa +introspection ivorbis +ogg +orc +pango theora +vorbis X"
+REQUIRED_USE="
+	ivorbis? ( ogg )
+	theora? ( ogg )
+	vorbis? ( ogg )
+"
+
+RDEPEND="
+	app-text/iso-codes
+	>=dev-libs/glib-2.32:2[${MULTILIB_USEDEP}]
+	>=media-libs/gstreamer-1.2.0:1.0[introspection?,${MULTILIB_USEDEP}]
+	sys-libs/zlib[${MULTILIB_USEDEP}]
+	alsa? ( >=media-libs/alsa-lib-0.9.1[${MULTILIB_USEDEP}] )
+	introspection? ( >=dev-libs/gobject-introspection-1.31.1 )
+	ivorbis? ( media-libs/tremor[${MULTILIB_USEDEP}] )
+	ogg? ( >=media-libs/libogg-1[${MULTILIB_USEDEP}] )
+	orc? ( >=dev-lang/orc-0.4.18[${MULTILIB_USEDEP}] )
+	pango? ( >=x11-libs/pango-1.22[${MULTILIB_USEDEP}] )
+	theora? ( >=media-libs/libtheora-1.1[encode,${MULTILIB_USEDEP}] )
+	vorbis? ( >=media-libs/libvorbis-1[${MULTILIB_USEDEP}] )
+	X? (
+		x11-libs/libX11[${MULTILIB_USEDEP}]
+		x11-libs/libXext[${MULTILIB_USEDEP}]
+		x11-libs/libXv[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.12
+	X? (
+		x11-proto/videoproto[${MULTILIB_USEDEP}]
+		x11-proto/xextproto[${MULTILIB_USEDEP}]
+		x11-proto/xproto[${MULTILIB_USEDEP}] )
+"
+
+src_prepare() {
+	# The AC_PATH_XTRA macro unnecessarily pulls in libSM and libICE even
+	# though they are not actually used. This needs to be fixed upstream by
+	# replacing AC_PATH_XTRA with PKG_CONFIG calls, upstream bug #731047
+	sed -i -e 's:X_PRE_LIBS -lSM -lICE:X_PRE_LIBS:' "${S}"/configure || die
+}
+
+multilib_src_configure() {
+	gstreamer_multilib_src_configure \
+		$(use_enable alsa) \
+		$(multilib_native_use_enable introspection) \
+		$(use_enable ivorbis) \
+		$(use_enable ogg) \
+		$(use_enable orc) \
+		$(use_enable pango) \
+		$(use_enable theora) \
+		$(use_enable vorbis) \
+		$(use_enable X x) \
+		$(use_enable X xshm) \
+		$(use_enable X xvideo) \
+		--disable-debug \
+		--disable-examples \
+		--disable-freetypetest \
+		--disable-static
+	# cdparanoia and libvisual are split out, per leio's request
+
+	# bug #366931, flag-o-matic for the whole thing is overkill
+	if [[ ${CHOST} == *86-*-darwin* ]] ; then
+		sed -i \
+			-e '/FLAGS = /s|-O[23]|-O1|g' \
+			gst/audioconvert/Makefile \
+			gst/volume/Makefile || die
+	fi
+
+	if multilib_is_native_abi; then
+		local x
+		for x in libs plugins; do
+			ln -s "${S}"/docs/${x}/html docs/${x}/html || die
+		done
+	fi
+}
+
+multilib_src_install_all() {
+	DOCS="AUTHORS NEWS README RELEASE"
+	einstalldocs
+	prune_libtool_files --modules
+}