version bump (bug #390375), added static-libs support (bug #378205), depend on python2 only with USE=doc and in DEPEND (bug #398959), set dev-util/pkgconfig dependencies again for older ebuilds due to profile-errors during commit (feel free to fix it)

(Portage version: 2.2.0_alpha111/cvs/Linux x86_64)

5 files changed, 146 insertions, 7 deletions

diff --git a/media-gfx/exiv2/ChangeLog b/media-gfx/exiv2/ChangeLog
index cd837861c93a..3e742ce90e12 100644
--- a/media-gfx/exiv2/ChangeLog
+++ b/media-gfx/exiv2/ChangeLog
@@ -1,6 +1,15 @@
 # ChangeLog for media-gfx/exiv2
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/exiv2/ChangeLog,v 1.99 2012/05/17 16:31:08 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/exiv2/ChangeLog,v 1.100 2012/06/24 21:36:09 sbriesen Exp $
+
+*exiv2-0.23 (24 Jun 2012)
+
+  24 Jun 2012; Stefan Briesenick <sbriesen@gentoo.org> exiv2-0.19.ebuild,
+  exiv2-0.21.1-r1.ebuild, exiv2-0.21.1-r2.ebuild, +exiv2-0.23.ebuild:
+  version bump (bug #390375), added static-libs support (bug #378205), depend
+  on python2 only with USE=doc and in DEPEND (bug #398959), set
+  dev-util/pkgconfig dependencies again for older ebuilds due to profile-errors
+  during commit (feel free to fix it)
 
   17 May 2012; Alexis Ballier <aballier@gentoo.org> exiv2-0.21.1-r2.ebuild:
   keyword ~amd64-fbsd
diff --git a/media-gfx/exiv2/exiv2-0.19.ebuild b/media-gfx/exiv2/exiv2-0.19.ebuild
index 76a1198165d3..60e72cfb39e0 100644
--- a/media-gfx/exiv2/exiv2-0.19.ebuild
+++ b/media-gfx/exiv2/exiv2-0.19.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/exiv2/exiv2-0.19.ebuild,v 1.9 2012/05/05 07:00:18 jdhore Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/exiv2/exiv2-0.19.ebuild,v 1.10 2012/06/24 21:36:09 sbriesen Exp $
 
 EAPI="2"
 
@@ -29,7 +29,7 @@ DEPEND="${RDEPEND}
 		dev-lang/python
 		app-doc/doxygen
 		dev-libs/libxslt
-		virtual/pkgconfig
+		dev-util/pkgconfig
 		media-gfx/graphviz
 	)
 	nls? ( sys-devel/gettext )
diff --git a/media-gfx/exiv2/exiv2-0.21.1-r1.ebuild b/media-gfx/exiv2/exiv2-0.21.1-r1.ebuild
index 8d224742cab4..5b259024df8a 100644
--- a/media-gfx/exiv2/exiv2-0.21.1-r1.ebuild
+++ b/media-gfx/exiv2/exiv2-0.21.1-r1.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/exiv2/exiv2-0.21.1-r1.ebuild,v 1.5 2012/05/05 07:00:18 jdhore Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/exiv2/exiv2-0.21.1-r1.ebuild,v 1.6 2012/06/24 21:36:09 sbriesen Exp $
 
 EAPI=3
 PYTHON_DEPEND="2"
@@ -29,7 +29,7 @@ DEPEND="${RDEPEND}
 	doc? (
 		app-doc/doxygen
 		dev-libs/libxslt
-		virtual/pkgconfig
+		dev-util/pkgconfig
 		media-gfx/graphviz
 	)
 	nls? ( sys-devel/gettext )
diff --git a/media-gfx/exiv2/exiv2-0.21.1-r2.ebuild b/media-gfx/exiv2/exiv2-0.21.1-r2.ebuild
index e3b6a9ae4a30..287ea4030ef0 100644
--- a/media-gfx/exiv2/exiv2-0.21.1-r2.ebuild
+++ b/media-gfx/exiv2/exiv2-0.21.1-r2.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/exiv2/exiv2-0.21.1-r2.ebuild,v 1.4 2012/05/17 16:31:08 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/exiv2/exiv2-0.21.1-r2.ebuild,v 1.5 2012/06/24 21:36:09 sbriesen Exp $
 
 EAPI=3
 PYTHON_DEPEND="2"
@@ -29,7 +29,7 @@ DEPEND="${RDEPEND}
 	doc? (
 		app-doc/doxygen
 		dev-libs/libxslt
-		virtual/pkgconfig
+		dev-util/pkgconfig
 		media-gfx/graphviz
 	)
 	nls? ( sys-devel/gettext )
diff --git a/media-gfx/exiv2/exiv2-0.23.ebuild b/media-gfx/exiv2/exiv2-0.23.ebuild
new file mode 100644
index 000000000000..6c1336f6859e
--- /dev/null
+++ b/media-gfx/exiv2/exiv2-0.23.ebuild
@@ -0,0 +1,130 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/exiv2/exiv2-0.23.ebuild,v 1.1 2012/06/24 21:36:09 sbriesen Exp $
+
+EAPI=4
+AUTOTOOLS_IN_SOURCE_BUILD=1
+
+inherit eutils autotools-utils multilib toolchain-funcs python
+
+DESCRIPTION="EXIF and IPTC metadata C++ library and command line utility"
+HOMEPAGE="http://www.exiv2.org/"
+SRC_URI="http://www.exiv2.org/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE_LINGUAS="de es fi fr pl ru sk"
+IUSE="contrib doc examples nls xmp zlib static-libs $(printf 'linguas_%s ' ${IUSE_LINGUAS})"
+
+RDEPEND="
+	virtual/libiconv
+	nls? ( virtual/libintl )
+	xmp? ( dev-libs/expat )
+	zlib? ( sys-libs/zlib )
+"
+DEPEND="${RDEPEND}
+	contrib? ( >=dev-libs/boost-1.37 )
+	doc? (
+		app-doc/doxygen
+		dev-libs/libxslt
+		dev-util/pkgconfig
+		media-gfx/graphviz
+		=dev-lang/python-2*
+	)
+	nls? ( sys-devel/gettext )
+"
+
+DOCS=( README doc/ChangeLog doc/cmd.txt )
+
+src_prepare() {
+	# exiv2 fails to build with boost-1.46 due to boost filesystem
+	# API v3 becoming the default. This is easily fixed by adding a
+	#  #define BOOST_FILESYSTEM_VERSION 2
+	# to source files that include boost/filesystem.hpp
+	#
+	# Implemented via sed to avoid patch-file (bug #357605)
+	sed -i -e \
+		's|^\(#include <boost/filesystem.hpp>.*\)|#define BOOST_FILESYSTEM_VERSION 2\n\1|g' \
+		contrib/organize/helpers.hpp
+
+	# convert docs to UTF-8
+	local i
+	for i in doc/cmd.txt; do
+		einfo "Converting "${i}" to UTF-8"
+		iconv -f LATIN1 -t UTF-8 "${i}" > "${i}~" && mv -f "${i}~" "${i}" || rm -f "${i}~"
+	done
+
+	if use doc; then
+		einfo "Updating doxygen config"
+		doxygen 2>&1 >/dev/null -u config/Doxyfile
+		python_convert_shebangs -r 2 doc/templates
+	fi
+
+	if use contrib; then
+		# create build environment for contrib
+		ln -snf ../../src contrib/organize/exiv2
+		sed -i -e 's:/usr/local/include/.*:/usr/include:g' \
+			-e 's:/usr/local/lib/lib:-l:g' -e 's:-gcc..-mt-._..\.a::g' \
+			contrib/organize/boost.mk
+	fi
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable nls)
+		$(use_enable xmp)
+		$(use_enable static-libs static)
+	)
+
+	# plain 'use_with' fails
+	use zlib || myeconfargs+=("${myconf} --without-zlib")
+
+	# Bug #78720. amd64/gcc-3.4/-fvisibility* fail.
+	if [ $(gcc-major-version) -lt 4 ]; then
+		use amd64 && myeconfargs+=("${myconf} --disable-visibility")
+	fi
+
+	autotools-utils_src_configure
+}
+
+src_compile() {
+	autotools-utils_src_compile
+
+	if use contrib; then
+		emake -C contrib/organize \
+			LDFLAGS="\$(BOOST_LIBS) -L../../src -lexiv2 ${LDFLAGS}" \
+			CPPFLAGS="${CPPFLAGS} -I\$(BOOST_INC_DIR) -I. -DEXV_HAVE_STDINT_H" \
+		|| die "emake organize failed"
+	fi
+
+	if use doc; then
+		emake doc || die "emake doc failed"
+	fi
+}
+
+src_install() {
+	autotools-utils_src_install
+
+	if use contrib; then
+		emake DESTDIR="${D}" -C contrib/organize install || die "emake install organize failed"
+	fi
+
+	use xmp && dodoc doc/{COPYING-XMPSDK,README-XMP,cmdxmp.txt}
+	use doc && dohtml -r doc/html/.
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		docompress -x /usr/share/doc/${PF}/examples
+		doins samples/*.cpp
+	fi
+}
+
+pkg_postinst() {
+	ewarn
+	ewarn "PLEASE PLEASE take note of this:"
+	ewarn "Please make *sure* to run revdep-rebuild now"
+	ewarn "Certain things on your system may have linked against a"
+	ewarn "different version of exiv2 -- those things need to be"
+	ewarn "recompiled. Sorry for the inconvenience!"
+	ewarn
+}