version bump

(Portage version: 2.2.0_alpha44/cvs/Linux x86_64)

2 files changed, 63 insertions, 1 deletions

diff --git a/media-libs/libsndfile/ChangeLog b/media-libs/libsndfile/ChangeLog
index 6ca091430690..a88eeaed5213 100644
--- a/media-libs/libsndfile/ChangeLog
+++ b/media-libs/libsndfile/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/libsndfile
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libsndfile/ChangeLog,v 1.122 2011/03/24 08:09:37 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libsndfile/ChangeLog,v 1.123 2011/07/13 20:08:44 aballier Exp $
+
+*libsndfile-1.0.25 (13 Jul 2011)
+
+  13 Jul 2011; Alexis Ballier <aballier@gentoo.org> +libsndfile-1.0.25.ebuild:
+  version bump
 
 *libsndfile-1.0.24 (24 Mar 2011)
 
diff --git a/media-libs/libsndfile/libsndfile-1.0.25.ebuild b/media-libs/libsndfile/libsndfile-1.0.25.ebuild
new file mode 100644
index 000000000000..bb25d7cc0dc3
--- /dev/null
+++ b/media-libs/libsndfile/libsndfile-1.0.25.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libsndfile/libsndfile-1.0.25.ebuild,v 1.1 2011/07/13 20:08:44 aballier Exp $
+
+EAPI=4
+inherit eutils autotools
+
+MY_P=${P/_pre/pre}
+
+DESCRIPTION="A C library for reading and writing files containing sampled sound"
+HOMEPAGE="http://www.mega-nerd.com/libsndfile"
+if [[ "${MY_P}" == "${P}" ]]; then
+	SRC_URI="http://www.mega-nerd.com/libsndfile/files/${P}.tar.gz"
+else
+	SRC_URI="http://www.mega-nerd.com/tmp/${MY_P}b.tar.gz"
+fi
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="alsa minimal sqlite static-libs"
+
+RDEPEND="!minimal? ( >=media-libs/flac-1.2.1
+		>=media-libs/libogg-1.1.3
+		>=media-libs/libvorbis-1.2.3 )
+	alsa? ( media-libs/alsa-lib )
+	sqlite? ( >=dev-db/sqlite-3.2 )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	sed -i -e "s/noinst_PROGRAMS/check_PROGRAMS/" "${S}/tests/Makefile.am" \
+		"${S}/examples/Makefile.am" || die "sed failed"
+
+	epatch "${FILESDIR}"/${PN}-1.0.17-regtests-need-sqlite.patch
+
+	AT_M4DIR=M4 eautoreconf
+	epunt_cxx
+}
+
+src_configure() {
+	econf $(use_enable sqlite) \
+		$(use_enable static-libs static) \
+		$(use_enable alsa) \
+		$(use_enable !minimal external-libs) \
+		htmldocdir=/usr/share/doc/${PF}/html \
+		--disable-octave \
+		--disable-gcc-werror \
+		--disable-gcc-pipe
+}
+
+src_install() {
+	emake DESTDIR="${D}" htmldocdir="/usr/share/doc/${PF}/html" install
+	dodoc AUTHORS ChangeLog NEWS README
+}