Version bump.

(Portage version: 2.2_rc1/cvs/Linux 2.6.26-rc3 x86_64)

1 files changed, 57 insertions, 0 deletions

diff --git a/media-libs/gstreamer/gstreamer-0.10.20.ebuild b/media-libs/gstreamer/gstreamer-0.10.20.ebuild
new file mode 100644
index 000000000000..f97de2c26e70
--- /dev/null
+++ b/media-libs/gstreamer/gstreamer-0.10.20.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/gstreamer/gstreamer-0.10.20.ebuild,v 1.1 2008/06/29 14:43:26 drac Exp $
+
+inherit libtool
+
+# Create a major/minor combo for our SLOT and executables suffix
+PVP=(${PV//[-\._]/ })
+PV_MAJ_MIN=${PVP[0]}.${PVP[1]}
+
+DESCRIPTION="Streaming media framework"
+HOMEPAGE="http://gstreamer.sourceforge.net"
+SRC_URI="http://${PN}.freedesktop.org/src/${PN}/${P}.tar.bz2"
+
+LICENSE="LGPL-2"
+SLOT=${PV_MAJ_MIN}
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="debug nls test"
+
+RDEPEND=">=dev-libs/glib-2.12
+	>=dev-libs/libxml2-2.4.9
+	>=dev-libs/check-0.9.2"
+DEPEND="${RDEPEND}
+	nls? ( >=sys-devel/gettext-0.11.5 )
+	dev-util/pkgconfig
+	!<media-libs/gst-plugins-ugly-0.10.6-r1"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	# Needed for sane .so versioning on Gentoo/FreeBSD
+	elibtoolize
+}
+
+src_compile() {
+	econf --disable-dependency-tracking \
+		--with-package-name="Gentoo GStreamer ebuild" \
+		--with-package-origin="http://www.gentoo.org" \
+		$(use_enable test tests) \
+		$(use_enable debug) \
+		$(use_enable nls)
+
+	emake || die "emake failed."
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed."
+	dodoc AUTHORS ChangeLog NEWS README RELEASE
+
+	# Remove unversioned binaries to allow SLOT installations in future.
+	cd "${D}"/usr/bin
+	local gst_bins
+	for gst_bins in $(ls *-${PV_MAJ_MIN}) ; do
+		rm ${gst_bins/-${PV_MAJ_MIN}/}
+		einfo "Removed ${gst_bins/-${PV_MAJ_MIN}/}"
+	done
+}