Version bump.

(Portage version: 2.2.0_alpha108/cvs/Linux x86_64)

2 files changed, 72 insertions, 1 deletions

diff --git a/media-libs/libzen/ChangeLog b/media-libs/libzen/ChangeLog
index 58d0d6e4b02e..df2004fe4966 100644
--- a/media-libs/libzen/ChangeLog
+++ b/media-libs/libzen/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/libzen
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libzen/ChangeLog,v 1.38 2012/05/10 07:17:38 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libzen/ChangeLog,v 1.39 2012/05/31 10:18:43 radhermit Exp $
+
+*libzen-0.4.27 (31 May 2012)
+
+  31 May 2012; Tim Harder <radhermit@gentoo.org> +libzen-0.4.27.ebuild:
+  Version bump.
 
   10 May 2012; Tim Harder <radhermit@gentoo.org> -libzen-0.4.25.ebuild:
   Remove old.
diff --git a/media-libs/libzen/libzen-0.4.27.ebuild b/media-libs/libzen/libzen-0.4.27.ebuild
new file mode 100644
index 000000000000..1afbf98f0545
--- /dev/null
+++ b/media-libs/libzen/libzen-0.4.27.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libzen/libzen-0.4.27.ebuild,v 1.1 2012/05/31 10:18:43 radhermit Exp $
+
+EAPI="4"
+
+inherit autotools multilib
+
+MY_PN="ZenLib"
+DESCRIPTION="Shared library for libmediainfo and mediainfo"
+HOMEPAGE="http://sourceforge.net/projects/zenlib"
+SRC_URI="mirror://sourceforge/zenlib/${MY_PN}%20-%20Sources/${PV}/${PN}_${PV}.tar.bz2"
+
+LICENSE="as-is ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc static-libs"
+
+RDEPEND="sys-libs/zlib"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )"
+
+S=${WORKDIR}/${MY_PN}/Project/GNU/Library
+
+src_prepare() {
+	sed -i -e "s:-O2::" configure.ac
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-unicode \
+		--enable-shared \
+		$(use_enable static-libs static)
+}
+
+src_compile() {
+	default
+
+	if use doc ; then
+		cd "${WORKDIR}"/${MY_PN}/Source/Doc
+		doxygen Doxyfile || die
+	fi
+}
+
+src_install() {
+	default
+
+	# remove since the pkgconfig file should be used instead
+	rm "${D}"/usr/bin/libzen-config
+
+	insinto /usr/$(get_libdir)/pkgconfig
+	doins ${PN}.pc
+
+	for x in ./ Format/Html Format/Http HTTP_Client ; do
+		insinto /usr/include/${MY_PN}/${x}
+		doins "${WORKDIR}"/${MY_PN}/Source/${MY_PN}/${x}/*.h
+	done
+
+	dodoc "${WORKDIR}"/${MY_PN}/History.txt
+	if use doc ; then
+		dohtml "${WORKDIR}"/${MY_PN}/Doc/*
+	fi
+
+	find "${ED}" -name '*.la' -exec rm -f {} +
+}