Version bump KDE SC 4.9.5

(Portage version: 2.2.0_alpha149/cvs/Linux x86_64, RepoMan options: --force, signed Manifest commit with key 42618354)

2 files changed, 84 insertions, 2 deletions

diff --git a/kde-base/korundum/ChangeLog b/kde-base/korundum/ChangeLog
index e05ecea6c075..eef346f0b4ce 100644
--- a/kde-base/korundum/ChangeLog
+++ b/kde-base/korundum/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/korundum
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/korundum/ChangeLog,v 1.136 2012/12/26 10:48:13 maekke Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/korundum/ChangeLog,v 1.137 2013/01/05 20:18:40 creffett Exp $
+
+*korundum-4.9.5 (05 Jan 2013)
+
+  05 Jan 2013; <creffett@gentoo.org> +korundum-4.9.5.ebuild:
+  Version bump KDE SC 4.9.5
 
   26 Dec 2012; Markus Meier <maekke@gentoo.org> korundum-4.9.4.ebuild:
   add ~arm
diff --git a/kde-base/korundum/korundum-4.9.5.ebuild b/kde-base/korundum/korundum-4.9.5.ebuild
new file mode 100644
index 000000000000..02ed42f22070
--- /dev/null
+++ b/kde-base/korundum/korundum-4.9.5.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/korundum/korundum-4.9.5.ebuild,v 1.1 2013/01/05 20:18:40 creffett Exp $
+
+EAPI=4
+
+OPENGL_REQUIRED="always"
+
+USE_RUBY="ruby18"
+# No ruby19 for three reasons:
+# 1) it does not build (yet) - will likely be solved soon
+# 2) cmake bails when configuring twice or more - solved with CMAKE_IN_SOURCE_BUILD=1
+# 3) the ebuild can only be installed for one ruby variant, otherwise the compiled
+#    files with identical path+name will overwrite each other - difficult :(
+
+inherit kde4-base ruby-ng
+
+DESCRIPTION="KDE Ruby bindings"
+KEYWORDS="~amd64 ~arm ~ppc ~x86 ~amd64-linux ~x86-linux"
+IUSE="akonadi debug kate okular"
+
+# unfortunately single modules cannot be disabled with cmake defines
+# possible more useflags have no effect... does anyone actually build this stuff?
+# may need some hacking, for now semantic-desktop just becomes a hard dependency
+
+DEPEND="
+	$(add_kdebase_dep qtruby)
+	$(add_kdebase_dep smokekde 'kate?,okular?,semantic-desktop')
+	$(add_kdebase_dep smokeqt)
+"
+RDEPEND="${DEPEND}
+"
+
+# Split from kdebindings-ruby in 4.7
+add_blocker kdebindings-ruby
+
+pkg_setup() {
+	ruby-ng_pkg_setup
+	kde4-base_pkg_setup
+}
+
+src_unpack() {
+	local S="${WORKDIR}/${P}"
+	kde4-base_src_unpack
+
+	cd "${WORKDIR}"
+	mkdir all
+	mv ${P} all/ || die "Could not move sources"
+}
+
+all_ruby_prepare() {
+	kde4-base_src_prepare
+}
+
+each_ruby_configure() {
+	CMAKE_USE_DIR=${S}
+	mycmakeargs=(
+		-DRUBY_LIBRARY=$(ruby_get_libruby)
+		-DRUBY_INCLUDE_PATH=$(ruby_get_hdrdir)
+		-DRUBY_EXECUTABLE=${RUBY}
+		$(cmake-utils_use_with akonadi)
+		$(cmake-utils_use_with akonadi KdepimLibs)
+		$(cmake-utils_use_disable kate)
+		$(cmake-utils_use_with okular)
+	)
+	kde4-base_src_configure
+}
+
+each_ruby_compile() {
+	CMAKE_USE_DIR=${S}
+	kde4-base_src_compile
+}
+
+each_ruby_install() {
+	CMAKE_USE_DIR=${S}
+	kde4-base_src_install
+}