Version bump for gnome-3.6. Switch to global introspection USE flag.

(Portage version: 2.2.0_alpha148/cvs/Linux x86_64, signed Manifest commit with key CF0ADD61)

3 files changed, 114 insertions, 3 deletions

diff --git a/media-libs/clutter/ChangeLog b/media-libs/clutter/ChangeLog
index 8233e9e132fe..16a1d0ecd919 100644
--- a/media-libs/clutter/ChangeLog
+++ b/media-libs/clutter/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/clutter
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/clutter/ChangeLog,v 1.59 2012/12/05 23:12:48 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/clutter/ChangeLog,v 1.60 2012/12/16 22:04:03 tetromino Exp $
+
+*clutter-1.12.2 (16 Dec 2012)
+
+  16 Dec 2012; Alexandre Rostovtsev <tetromino@gentoo.org>
+  +clutter-1.12.2.ebuild, metadata.xml:
+  Version bump for gnome-3.6. Switch to global introspection USE flag.
 
   05 Dec 2012; Alexandre Rostovtsev <tetromino@gentoo.org>
   -clutter-1.2.14.ebuild, -clutter-1.6.16.ebuild, -clutter-1.6.20.ebuild,
diff --git a/media-libs/clutter/clutter-1.12.2.ebuild b/media-libs/clutter/clutter-1.12.2.ebuild
new file mode 100644
index 000000000000..7cad398eecb9
--- /dev/null
+++ b/media-libs/clutter/clutter-1.12.2.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/clutter/clutter-1.12.2.ebuild,v 1.1 2012/12/16 22:04:03 tetromino Exp $
+
+EAPI="5"
+CLUTTER_LA_PUNT="yes"
+
+# Inherit gnome2 after clutter to download sources from gnome.org
+# since clutter-project.org doesn't provide .xz tarballs
+inherit clutter gnome2 virtualx
+
+DESCRIPTION="Clutter is a library for creating graphical user interfaces"
+
+LICENSE="LGPL-2.1+ FDL-1.1+"
+SLOT="1.0"
+IUSE="debug doc gtk +introspection test" # evdev tslib
+KEYWORDS="~alpha ~amd64 ~mips ~ppc ~ppc64 ~x86"
+
+# NOTE: glx flavour uses libdrm + >=mesa-7.3
+# XXX: uprof needed for profiling
+# >=libX11-1.3.1 needed for X Generic Event support
+RDEPEND="
+	>=dev-libs/glib-2.31.19:2
+	>=dev-libs/atk-2.5.3[introspection?]
+	>=dev-libs/json-glib-0.12[introspection?]
+	>=media-libs/cogl-1.9.6:1.0=[introspection?,pango]
+	media-libs/fontconfig
+	>=x11-libs/cairo-1.10:=[glib]
+	>=x11-libs/pango-1.30[introspection?]
+
+	virtual/opengl
+	x11-libs/libdrm:=
+	>=x11-libs/libX11-1.3.1
+	x11-libs/libXext
+	x11-libs/libXdamage
+	x11-proto/inputproto
+	>=x11-libs/libXi-1.3
+	>=x11-libs/libXfixes-3
+	>=x11-libs/libXcomposite-0.4
+
+	gtk? ( >=x11-libs/gtk+-3.3.18:3 )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.6 )"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.15
+	virtual/pkgconfig
+	>=sys-devel/gettext-0.17
+	doc? (
+		>=dev-util/gtk-doc-1.15
+		>=app-text/docbook-sgml-utils-0.6.14[jadetex]
+		dev-libs/libxslt )
+	test? ( x11-libs/gdk-pixbuf )"
+
+# Tests fail with both swrast and llvmpipe
+# They pass under r600g or i965, so the bug is in mesa
+RESTRICT="test"
+
+src_prepare() {
+	DOCS="README NEWS ChangeLog*"
+
+	# XXX: Conformance test suite (and clutter itself) does not work under Xvfb
+	# (GLX error blabla)
+	# XXX: Profiling, coverage disabled for now
+	# XXX: What about cex100/egl/osx/wayland/win32 backends?
+	# XXX: evdev/tslib input seem to be experimental?
+	G2CONF="${G2CONF} ${myconf}
+		--enable-xinput
+		--enable-x11-backend=yes
+		--disable-profile
+		--disable-maintainer-flags
+		--disable-gcov
+		--disable-cex100-backend
+		--disable-egl-backend
+		--disable-quartz-backend
+		--disable-wayland-backend
+		--disable-win32-backend
+		--disable-tslib-input
+		--disable-evdev-input
+		$(usex debug --enable-debug=yes --enable-debug=minimum)
+		$(use_enable gtk gdk-backend)
+		$(use_enable introspection)
+		$(use_enable doc docs)
+		$(use_enable test conformance)
+		$(use_enable test gdk-pixbuf)"
+
+	# We only need conformance tests, the rest are useless for us
+	sed -e 's/^\(SUBDIRS =\).*/\1/g' \
+		-i tests/Makefile.am || die "am tests sed failed"
+	sed -e 's/^\(SUBDIRS =\)[^\]*/\1/g' \
+		-i tests/Makefile.in || die "in tests sed failed"
+
+	gnome2_src_prepare
+}
+
+src_compile() {
+	default
+	if use test; then
+		emake -C tests/conform
+	fi
+}
+
+src_test() {
+	Xemake check
+}
+
+src_install() {
+	clutter_src_install
+}
diff --git a/media-libs/clutter/metadata.xml b/media-libs/clutter/metadata.xml
index 470e6fcbaad7..8fcea51eeef5 100644
--- a/media-libs/clutter/metadata.xml
+++ b/media-libs/clutter/metadata.xml
@@ -4,7 +4,5 @@
 <herd>gnome</herd>
 <use>
 	<flag name="gtk">Use gdk-pixbuf from <pkg>x11-libs/gtk+</pkg> as image rendering backend</flag>
-	<flag name="introspection">Use <pkg>dev-libs/gobject-introspection</pkg> for
-		introspection</flag>
 </use>
 </pkgmetadata>