[kde-base] Add KDE SC 4.9.4

(Portage version: 2.2.0_alpha144/cvs/Linux x86_64, signed Manifest commit with key F82F92E6)

2 files changed, 93 insertions, 1 deletions

diff --git a/kde-base/kde-l10n/ChangeLog b/kde-base/kde-l10n/ChangeLog
index 72b3e3c8fd13..9c581259ca6d 100644
--- a/kde-base/kde-l10n/ChangeLog
+++ b/kde-base/kde-l10n/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/kde-l10n
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kde-l10n/ChangeLog,v 1.157 2012/11/30 15:31:43 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kde-l10n/ChangeLog,v 1.158 2012/12/05 16:57:38 alexxy Exp $
+
+*kde-l10n-4.9.4 (05 Dec 2012)
+
+  05 Dec 2012; Alexey Shvetsov <alexxy@gentoo.org> +kde-l10n-4.9.4.ebuild:
+  Version bump KDE SC 4.9.4
 
   30 Nov 2012; <ago@gentoo.org> kde-l10n-4.9.3.ebuild:
   Stable for ppc, wrt bug #442394
diff --git a/kde-base/kde-l10n/kde-l10n-4.9.4.ebuild b/kde-base/kde-l10n/kde-l10n-4.9.4.ebuild
new file mode 100644
index 000000000000..971eed58cb43
--- /dev/null
+++ b/kde-base/kde-l10n/kde-l10n-4.9.4.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kde-l10n/kde-l10n-4.9.4.ebuild,v 1.1 2012/12/05 16:57:38 alexxy Exp $
+
+EAPI=4
+
+inherit kde4-base
+
+DESCRIPTION="KDE internationalization package"
+
+DEPEND="
+	sys-devel/gettext
+"
+RDEPEND="!<kde-misc/konq-plugins-4.6"
+
+KEYWORDS="~amd64 ~arm ~ppc ~x86 ~amd64-linux ~x86-linux"
+IUSE="+handbook"
+
+# /usr/portage/distfiles $ ls -1 kde-l10n-*-${PV}.* |sed -e 's:-${PV}.tar.xz::' -e 's:kde-l10n-::' |tr '\n' ' '
+MY_LANGS="ar bg bs ca ca@valencia cs da de el en_GB es et eu fa fi fr ga gl he
+hi hr hu ia is it ja kk km ko lt lv nb nds nl nn pa pl pt pt_BR ro ru si sk sl
+sr sv tg th tr ug uk vi wa zh_CN zh_TW"
+
+URI_BASE="${SRC_URI/-${PV}.tar.xz/}"
+SRC_URI=""
+
+for MY_LANG in ${MY_LANGS} ; do
+	IUSE="${IUSE} linguas_${MY_LANG}"
+	SRC_URI="${SRC_URI} linguas_${MY_LANG}? ( ${URI_BASE}/${PN}-${MY_LANG}-${PV}.tar.xz )"
+done
+
+S="${WORKDIR}"
+
+src_unpack() {
+	local LNG DIR
+	if [[ -z ${A} ]]; then
+		elog
+		elog "You either have the LINGUAS variable unset, or it only"
+		elog "contains languages not supported by ${P}."
+		elog "You won't have any additional language support."
+		elog
+		elog "${P} supports these language codes:"
+		elog "${MY_LANGS}"
+		elog
+	fi
+
+	[[ -n ${A} ]] && unpack ${A}
+	cd "${S}"
+
+	# add all linguas to cmake
+	if [[ -n ${A} ]]; then
+		for LNG in ${LINGUAS}; do
+			DIR="${PN}-${LNG}-${PV}"
+			if [[ -d "${DIR}" ]] ; then
+				echo "add_subdirectory( ${DIR} )" >> "${S}"/CMakeLists.txt
+			fi
+		done
+	fi
+}
+
+src_prepare() {
+	find "${S}" -name CMakeLists.txt -type f \
+		-exec sed -i -e 's:^ *add_subdirectory( *kdepim-runtime *):# no kdepim-runtime:g' {} +
+	find "${S}" -name CMakeLists.txt -type f \
+		-exec sed -i -e 's:^ *add_subdirectory( *kdepim *):# no kdepim:g' {} +
+
+	kde4-base_src_prepare
+}
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_build handbook docs)
+	)
+	[[ -n ${A} ]] && kde4-base_src_configure
+}
+
+src_compile() {
+	[[ -n ${A} ]] && kde4-base_src_compile
+}
+
+src_test() {
+	[[ -n ${A} ]] && kde4-base_src_test
+}
+
+src_install() {
+	[[ -n ${A} ]] && kde4-base_src_install
+}